options {
  LOOKAHEAD = 1;
  CHOICE_AMBIGUITY_CHECK = 2;
  OTHER_AMBIGUITY_CHECK = 1;
  STATIC = true;
  DEBUG_PARSER = false;
  DEBUG_LOOKAHEAD = false;
  DEBUG_TOKEN_MANAGER = false;
  OPTIMIZE_TOKEN_MANAGER = false;
  ERROR_REPORTING = true;
  JAVA_UNICODE_ESCAPE = false;
  UNICODE_INPUT = false;
  IGNORE_CASE = true;
  USER_TOKEN_MANAGER = false;
  USER_CHAR_STREAM = false;
  BUILD_PARSER = true;
  BUILD_TOKEN_MANAGER = true;
  SANITY_CHECK = true;
  FORCE_LA_CHECK = false;
}

PARSER_BEGIN(PHPParser)
package test;

import org.eclipse.core.resources.IFile;
import org.eclipse.core.resources.IMarker;
import org.eclipse.core.runtime.CoreException;
import org.eclipse.ui.texteditor.MarkerUtilities;
import org.eclipse.jface.preference.IPreferenceStore;

import java.util.Hashtable;
import java.util.Enumeration;
import java.io.StringReader;
import java.io.*;
import java.text.MessageFormat;

import net.sourceforge.phpeclipse.actions.PHPStartApacheAction;
import net.sourceforge.phpeclipse.PHPeclipsePlugin;
import net.sourceforge.phpdt.internal.compiler.parser.*;
import net.sourceforge.phpdt.internal.compiler.ast.*;

/**
 * A new php parser.
 * This php parser is inspired by the Java 1.2 grammar example
 * given with JavaCC. You can get JavaCC at http://www.webgain.com
 * You can test the parser with the PHPParserTestCase2.java
 * @author Matthieu Casanova
 */
public final class PHPParser extends PHPParserSuperclass {

  /** The file that is parsed. */
  private static IFile fileToParse;

  /** The current segment. */
  private static PHPSegmentWithChildren currentSegment;

  private static final String PARSE_ERROR_STRING = "Parse error"; //$NON-NLS-1$
  private static final String PARSE_WARNING_STRING = "Warning"; //$NON-NLS-1$
  static PHPOutlineInfo outlineInfo;

  private static PHPFunctionDeclaration currentFunction;
  private static boolean assigning;

  /** The error level of the current ParseException. */
  private static int errorLevel = ERROR;
  /** The message of the current ParseException. If it's null it's because the parse exception wasn't handled */
  private static String errorMessage;

  private static int errorStart = -1;
  private static int errorEnd = -1;

  //ast stack
  private final static int AstStackIncrement = 100;
  /** The stack of node. */
  private static AstNode[] astStack;
  /** The cursor in expression stack. */
	private static int expressionPtr;

  public final void setFileToParse(final IFile fileToParse) {
    this.fileToParse = fileToParse;
  }

  public PHPParser() {
  }

  public PHPParser(final IFile fileToParse) {
    this(new StringReader(""));
    this.fileToParse = fileToParse;
  }

  public static final void phpParserTester(final String strEval) throws CoreException, ParseException {
    PHPParserTokenManager.SwitchTo(PHPParserTokenManager.PHPPARSING);
    final StringReader stream = new StringReader(strEval);
    if (jj_input_stream == null) {
      jj_input_stream = new SimpleCharStream(stream, 1, 1);
    }
    ReInit(new StringReader(strEval));
    astStack = new AstNode[AstStackIncrement];
    phpTest();
  }

  public static final void htmlParserTester(final File fileName) throws CoreException, ParseException {
    try {
      final Reader stream = new FileReader(fileName);
      if (jj_input_stream == null) {
        jj_input_stream = new SimpleCharStream(stream, 1, 1);
      }
      ReInit(stream);
      astStack = new AstNode[AstStackIncrement];
      phpFile();
    } catch (FileNotFoundException e) {
      e.printStackTrace();  //To change body of catch statement use Options | File Templates.
    }
  }

  public static final void htmlParserTester(final String strEval) throws CoreException, ParseException {
    final StringReader stream = new StringReader(strEval);
    if (jj_input_stream == null) {
      jj_input_stream = new SimpleCharStream(stream, 1, 1);
    }
    ReInit(stream);
    astStack = new AstNode[AstStackIncrement];
    phpFile();
  }

  public final PHPOutlineInfo parseInfo(final Object parent, final String s) {
    outlineInfo = new PHPOutlineInfo(parent);
    currentSegment = outlineInfo.getDeclarations();
    final StringReader stream = new StringReader(s);
    if (jj_input_stream == null) {
      jj_input_stream = new SimpleCharStream(stream, 1, 1);
    }
    ReInit(stream);
    astStack = new AstNode[AstStackIncrement];
    try {
      parse();
    } catch (ParseException e) {
      processParseException(e);
    }
    return outlineInfo;
  }

  /**
   * This method will process the parse exception.
   * If the error message is null, the parse exception wasn't catched and a trace is written in the log
   * @param e the ParseException
   */
  private static void processParseException(final ParseException e) {
    if (errorMessage == null) {
      PHPeclipsePlugin.log(e);
      errorMessage = "this exception wasn't handled by the parser please tell us how to reproduce it";
      errorStart = jj_input_stream.getPosition();
      errorEnd   = errorStart + 1;
    }
    setMarker(e);
    errorMessage = null;
  }

  /**
   * Create marker for the parse error
   * @param e the ParseException
   */
  private static void setMarker(final ParseException e) {
    try {
      if (errorStart == -1) {
        setMarker(fileToParse,
                  errorMessage,
                  jj_input_stream.tokenBegin,
                  jj_input_stream.tokenBegin + e.currentToken.image.length(),
                  errorLevel,
                  "Line " + e.currentToken.beginLine);
      } else {
        setMarker(fileToParse,
                  errorMessage,
                  errorStart,
                  errorEnd,
                  errorLevel,
                  "Line " + e.currentToken.beginLine);
        errorStart = -1;
        errorEnd = -1;
      }
    } catch (CoreException e2) {
      PHPeclipsePlugin.log(e2);
    }
  }

  /**
   * Create markers according to the external parser output
   */
  private static void createMarkers(final String output, final IFile file) throws CoreException {
    // delete all markers
    file.deleteMarkers(IMarker.PROBLEM, false, 0);

    int indx = 0;
    int brIndx;
    boolean flag = true;
    while ((brIndx = output.indexOf("<br />", indx)) != -1) {
      // newer php error output (tested with 4.2.3)
      scanLine(output, file, indx, brIndx);
      indx = brIndx + 6;
      flag = false;
    }
    if (flag) {
      while ((brIndx = output.indexOf("<br>", indx)) != -1) {
        // older php error output (tested with 4.2.3)
        scanLine(output, file, indx, brIndx);
        indx = brIndx + 4;
      }
    }
  }

  private static void scanLine(final String output,
                               final IFile file,
                               final int indx,
                               final int brIndx) throws CoreException {
    String current;
    StringBuffer lineNumberBuffer = new StringBuffer(10);
    char ch;
    current = output.substring(indx, brIndx);

    if (current.indexOf(PARSE_WARNING_STRING) != -1 || current.indexOf(PARSE_ERROR_STRING) != -1) {
      int onLine = current.indexOf("on line <b>");
      if (onLine != -1) {
        lineNumberBuffer.delete(0, lineNumberBuffer.length());
        for (int i = onLine; i < current.length(); i++) {
          ch = current.charAt(i);
          if ('0' <= ch && '9' >= ch) {
            lineNumberBuffer.append(ch);
          }
        }

        int lineNumber = Integer.parseInt(lineNumberBuffer.toString());

        Hashtable attributes = new Hashtable();

        current = current.replaceAll("\n", "");
        current = current.replaceAll("<b>", "");
        current = current.replaceAll("</b>", "");
        MarkerUtilities.setMessage(attributes, current);

        if (current.indexOf(PARSE_ERROR_STRING) != -1)
          attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_ERROR));
        else if (current.indexOf(PARSE_WARNING_STRING) != -1)
          attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_WARNING));
        else
          attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_INFO));
        MarkerUtilities.setLineNumber(attributes, lineNumber);
        MarkerUtilities.createMarker(file, attributes, IMarker.PROBLEM);
      }
    }
  }

  public final void parse(final String s) throws CoreException {
    final StringReader stream = new StringReader(s);
    if (jj_input_stream == null) {
      jj_input_stream = new SimpleCharStream(stream, 1, 1);
    }
    ReInit(stream);
    astStack = new AstNode[AstStackIncrement];
    try {
      parse();
    } catch (ParseException e) {
      processParseException(e);
    }
  }

  /**
   * Call the php parse command ( php -l -f &lt;filename&gt; )
   * and create markers according to the external parser output
   */
  public static void phpExternalParse(final IFile file) {
    final IPreferenceStore store = PHPeclipsePlugin.getDefault().getPreferenceStore();
    final String filename = file.getLocation().toString();

    final String[] arguments = { filename };
    final MessageFormat form = new MessageFormat(store.getString(PHPeclipsePlugin.EXTERNAL_PARSER_PREF));
    final String command = form.format(arguments);

    final String parserResult = PHPStartApacheAction.getParserOutput(command, "External parser: ");

    try {
      // parse the buffer to find the errors and warnings
      createMarkers(parserResult, file);
    } catch (CoreException e) {
      PHPeclipsePlugin.log(e);
    }
  }

  private static final void parse() throws ParseException {
	  phpFile();
  }
}

PARSER_END(PHPParser)

<DEFAULT> TOKEN :
{
  <PHPSTARTSHORT : "<?">   : PHPPARSING
| <PHPSTARTLONG : "<?php"> : PHPPARSING
| <PHPECHOSTART : "<?=">   : PHPPARSING
}

<PHPPARSING> TOKEN :
{
  <PHPEND :"?>"> : DEFAULT
}

/* Skip any character if we are not in php mode */
<DEFAULT> SKIP :
{
 < ~[] >
}


/* WHITE SPACE */
<PHPPARSING> SKIP :
{
  " "
| "\t"
| "\n"
| "\r"
| "\f"
}

/* COMMENTS */
<PHPPARSING> SPECIAL_TOKEN :
{
  "//" : IN_SINGLE_LINE_COMMENT
|
  "#"  : IN_SINGLE_LINE_COMMENT
|
  <"/**" ~["/"]> { input_stream.backup(1); } : IN_FORMAL_COMMENT
|
  "/*" : IN_MULTI_LINE_COMMENT
}

<IN_SINGLE_LINE_COMMENT> SPECIAL_TOKEN :
{
  <SINGLE_LINE_COMMENT: "\n" | "\r" | "\r\n" > : PHPPARSING
}

<IN_SINGLE_LINE_COMMENT> SPECIAL_TOKEN :
{
  <SINGLE_LINE_COMMENT_PHPEND : "?>" > : DEFAULT
}

<IN_FORMAL_COMMENT>
SPECIAL_TOKEN :
{
  <FORMAL_COMMENT: "*/" > : PHPPARSING
}

<IN_MULTI_LINE_COMMENT>
SPECIAL_TOKEN :
{
  <MULTI_LINE_COMMENT: "*/" > : PHPPARSING
}

<IN_SINGLE_LINE_COMMENT,IN_FORMAL_COMMENT,IN_MULTI_LINE_COMMENT>
MORE :
{
  < ~[] >
}

/* KEYWORDS */
<PHPPARSING> TOKEN :
{
  <CLASS    : "class">
| <FUNCTION : "function">
| <VAR      : "var">
| <IF       : "if">
| <ELSEIF   : "elseif">
| <ELSE     : "else">
| <ARRAY    : "array">
| <BREAK    : "break">
| <LIST     : "list">
}

/* LANGUAGE CONSTRUCT */
<PHPPARSING> TOKEN :
{
  <PRINT              : "print">
| <ECHO               : "echo">
| <INCLUDE            : "include">
| <REQUIRE            : "require">
| <INCLUDE_ONCE       : "include_once">
| <REQUIRE_ONCE       : "require_once">
| <GLOBAL             : "global">
| <STATIC             : "static">
| <CLASSACCESS        : "->">
| <STATICCLASSACCESS  : "::">
| <ARRAYASSIGN        : "=>">
}

/* RESERVED WORDS AND LITERALS */

<PHPPARSING> TOKEN :
{
  <CASE     : "case">
| <CONST    : "const">
| <CONTINUE : "continue">
| <_DEFAULT : "default">
| <DO       : "do">
| <EXTENDS  : "extends">
| <FOR      : "for">
| <GOTO     : "goto">
| <NEW      : "new">
| <NULL     : "null">
| <RETURN   : "return">
| <SUPER    : "super">
| <SWITCH   : "switch">
| <THIS     : "this">
| <TRUE     : "true">
| <FALSE    : "false">
| <WHILE    : "while">
| <ENDWHILE : "endwhile">
| <ENDSWITCH: "endswitch">
| <ENDIF    : "endif">
| <ENDFOR   : "endfor">
| <FOREACH  : "foreach">
| <AS       : "as" >
}

/* TYPES */
<PHPPARSING> TOKEN :
{
  <STRING  : "string">
| <OBJECT  : "object">
| <BOOL    : "bool">
| <BOOLEAN : "boolean">
| <REAL    : "real">
| <DOUBLE  : "double">
| <FLOAT   : "float">
| <INT     : "int">
| <INTEGER : "integer">
}

<PHPPARSING> TOKEN :
{
  <_ORL  : "OR">
| <_ANDL : "AND">
}

/* LITERALS */
<PHPPARSING> TOKEN :
{
  < INTEGER_LITERAL:
        <DECIMAL_LITERAL> (["l","L"])?
      | <HEX_LITERAL> (["l","L"])?
      | <OCTAL_LITERAL> (["l","L"])?
  >
|
  < #DECIMAL_LITERAL: ["1"-"9"] (["0"-"9"])* >
|
  < #HEX_LITERAL: "0" ["x","X"] (["0"-"9","a"-"f","A"-"F"])+ >
|
  < #OCTAL_LITERAL: "0" (["0"-"7"])* >
|
  < FLOATING_POINT_LITERAL:
        (["0"-"9"])+ "." (["0"-"9"])* (<EXPONENT>)? (["f","F","d","D"])?
      | "." (["0"-"9"])+ (<EXPONENT>)? (["f","F","d","D"])?
      | (["0"-"9"])+ <EXPONENT> (["f","F","d","D"])?
      | (["0"-"9"])+ (<EXPONENT>)? ["f","F","d","D"]
  >
|
  < #EXPONENT: ["e","E"] (["+","-"])? (["0"-"9"])+ >
|
  < STRING_LITERAL: (<STRING_1> | <STRING_2> | <STRING_3>)>
|    < STRING_1:
      "\""
      (
          ~["\"","{","}"]
        | "\\\""
        | "\\"
        | "{" ~["\""] "}"
      )*
      "\""
    >
|    < STRING_2:
      "'"
      (
         ~["'"]
       | "\\'"
      )*

      "'"
    >
|   < STRING_3:
      "`"
      (
        ~["`"]
      | "\\`"
      )*
      "`"
    >
}

/* IDENTIFIERS */

<PHPPARSING> TOKEN :
{
  < IDENTIFIER: (<LETTER>|<SPECIAL>) (<LETTER>|<DIGIT>|<SPECIAL>)* >
|
  < #LETTER:
      ["a"-"z"] | ["A"-"Z"]
  >
|
  < #DIGIT:
      ["0"-"9"]
  >
|
  < #SPECIAL:
    "_" | ["\u007f"-"\u00ff"]
  >
}

/* SEPARATORS */

<PHPPARSING> TOKEN :
{
  <LPAREN    : "(">
| <RPAREN    : ")">
| <LBRACE    : "{">
| <RBRACE    : "}">
| <LBRACKET  : "[">
| <RBRACKET  : "]">
| <SEMICOLON : ";">
| <COMMA     : ",">
| <DOT       : ".">
}


/* COMPARATOR */
<PHPPARSING> TOKEN :
{
  <GT                 : ">">
| <LT                 : "<">
| <EQ                 : "==">
| <LE                 : "<=">
| <GE                 : ">=">
| <NE                 : "!=">
| <DIF                : "<>">
| <BANGDOUBLEEQUAL    : "!==">
| <TRIPLEEQUAL        : "===">
}

/* ASSIGNATION */
<PHPPARSING> TOKEN :
{
  <ASSIGN             : "=">
| <PLUSASSIGN         : "+=">
| <MINUSASSIGN        : "-=">
| <STARASSIGN         : "*=">
| <SLASHASSIGN        : "/=">
| <ANDASSIGN          : "&=">
| <ORASSIGN           : "|=">
| <XORASSIGN          : "^=">
| <DOTASSIGN          : ".=">
| <REMASSIGN          : "%=">
| <TILDEEQUAL         : "~=">
}

/* OPERATORS */
<PHPPARSING> TOKEN :
{
  <AT                 : "@">
| <DOLLAR             : "$">
| <BANG               : "!">
| <TILDE              : "~">
| <HOOK               : "?">
| <COLON              : ":">
| <SC_OR              : "||">
| <SC_AND             : "&&">
| <INCR               : "++">
| <DECR               : "--">
| <PLUS               : "+">
| <MINUS              : "-">
| <STAR               : "*">
| <SLASH              : "/">
| <BIT_AND            : "&">
| <BIT_OR             : "|">
| <XOR                : "^">
| <REM                : "%">
| <LSHIFT             : "<<">
| <RSIGNEDSHIFT       : ">>">
| <RUNSIGNEDSHIFT     : ">>>">
| <LSHIFTASSIGN       : "<<=">
| <RSIGNEDSHIFTASSIGN : ">>=">
}

<PHPPARSING> TOKEN :
{
  < DOLLAR_ID: <DOLLAR> <IDENTIFIER>  >
}

void phpTest() :
{}
{
  Php()
  <EOF>
}

void phpFile() :
{}
{
  try {
    (PhpBlock())*
    <EOF>
  } catch (TokenMgrError e) {
    PHPeclipsePlugin.log(e);
    errorStart   = SimpleCharStream.getPosition();
    errorEnd     = errorStart + 1;
    errorMessage = e.getMessage();
    errorLevel   = ERROR;
    throw generateParseException();
  }
}

/**
 * A php block is a <?= expression [;]?>
 * or <?php somephpcode ?>
 * or <? somephpcode ?>
 */
void PhpBlock() :
{
  final int start = jj_input_stream.getPosition();
}
{
  phpEchoBlock()
|
  [ <PHPSTARTLONG>
    | <PHPSTARTSHORT>
    {try {
      setMarker(fileToParse,
                "You should use '<?php' instead of '<?' it will avoid some problems with XML",
                start,
                jj_input_stream.getPosition(),
                INFO,
                "Line " + token.beginLine);
    } catch (CoreException e) {
      PHPeclipsePlugin.log(e);
    }}
  ]
  Php()
  try {
    <PHPEND>
  } catch (ParseException e) {
    errorMessage = "'?>' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void phpEchoBlock() :
{}
{
  <PHPECHOSTART> Expression() [ <SEMICOLON> ] <PHPEND>
}

void Php() :
{}
{
  (BlockStatement())*
}

void ClassDeclaration() :
{
  final PHPClassDeclaration classDeclaration;
  final Token className;
  final int pos;
}
{
  <CLASS>
  try {
    {pos = jj_input_stream.getPosition();}
    className = <IDENTIFIER>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', identifier expected";
    errorLevel   = ERROR;
    errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd     = jj_input_stream.getPosition() + 1;
    throw e;
  }
  [
    <EXTENDS>
    try {
      <IDENTIFIER>
    } catch (ParseException e) {
      errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', identifier expected";
      errorLevel   = ERROR;
      errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
      errorEnd   = jj_input_stream.getPosition() + 1;
      throw e;
    }
  ]
  {
    if (currentSegment != null) {
      classDeclaration = new PHPClassDeclaration(currentSegment,className.image,pos);
      currentSegment.add(classDeclaration);
      currentSegment = classDeclaration;
    }
  }
  ClassBody()
  {
    if (currentSegment != null) {
      currentSegment = (PHPSegmentWithChildren) currentSegment.getParent();
    }
  }
}

void ClassBody() :
{}
{
  try {
    <LBRACE>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image + "', '{' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  ( ClassBodyDeclaration() )*
  try {
    <RBRACE>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', 'var', 'function' or '}' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

/**
 * A class can contain only methods and fields.
 */
void ClassBodyDeclaration() :
{}
{
  MethodDeclaration()
| FieldDeclaration()
}

/**
 * A class field declaration : it's var VariableDeclarator() (, VariableDeclarator())*;.
 */
void FieldDeclaration() :
{
  PHPVarDeclaration variableDeclaration;
}
{
  <VAR> variableDeclaration = VariableDeclarator()
  {
    outlineInfo.addVariable(variableDeclaration.getVariable().getName());
    if (currentSegment != null) {
      currentSegment.add(variableDeclaration);
    }
  }
  ( <COMMA>
      variableDeclaration = VariableDeclarator()
      {
      if (currentSegment != null) {
        currentSegment.add(variableDeclaration);
      }
      }
  )*
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected after variable declaration";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

PHPVarDeclaration VariableDeclarator() :
{
  final String varName, varValue;
  final int pos = jj_input_stream.getPosition();
}
{
  varName = VariableDeclaratorId()
  [
    <ASSIGN>
    try {
      varValue = VariableInitializer()
      {return new PHPVarDeclaration(currentSegment,varName,pos,varValue);}
    } catch (ParseException e) {
      errorMessage = "Literal expression expected in variable initializer";
      errorLevel   = ERROR;
      errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
      errorEnd   = jj_input_stream.getPosition() + 1;
      throw e;
    }
  ]
  {return new PHPVarDeclaration(currentSegment,varName,pos);}
}

String VariableDeclaratorId() :
{
  String expr;
  final StringBuffer buff = new StringBuffer();
}
{
  try {
    expr = Variable()   {buff.append(expr);}
    ( LOOKAHEAD(2)
      expr = VariableSuffix() {buff.append(expr);}
    )*
    {return buff.toString();}
  } catch (ParseException e) {
    errorMessage = "'$' expected for variable identifier";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

String Variable():
{
  String expr = null;
  final Token token;
}
{
  token = <DOLLAR_ID> [<LBRACE> expr = Expression() <RBRACE>]
  {
    if (expr == null && !assigning) {
      if (currentFunction != null) {
        PHPVarDeclaration var = currentFunction.getParameter(token.image.substring(1));
        if (var != null) {
          var.getVariable().setUsed(true);
        }
      }
      return token.image.substring(1);
    }
    return token + "{" + expr + "}";
  }
|
  <DOLLAR> expr = VariableName()
  {return expr;}
}

String VariableName():
{
String expr = null;
final Token token;
}
{
  <LBRACE> expr = Expression() <RBRACE>
  {return "{"+expr+"}";}
|
  token = <IDENTIFIER> [<LBRACE> expr = Expression() <RBRACE>]
  {
    if (expr == null) {
      if (currentFunction != null) {
        PHPVarDeclaration var = currentFunction.getParameter(token.image);
        if (var != null) {
          var.getVariable().setUsed(true);
        }
      }
      return token.image;
    }
    return token + "{" + expr + "}";
  }
|
  <DOLLAR> expr = VariableName()
  {
    if (currentFunction != null) {
      PHPVarDeclaration var = currentFunction.getParameter(expr);
      if (var != null) {
        var.getVariable().setUsed(true);
      }
    }
    return "$" + expr;
  }
|
  token = <DOLLAR_ID>
  {
    if (currentFunction != null) {
      PHPVarDeclaration var = currentFunction.getParameter(token.image.substring(1));
      if (var != null) {
        var.getVariable().setUsed(true);
      }
    }
    return token.image + expr;
  }
/*|      pas besoin ?
  token = <DOLLAR_ID> [expr = VariableName()]
  {
  if (expr == null) {
    return token.image;
  }
  return token.image + expr;
  }*/
}

String VariableInitializer() :
{
  final String expr;
  final Token token;
}
{
  expr = Literal()
  {return expr;}
|
  <MINUS> (token = <INTEGER_LITERAL> | token = <FLOATING_POINT_LITERAL>)
  {return "-" + token.image;}
|
  <PLUS> (token = <INTEGER_LITERAL> | token = <FLOATING_POINT_LITERAL>)
  {return "+" + token.image;}
|
  expr = ArrayDeclarator()
  {return expr;}
|
  token = <IDENTIFIER>
  {return token.image;}
}

String ArrayVariable() :
{
String expr;
final StringBuffer buff = new StringBuffer();
}
{
  expr = Expression()
  {buff.append(expr);}
   [<ARRAYASSIGN> expr = Expression()
   {buff.append("=>").append(expr);}]
  {return buff.toString();}
}

String ArrayInitializer() :
{
String expr;
final StringBuffer buff = new StringBuffer("(");
}
{
  <LPAREN> [ expr = ArrayVariable()
            {buff.append(expr);}
            ( LOOKAHEAD(2) <COMMA> expr = ArrayVariable()
            {buff.append(",").append(expr);}
            )*
           ]
           [<COMMA> {buff.append(",");}]
  <RPAREN>
  {
    buff.append(")");
    return buff.toString();
  }
}

/**
 * A Method Declaration.
 * <b>function</b> MetodDeclarator() Block()
 */
void MethodDeclaration() :
{
  final PHPFunctionDeclaration functionDeclaration;
  Token functionToken;
}
{
  functionToken = <FUNCTION>
  try {
    functionDeclaration = MethodDeclarator()
    {outlineInfo.addVariable(functionDeclaration.getName());}
  } catch (ParseException e) {
    if (errorMessage != null) {
      throw e;
    }
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', function identifier expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {
    if (currentSegment != null) {
      currentSegment.add(functionDeclaration);
      currentSegment = functionDeclaration;
    }
    currentFunction = functionDeclaration;
  }
  Block()
  {
    Hashtable parameters = currentFunction.getParameters();
    Enumeration vars = parameters.elements();
    while (vars.hasMoreElements()) {
      PHPVarDeclaration o = (PHPVarDeclaration) vars.nextElement();
      if (!o.getVariable().isUsed()) {
        try {
          setMarker(fileToParse,
                    "Parameter "+o.getVariable().getName()+" is never used in function",
                    functionToken.beginLine,
                    WARNING,
                    "Line " + token.beginLine);
        } catch (CoreException e) {
          PHPeclipsePlugin.log(e);
        }
      }
    }
    currentFunction = null;
    if (currentSegment != null) {
      currentSegment = (PHPSegmentWithChildren) currentSegment.getParent();
    }
  }
}

/**
 * A MethodDeclarator.
 * [&] IDENTIFIER(parameters ...).
 * @return a function description for the outline
 */
PHPFunctionDeclaration MethodDeclarator() :
{
  final Token identifier;
  final StringBuffer methodDeclaration = new StringBuffer();
  final Hashtable formalParameters;
  final int pos = jj_input_stream.getPosition();
}
{
  [ <BIT_AND> {methodDeclaration.append("&");} ]
  identifier = <IDENTIFIER>
  formalParameters = FormalParameters()
  {
    methodDeclaration.append(identifier);
    return new PHPFunctionDeclaration(currentSegment,methodDeclaration.toString(),pos,formalParameters);
  }
}

/**
 * FormalParameters follows method identifier.
 * (FormalParameter())
 */
Hashtable FormalParameters() :
{
  String expr;
  final StringBuffer buff = new StringBuffer("(");
  PHPVarDeclaration var;
  final Hashtable parameters = new Hashtable();
}
{
  try {
  <LPAREN>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', '(' expected after function identifier";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
            [ var = FormalParameter()
              {parameters.put(var.getVariable().getName(),var);}
              (
                <COMMA> var = FormalParameter()
                {parameters.put(var.getVariable().getName(),var);}
              )*
            ]
  try {
    <RPAREN>
  } catch (ParseException e) {
    errorMessage = "')' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
 {return parameters;}
}

/**
 * A formal parameter.
 * $varname[=value] (,$varname[=value])
 */
PHPVarDeclaration FormalParameter() :
{
  final PHPVarDeclaration variableDeclaration;
  Token token = null;
}
{
  [token = <BIT_AND>] variableDeclaration = VariableDeclarator()
  {
    if (token != null) {
      variableDeclaration.getVariable().setReference(true);
    }
    return variableDeclaration;
  }
}

String Type() :
{}
{
  <STRING>  {return "string";}
| <BOOL>    {return "bool";}
| <BOOLEAN> {return "boolean";}
| <REAL>    {return "real";}
| <DOUBLE>  {return "double";}
| <FLOAT>   {return "float";}
| <INT>     {return "int";}
| <INTEGER> {return "integer";}
| <OBJECT>  {return "object";}
}

String Expression() :
{
  final String expr;
  final String assignOperator;
  final String expr2;
}
{
  expr = PrintExpression()       {return expr;}
| expr = ListExpression()        {return expr;}
| LOOKAHEAD(varAssignation())
  expr = varAssignation()        {return expr;}
| expr = ConditionalExpression() {return expr;}
}

/**
 * A Variable assignation.
 * varName (an assign operator) any expression
 */
String varAssignation() :
{
  String varName,assignOperator,expr2;
  PHPVarDeclaration variable;
  final int pos = SimpleCharStream.getPosition();
}
{
  varName = VariableDeclaratorId()
  assignOperator = AssignmentOperator()
    try {
      expr2 = Expression()
    } catch (ParseException e) {
      if (errorMessage != null) {
        throw e;
      }
      errorMessage = "expression expected";
      errorLevel   = ERROR;
      errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
      errorEnd   = jj_input_stream.getPosition() + 1;
      throw e;
    }
    {return varName + assignOperator + expr2;}
}

String AssignmentOperator() :
{}
{
  <ASSIGN>             {return "=";}
| <STARASSIGN>         {return "*=";}
| <SLASHASSIGN>        {return "/=";}
| <REMASSIGN>          {return "%=";}
| <PLUSASSIGN>         {return "+=";}
| <MINUSASSIGN>        {return "-=";}
| <LSHIFTASSIGN>       {return "<<=";}
| <RSIGNEDSHIFTASSIGN> {return ">>=";}
| <ANDASSIGN>          {return "&=";}
| <XORASSIGN>          {return "|=";}
| <ORASSIGN>           {return "|=";}
| <DOTASSIGN>          {return ".=";}
| <TILDEEQUAL>         {return "~=";}
}

String ConditionalExpression() :
{
  final String expr;
  String expr2 = null;
  String expr3 = null;
}
{
  expr = ConditionalOrExpression() [ <HOOK> expr2 = Expression() <COLON> expr3 = ConditionalExpression() ]
{
  if (expr3 == null) {
    return expr;
  } else {
    return expr + "?" + expr2 + ":" + expr3;
  }
}
}

String ConditionalOrExpression() :
{
  String expr;
  Token operator;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = ConditionalAndExpression()
  {buff.append(expr);}
  (
    (operator = <SC_OR> | operator = <_ORL>) expr = ConditionalAndExpression()
    {
      buff.append(operator.image);
      buff.append(expr);
    }
  )*
  {
    return buff.toString();
  }
}

String ConditionalAndExpression() :
{
  String expr;
  Token operator;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = ConcatExpression()
  {buff.append(expr);}
  (
  (operator = <SC_AND> | operator = <_ANDL>) expr = ConcatExpression()
    {
      buff.append(operator.image);
      buff.append(expr);
    }
  )*
  {return buff.toString();}
}

String ConcatExpression() :
{
  String expr;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = InclusiveOrExpression()
  {buff.append(expr);}
  (
  <DOT> expr = InclusiveOrExpression()
  {buff.append(".").append(expr);}
  )*
  {return buff.toString();}
}

String InclusiveOrExpression() :
{
  String expr;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = ExclusiveOrExpression()
  {buff.append(expr);}
  (
  <BIT_OR> expr = ExclusiveOrExpression()
  {buff.append("|").append(expr);}
  )*
  {return buff.toString();}
}

String ExclusiveOrExpression() :
{
  String expr;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = AndExpression()
  {
    buff.append(expr);
  }
  (
    <XOR> expr = AndExpression()
  {
    buff.append("^");
    buff.append(expr);
  }
  )*
  {
    return buff.toString();
  }
}

String AndExpression() :
{
  String expr;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = EqualityExpression()
  {
    buff.append(expr);
  }
  (
    <BIT_AND> expr = EqualityExpression()
  {
    buff.append("&").append(expr);
  }
  )*
  {return buff.toString();}
}

String EqualityExpression() :
{
  String expr;
  Token operator;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = RelationalExpression()
  {buff.append(expr);}
  (
  (   operator = <EQ>
    | operator = <DIF>
    | operator = <NE>
    | operator = <BANGDOUBLEEQUAL>
    | operator = <TRIPLEEQUAL>
  )
  try {
    expr = RelationalExpression()
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', expression expected after '"+operator.image+"'";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {
    buff.append(operator.image);
    buff.append(expr);
  }
  )*
  {return buff.toString();}
}

String RelationalExpression() :
{
  String expr;
  Token operator;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = ShiftExpression()
  {buff.append(expr);}
  (
  ( operator = <LT> | operator = <GT> | operator = <LE> | operator = <GE> ) expr = ShiftExpression()
  {buff.append(operator.image).append(expr);}
  )*
  {return buff.toString();}
}

String ShiftExpression() :
{
  String expr;
  Token operator;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = AdditiveExpression()
  {buff.append(expr);}
  (
  (operator = <LSHIFT> | operator = <RSIGNEDSHIFT> | operator = <RUNSIGNEDSHIFT> ) expr = AdditiveExpression()
  {
    buff.append(operator.image);
    buff.append(expr);
  }
  )*
  {return buff.toString();}
}

String AdditiveExpression() :
{
  String expr;
  Token operator;
  final StringBuffer buff = new StringBuffer();
}
{
  expr = MultiplicativeExpression()
  {buff.append(expr);}
  (
   ( operator = <PLUS> | operator = <MINUS> ) expr = MultiplicativeExpression()
  {
    buff.append(operator.image);
    buff.append(expr);
  }
   )*
  {return buff.toString();}
}

String MultiplicativeExpression() :
{
  String expr;
  Token operator;
  final StringBuffer buff = new StringBuffer();}
{
  try {
    expr = UnaryExpression()
  } catch (ParseException e) {
    errorMessage = "unexpected token '"+e.currentToken.next.image+"'";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {buff.append(expr);}
  (
    ( operator = <STAR> | operator = <SLASH> | operator = <REM> ) expr = UnaryExpression()
    {
      buff.append(operator.image);
      buff.append(expr);
    }
  )*
  {return buff.toString();}
}

/**
 * An unary expression starting with @, & or nothing
 */
String UnaryExpression() :
{
  final String expr;
  final Token token;
  final StringBuffer buff = new StringBuffer();
}
{
  token = <BIT_AND> expr = UnaryExpressionNoPrefix()
  {
    if (token == null) {
      return expr;
    }
    return token.image + expr;
  }
| (<AT> {buff.append("@");})*
  expr = UnaryExpressionNoPrefix()
  {return buff.append(expr).toString();}
}

String UnaryExpressionNoPrefix() :
{
  final String expr;
  final Token token;
}
{
  ( token = <PLUS> | token = <MINUS> ) expr = UnaryExpression()
  {
    return token.image + expr;
  }
|
  expr = PreIncDecExpression()
  {return expr;}
|
  expr = UnaryExpressionNotPlusMinus()
  {return expr;}
}


String PreIncDecExpression() :
{
final String expr;
final Token token;
}
{
  (token = <INCR> | token = <DECR>) expr = PrimaryExpression()
  {return token.image + expr;}
}

String UnaryExpressionNotPlusMinus() :
{
  final String expr;
}
{
  <BANG> expr = UnaryExpression() {return "!" + expr;}
| LOOKAHEAD( <LPAREN> (Type() | <ARRAY>) <RPAREN> )
  expr = CastExpression()         {return expr;}
| expr = PostfixExpression()      {return expr;}
| expr = Literal()                {return expr;}
| <LPAREN> expr = Expression()
  try {
    <RPAREN>
  } catch (ParseException e) {
    errorMessage = "')' expected";
    errorLevel   = ERROR;
    errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd     = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {return "("+expr+")";}
}

String CastExpression() :
{
final String type, expr;
}
{
  <LPAREN> (type = Type() | <ARRAY> {type = "array";}) <RPAREN> expr = UnaryExpression()
  {return "(" + type + ")" + expr;}
}

String PostfixExpression() :
{
  final String expr;
  Token operator = null;
}
{
  expr = PrimaryExpression() [ operator = <INCR> | operator = <DECR> ]
  {
    if (operator == null) {
      return expr;
    }
    return expr + operator.image;
  }
}

String PrimaryExpression() :
{
  final Token identifier;
  String expr;
  final StringBuffer buff = new StringBuffer();
}
{
  LOOKAHEAD(2)
  identifier = <IDENTIFIER> <STATICCLASSACCESS> expr = ClassIdentifier()
  {buff.append(identifier.image).append("::").append(expr);}
  (
  expr = PrimarySuffix()
  {buff.append(expr);}
  )*
  {return buff.toString();}
|
  expr = PrimaryPrefix()  {buff.append(expr);}
  ( expr = PrimarySuffix()  {buff.append(expr);} )*
  {return buff.toString();}
|
  expr = ArrayDeclarator()
  {return "array" + expr;}
}

String ArrayDeclarator() :
{
  final String expr;
}
{
  <ARRAY> expr = ArrayInitializer()
  {return "array" + expr;}
}

String PrimaryPrefix() :
{
  final String expr;
  final Token token;
}
{
  token = <IDENTIFIER>           {return token.image;}
| <NEW> expr = ClassIdentifier() {return "new " + expr;}
| expr = VariableDeclaratorId()  {return expr;}
}

String classInstantiation() :
{
  String expr;
  final StringBuffer buff = new StringBuffer("new ");
}
{
  <NEW> expr = ClassIdentifier()
  {buff.append(expr);}
  [
    expr = PrimaryExpression()
    {buff.append(expr);}
  ]
  {return buff.toString();}
}

String ClassIdentifier():
{
  final String expr;
  final Token token;
}
{
  token = <IDENTIFIER>          {return token.image;}
| expr = VariableDeclaratorId() {return expr;}
}

String PrimarySuffix() :
{
  final String expr;
}
{
  expr = Arguments()      {return expr;}
| expr = VariableSuffix() {return expr;}
}

String VariableSuffix() :
{
  String expr = null;
}
{
  <CLASSACCESS>
  try {
    expr = VariableName()
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', function call or field access expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {return "->" + expr;}
|
  <LBRACKET> [ expr = Expression() | expr = Type() ]  //Not good
  try {
    <RBRACKET>
  } catch (ParseException e) {
    errorMessage = "']' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {
    if(expr == null) {
      return "[]";
    }
    return "[" + expr + "]";
  }
}

String Literal() :
{
  final String expr;
  final Token token;
}
{
  token = <INTEGER_LITERAL>        {return token.image;}
| token = <FLOATING_POINT_LITERAL> {return token.image;}
| token = <STRING_LITERAL>         {return token.image;}
| expr = BooleanLiteral()          {return expr;}
| <NULL>                           {return "null";}
}

String BooleanLiteral() :
{}
{
  <TRUE>  {return "true";}
| <FALSE> {return "false";}
}

String Arguments() :
{
String expr = null;
}
{
  <LPAREN> [ expr = ArgumentList() ]
  try {
    <RPAREN>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', ')' expected to close the argument list";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {
  if (expr == null) {
    return "()";
  }
  return "(" + expr + ")";
  }
}

String ArgumentList() :
{
String expr;
final StringBuffer buff = new StringBuffer();
}
{
  expr = Expression()
  {buff.append(expr);}
  ( <COMMA>
      try {
        expr = Expression()
      } catch (ParseException e) {
        errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. An expression expected after a comma in argument list";
        errorLevel   = ERROR;
        errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
        errorEnd     = jj_input_stream.getPosition() + 1;
        throw e;
      }
    {buff.append(",").append(expr);}
   )*
   {return buff.toString();}
}

/**
 * A Statement without break.
 */
void StatementNoBreak() :
{}
{
  LOOKAHEAD(2)
  Expression()
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    if (e.currentToken.next.kind != 4) {
      errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected";
      errorLevel   = ERROR;
      errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
      errorEnd   = jj_input_stream.getPosition() + 1;
      throw e;
    }
  }
| LOOKAHEAD(2)
  LabeledStatement()
| Block()
| EmptyStatement()
| StatementExpression()
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected";
    errorLevel   = ERROR;
    errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd     = jj_input_stream.getPosition() + 1;
    throw e;
  }
| SwitchStatement()
| IfStatement()
| WhileStatement()
| DoStatement()
| ForStatement()
| ForeachStatement()
| ContinueStatement()
| ReturnStatement()
| EchoStatement()
| [<AT>] IncludeStatement()
| StaticStatement()
| GlobalStatement()
}

/**
 * A Normal statement.
 */
void Statement() :
{}
{
  StatementNoBreak()
| BreakStatement()
}

/**
 * An html block inside a php syntax.
 */
void htmlBlock() :
{}
{
  <PHPEND> (phpEchoBlock())*
  try {
    (<PHPSTARTLONG> | <PHPSTARTSHORT>)
  } catch (ParseException e) {
    errorMessage = "End of file unexpected, '<?php' expected";
    errorLevel   = ERROR;
    errorStart   = jj_input_stream.getPosition();
    errorEnd     = jj_input_stream.getPosition();
    throw e;
  }
}

/**
 * An include statement. It's "include" an expression;
 */
void IncludeStatement() :
{
  final String expr;
  final Token token;
  final int pos = jj_input_stream.getPosition();
}
{
  (  token = <REQUIRE>
   | token = <REQUIRE_ONCE>
   | token = <INCLUDE>
   | token = <INCLUDE_ONCE> )
    try {
      expr = Expression()
    } catch (ParseException e) {
      if (errorMessage != null) {
        throw e;
      }
      errorMessage = "unexpected token '"+ e.currentToken.next.image+"', expression expected";
      errorLevel   = ERROR;
      errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
      errorEnd     = jj_input_stream.getPosition() + 1;
      throw e;
    }
  {
    if (currentSegment != null) {
      currentSegment.add(new PHPReqIncDeclaration(currentSegment, token.image,pos,expr));
    }
  }
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected";
    errorLevel   = ERROR;
    errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd     = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

String PrintExpression() :
{
  final String expr;
}
{
  <PRINT> expr = Expression() {return "print " + expr;}
}

String ListExpression() :
{
  final StringBuffer buff = new StringBuffer("list(");
  String expr;
}
{
  <LIST>
  try {
    <LPAREN>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', '(' expected";
    errorLevel   = ERROR;
    errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd     = jj_input_stream.getPosition() + 1;
    throw e;
  }
  [
    expr = VariableDeclaratorId()
    {buff.append(expr);}
  ]
  (
    try {
      <COMMA>
    } catch (ParseException e) {
      errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', ',' expected";
      errorLevel   = ERROR;
      errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
      errorEnd     = jj_input_stream.getPosition() + 1;
      throw e;
    }
    expr = VariableDeclaratorId()
    {buff.append(",").append(expr);}
  )*
  {buff.append(")");}
  try {
    <RPAREN>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', ')' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  [ <ASSIGN> expr = Expression() {buff.append("(").append(expr);}]
  {return buff.toString();}
}

/**
 * An echo statement.
 * echo anyexpression (, otherexpression)*
 */
void EchoStatement() :
{}
{
  <ECHO> Expression() (<COMMA> Expression())*
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    if (e.currentToken.next.kind != 4) {
      errorMessage = "';' expected after 'echo' statement";
      errorLevel   = ERROR;
      errorStart   = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
      errorEnd     = jj_input_stream.getPosition() + 1;
      throw e;
    }
  }
}

void GlobalStatement() :
{
   final int pos = jj_input_stream.getPosition();
   String expr;
}
{
  <GLOBAL>
    expr = VariableDeclaratorId()
    {if (currentSegment != null) {
      currentSegment.add(new PHPGlobalDeclaration(currentSegment, "global",pos,expr));
    }}
  (<COMMA>
    expr = VariableDeclaratorId()
    {if (currentSegment != null) {
      currentSegment.add(new PHPGlobalDeclaration(currentSegment, "global",pos,expr));
    }}
  )*
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. a ';' was expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void StaticStatement() :
{}
{
  <STATIC> VariableDeclarator() (<COMMA> VariableDeclarator())*
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. a ';' was expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void LabeledStatement() :
{}
{
  <IDENTIFIER> <COLON> Statement()
}

void Block() :
{}
{
  try {
    <LBRACE>
  } catch (ParseException e) {
    errorMessage = "'{' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  ( BlockStatement() | htmlBlock())*
  try {
    <RBRACE>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.image +"', '}' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void BlockStatement() :
{}
{
  Statement()
| ClassDeclaration()
| MethodDeclaration()
}

/**
 * A Block statement that will not contain any 'break'
 */
void BlockStatementNoBreak() :
{}
{
  StatementNoBreak()
| ClassDeclaration()
| MethodDeclaration()
}

void LocalVariableDeclaration() :
{}
{
  LocalVariableDeclarator() ( <COMMA> LocalVariableDeclarator() )*
}

void LocalVariableDeclarator() :
{}
{
  VariableDeclaratorId() [ <ASSIGN> Expression() ]
}

void EmptyStatement() :
{}
{
  <SEMICOLON>
}

void StatementExpression() :
{}
{
  PreIncDecExpression()
|
  PrimaryExpression()
  [ <INCR>
  | <DECR>
  | AssignmentOperator() Expression() ]
}

void SwitchStatement() :
{
  final int pos = jj_input_stream.getPosition();
}
{
  <SWITCH>
  try {
    <LPAREN>
  } catch (ParseException e) {
    errorMessage = "'(' expected after 'switch'";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    Expression()
  } catch (ParseException e) {
    if (errorMessage != null) {
      throw e;
    }
    errorMessage = "expression expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    <RPAREN>
  } catch (ParseException e) {
    errorMessage = "')' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  (switchStatementBrace() | switchStatementColon(pos, pos + 6))
}

void switchStatementBrace() :
{}
{
  <LBRACE>
 ( switchLabel0() )*
  try {
    <RBRACE>
  } catch (ParseException e) {
    errorMessage = "'}' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}
/**
 * A Switch statement with : ... endswitch;
 * @param start the begin offset of the switch
 * @param end the end offset of the switch
 */
void switchStatementColon(final int start, final int end) :
{}
{
  <COLON>
  {try {
  setMarker(fileToParse,
            "Ugly syntax detected, you should switch () {...} instead of switch (): ... enswitch;",
            start,
            end,
            INFO,
            "Line " + token.beginLine);
  } catch (CoreException e) {
    PHPeclipsePlugin.log(e);
  }}
  (switchLabel0())*
  try {
    <ENDSWITCH>
  } catch (ParseException e) {
    errorMessage = "'endswitch' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "';' expected after 'endswitch' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void switchLabel0() :
{
  Token breakToken = null;
  final int line;
}
{
  line = SwitchLabel()
  ( BlockStatementNoBreak() | htmlBlock() )*
  [ breakToken = BreakStatement() ]
  {
    try {
      if (breakToken == null) {
        setMarker(fileToParse,
                  "You should use put a 'break' at the end of your statement",
                  line,
                  INFO,
                  "Line " + line);
      }
    } catch (CoreException e) {
      PHPeclipsePlugin.log(e);
    }
  }
}

Token BreakStatement() :
{
  final Token token;
}
{
  token = <BREAK> [ Expression() ]
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "';' expected after 'break' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {return token;}
}

int SwitchLabel() :
{
  final Token token;
}
{
  token = <CASE>
  try {
    Expression()
  } catch (ParseException e) {
    if (errorMessage != null) throw e;
    errorMessage = "expression expected after 'case' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    <COLON>
  } catch (ParseException e) {
    errorMessage = "':' expected after case expression";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {return token.beginLine;}
|
  token = <_DEFAULT>
  try {
    <COLON>
  } catch (ParseException e) {
    errorMessage = "':' expected after 'default' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  {return token.beginLine;}
}

void IfStatement() :
{
  final Token token;
  final int pos = jj_input_stream.getPosition();
}
{
  token = <IF> Condition("if") IfStatement0(pos,pos+token.image.length())
}

void Condition(final String keyword) :
{}
{
  try {
    <LPAREN>
  } catch (ParseException e) {
    errorMessage = "'(' expected after " + keyword + " keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length();
    errorEnd   = errorStart +1;
    processParseException(e);
  }
  Expression()
  try {
     <RPAREN>
  } catch (ParseException e) {
    errorMessage = "')' expected after " + keyword + " keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void IfStatement0(final int start,final int end) :
{}
{
  <COLON> (Statement() | htmlBlock())* (ElseIfStatementColon())* [ElseStatementColon()]

  {try {
  setMarker(fileToParse,
            "Ugly syntax detected, you should if () {...} instead of if (): ... endif;",
            start,
            end,
            INFO,
            "Line " + token.beginLine);
  } catch (CoreException e) {
    PHPeclipsePlugin.log(e);
  }}
  try {
    <ENDIF>
  } catch (ParseException e) {
    errorMessage = "'endif' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "';' expected after 'endif' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
|
  (Statement() |  htmlBlock())
  ( LOOKAHEAD(1) ElseIfStatement() )*
  [ LOOKAHEAD(1)
    <ELSE>
    try {
      Statement()
    } catch (ParseException e) {
      if (errorMessage != null) {
        throw e;
      }
      errorMessage = "unexpected token '"+e.currentToken.next.image+"', a statement was expected";
      errorLevel   = ERROR;
      errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
      errorEnd   = jj_input_stream.getPosition() + 1;
      throw e;
    }
  ]
}

void ElseIfStatementColon() :
{}
{
  <ELSEIF> Condition("elseif") <COLON> (Statement() | htmlBlock())*
}

void ElseStatementColon() :
{}
{
  <ELSE> <COLON> (Statement() | htmlBlock())*
}

void ElseIfStatement() :
{}
{
  <ELSEIF> Condition("elseif") Statement()
}

void WhileStatement() :
{
  final Token token;
  final int pos = jj_input_stream.getPosition();
}
{
  token = <WHILE> Condition("while") WhileStatement0(pos,pos + token.image.length())
}

void WhileStatement0(final int start, final int end) :
{}
{
  <COLON> (Statement())*
  {try {
  setMarker(fileToParse,
            "Ugly syntax detected, you should while () {...} instead of while (): ... endwhile;",
            start,
            end,
            INFO,
            "Line " + token.beginLine);
  } catch (CoreException e) {
    PHPeclipsePlugin.log(e);
  }}
  try {
    <ENDWHILE>
  } catch (ParseException e) {
    errorMessage = "'endwhile' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "';' expected after 'endwhile' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
|
  Statement()
}

void DoStatement() :
{}
{
  <DO> Statement() <WHILE> Condition("while")
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void ForeachStatement() :
{}
{
  <FOREACH>
    try {
    <LPAREN>
  } catch (ParseException e) {
    errorMessage = "'(' expected after 'foreach' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    Variable()
  } catch (ParseException e) {
    errorMessage = "variable expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  ( VariableSuffix() )*
  try {
    <AS>
  } catch (ParseException e) {
    errorMessage = "'as' expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    Variable()
  } catch (ParseException e) {
    errorMessage = "variable expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  [ <ARRAYASSIGN> Expression() ]
  try {
    <RPAREN>
  } catch (ParseException e) {
    errorMessage = "')' expected after 'foreach' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
  try {
    Statement()
  } catch (ParseException e) {
    if (errorMessage != null) throw e;
    errorMessage = "statement expected";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void ForStatement() :
{
final Token token;
final int pos = jj_input_stream.getPosition();
}
{
  token = <FOR>
  try {
    <LPAREN>
  } catch (ParseException e) {
    errorMessage = "'(' expected after 'for' keyword";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
     [ ForInit() ] <SEMICOLON> [ Expression() ] <SEMICOLON> [ StatementExpressionList() ] <RPAREN>
    (
      Statement()
    |
      <COLON> (Statement())*
      {
        try {
        setMarker(fileToParse,
                  "Ugly syntax detected, you should for () {...} instead of for (): ... endfor;",
                  pos,
                  pos+token.image.length(),
                  INFO,
                  "Line " + token.beginLine);
        } catch (CoreException e) {
          PHPeclipsePlugin.log(e);
        }
      }
      try {
        <ENDFOR>
      } catch (ParseException e) {
        errorMessage = "'endfor' expected";
        errorLevel   = ERROR;
        errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
        errorEnd   = jj_input_stream.getPosition() + 1;
        throw e;
      }
      try {
        <SEMICOLON>
      } catch (ParseException e) {
        errorMessage = "';' expected after 'endfor' keyword";
        errorLevel   = ERROR;
        errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
        errorEnd   = jj_input_stream.getPosition() + 1;
        throw e;
      }
    )
}

void ForInit() :
{}
{
  LOOKAHEAD(LocalVariableDeclaration())
  LocalVariableDeclaration()
|
  StatementExpressionList()
}

void StatementExpressionList() :
{}
{
  StatementExpression() ( <COMMA> StatementExpression() )*
}

void ContinueStatement() :
{}
{
  <CONTINUE> [ Expression() ]
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "';' expected after 'continue' statement";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}

void ReturnStatement() :
{}
{
  <RETURN> [ Expression() ]
  try {
    <SEMICOLON>
  } catch (ParseException e) {
    errorMessage = "';' expected after 'return' statement";
    errorLevel   = ERROR;
    errorStart = jj_input_stream.getPosition() - e.currentToken.next.image.length() + 1;
    errorEnd   = jj_input_stream.getPosition() + 1;
    throw e;
  }
}