+++ /dev/null
-options {
- LOOKAHEAD = 1;
- CHOICE_AMBIGUITY_CHECK = 2;
- OTHER_AMBIGUITY_CHECK = 1;
- STATIC = true;
- DEBUG_PARSER = false;
- DEBUG_LOOKAHEAD = false;
- DEBUG_TOKEN_MANAGER = false;
- OPTIMIZE_TOKEN_MANAGER = false;
- ERROR_REPORTING = true;
- JAVA_UNICODE_ESCAPE = false;
- UNICODE_INPUT = false;
- IGNORE_CASE = true;
- USER_TOKEN_MANAGER = false;
- USER_CHAR_STREAM = false;
- BUILD_PARSER = true;
- BUILD_TOKEN_MANAGER = true;
- SANITY_CHECK = true;
- FORCE_LA_CHECK = false;
-}
-
-PARSER_BEGIN(PHPParser)
-package test;
-
-import org.eclipse.core.resources.IFile;
-import org.eclipse.core.resources.IMarker;
-import org.eclipse.core.runtime.CoreException;
-import org.eclipse.ui.texteditor.MarkerUtilities;
-import org.eclipse.jface.preference.IPreferenceStore;
-
-import java.util.Hashtable;
-import java.io.StringReader;
-import java.text.MessageFormat;
-
-import net.sourceforge.phpeclipse.actions.PHPStartApacheAction;
-import net.sourceforge.phpeclipse.PHPeclipsePlugin;
-import net.sourceforge.phpdt.internal.compiler.parser.PHPOutlineInfo;
-
-/**
- * A new php parser.
- * This php parser is inspired by the Java 1.2 grammar example
- * given with JavaCC. You can get JavaCC at http://www.webgain.com
- * You can test the parser with the PHPParserTestCase2.java
- * @author Matthieu Casanova
- */
-public class PHPParser extends PHPParserSuperclass {
-
- private static PHPParser me;
-
- private static IFile fileToParse;
-
- private static final String PARSE_ERROR_STRING = "Parse error"; //$NON-NLS-1$
- private static final String PARSE_WARNING_STRING = "Warning"; //$NON-NLS-1$
- public static final int ERROR = 2;
- public static final int WARNING = 1;
- public static final int INFO = 0;
- PHPOutlineInfo outlineInfo;
- private static int errorLevel = ERROR;
- private static String errorMessage;
-
- public PHPParser() {
- }
-
- public static PHPParser getInstance(IFile fileToParse) {
- if (me == null) {
- me = new PHPParser(fileToParse);
- } else {
- me.setFileToParse(fileToParse);
- }
- return me;
- }
-
- public void setFileToParse(IFile fileToParse) {
- this.fileToParse = fileToParse;
- }
-
- public static PHPParser getInstance(java.io.Reader stream) {
- if (me == null) {
- me = new PHPParser(stream);
- } else {
- me.ReInit(stream);
- }
- return me;
- }
-
- public PHPParser(IFile fileToParse) {
- this(new StringReader(""));
- this.fileToParse = fileToParse;
- }
-
- public void phpParserTester(String strEval) throws CoreException, ParseException {
- PHPParserTokenManager.SwitchTo(PHPParserTokenManager.PHPPARSING);
- StringReader stream = new StringReader(strEval);
- if (jj_input_stream == null) {
- jj_input_stream = new SimpleCharStream(stream, 1, 1);
- }
- ReInit(new StringReader(strEval));
- phpTest();
- }
-
- public void htmlParserTester(String strEval) throws CoreException, ParseException {
- StringReader stream = new StringReader(strEval);
- if (jj_input_stream == null) {
- jj_input_stream = new SimpleCharStream(stream, 1, 1);
- }
- ReInit(stream);
- phpFile();
- }
-
- public PHPOutlineInfo parseInfo(Object parent, String s) {
- outlineInfo = new PHPOutlineInfo(parent);
- StringReader stream = new StringReader(s);
- if (jj_input_stream == null) {
- jj_input_stream = new SimpleCharStream(stream, 1, 1);
- }
- ReInit(stream);
- try {
- parse();
- } catch (ParseException e) {
- if (errorMessage == null) {
- PHPeclipsePlugin.log(e);
- } else {
- setMarker(errorMessage, e.currentToken.beginLine, errorLevel);
- errorMessage = null;
- }
- }
- return outlineInfo;
- }
-
-
- /**
- * Create marker for the parse error
- */
- private static void setMarker(String message, int lineNumber, int errorLevel) {
- try {
- setMarker(fileToParse, message, lineNumber, errorLevel);
- } catch (CoreException e) {
- PHPeclipsePlugin.log(e);
- }
- }
-
- public static void setMarker(IFile file, String message, int lineNumber, int errorLevel) throws CoreException {
- if (file != null) {
- Hashtable attributes = new Hashtable();
- MarkerUtilities.setMessage(attributes, message);
- switch (errorLevel) {
- case ERROR :
- attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_ERROR));
- break;
- case WARNING :
- attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_WARNING));
- break;
- case INFO :
- attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_INFO));
- break;
- }
- MarkerUtilities.setLineNumber(attributes, lineNumber);
- MarkerUtilities.createMarker(file, attributes, IMarker.PROBLEM);
- }
- }
-
- /**
- * Create markers according to the external parser output
- */
- private static void createMarkers(String output, IFile file) throws CoreException {
- // delete all markers
- file.deleteMarkers(IMarker.PROBLEM, false, 0);
-
- int indx = 0;
- int brIndx = 0;
- boolean flag = true;
- while ((brIndx = output.indexOf("<br />", indx)) != -1) {
- // newer php error output (tested with 4.2.3)
- scanLine(output, file, indx, brIndx);
- indx = brIndx + 6;
- flag = false;
- }
- if (flag) {
- while ((brIndx = output.indexOf("<br>", indx)) != -1) {
- // older php error output (tested with 4.2.3)
- scanLine(output, file, indx, brIndx);
- indx = brIndx + 4;
- }
- }
- }
-
- private static void scanLine(String output, IFile file, int indx, int brIndx) throws CoreException {
- String current;
- StringBuffer lineNumberBuffer = new StringBuffer(10);
- char ch;
- current = output.substring(indx, brIndx);
-
- if (current.indexOf(PARSE_WARNING_STRING) != -1 || current.indexOf(PARSE_ERROR_STRING) != -1) {
- int onLine = current.indexOf("on line <b>");
- if (onLine != -1) {
- lineNumberBuffer.delete(0, lineNumberBuffer.length());
- for (int i = onLine; i < current.length(); i++) {
- ch = current.charAt(i);
- if ('0' <= ch && '9' >= ch) {
- lineNumberBuffer.append(ch);
- }
- }
-
- int lineNumber = Integer.parseInt(lineNumberBuffer.toString());
-
- Hashtable attributes = new Hashtable();
-
- current = current.replaceAll("\n", "");
- current = current.replaceAll("<b>", "");
- current = current.replaceAll("</b>", "");
- MarkerUtilities.setMessage(attributes, current);
-
- if (current.indexOf(PARSE_ERROR_STRING) != -1)
- attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_ERROR));
- else if (current.indexOf(PARSE_WARNING_STRING) != -1)
- attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_WARNING));
- else
- attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_INFO));
- MarkerUtilities.setLineNumber(attributes, lineNumber);
- MarkerUtilities.createMarker(file, attributes, IMarker.PROBLEM);
- }
- }
- }
-
- public void parse(String s) throws CoreException {
- ReInit(new StringReader(s));
- try {
- parse();
- } catch (ParseException e) {
- PHPeclipsePlugin.log(e);
- }
- }
-
- /**
- * Call the php parse command ( php -l -f <filename> )
- * and create markers according to the external parser output
- */
- public static void phpExternalParse(IFile file) {
- IPreferenceStore store = PHPeclipsePlugin.getDefault().getPreferenceStore();
- String filename = file.getLocation().toString();
-
- String[] arguments = { filename };
- MessageFormat form = new MessageFormat(store.getString(PHPeclipsePlugin.EXTERNAL_PARSER_PREF));
- String command = form.format(arguments);
-
- String parserResult = PHPStartApacheAction.getParserOutput(command, "External parser: ");
-
- try {
- // parse the buffer to find the errors and warnings
- createMarkers(parserResult, file);
- } catch (CoreException e) {
- PHPeclipsePlugin.log(e);
- }
- }
-
- public void parse() throws ParseException {
- phpFile();
- }
-}
-
-PARSER_END(PHPParser)
-
-<DEFAULT> TOKEN :
-{
- <PHPSTART : "<?php" | "<?"> : PHPPARSING
-}
-
-<PHPPARSING> TOKEN :
-{
- <PHPEND :"?>"> : DEFAULT
-}
-
-<DEFAULT> SKIP :
-{
- < ~[] >
-}
-
-
-/* WHITE SPACE */
-
-<PHPPARSING> SKIP :
-{
- " "
-| "\t"
-| "\n"
-| "\r"
-| "\f"
-}
-
-/* COMMENTS */
-
-<PHPPARSING> MORE :
-{
- "//" : IN_SINGLE_LINE_COMMENT
-|
- <"/**" ~["/"]> { input_stream.backup(1); } : IN_FORMAL_COMMENT
-|
- "/*" : IN_MULTI_LINE_COMMENT
-}
-
-<IN_SINGLE_LINE_COMMENT>
-SPECIAL_TOKEN :
-{
- <SINGLE_LINE_COMMENT: "\n" | "\r" | "\r\n" | "?>" > : PHPPARSING
-}
-
-<IN_FORMAL_COMMENT>
-SPECIAL_TOKEN :
-{
- <FORMAL_COMMENT: "*/" > : PHPPARSING
-}
-
-<IN_MULTI_LINE_COMMENT>
-SPECIAL_TOKEN :
-{
- <MULTI_LINE_COMMENT: "*/" > : PHPPARSING
-}
-
-<IN_SINGLE_LINE_COMMENT,IN_FORMAL_COMMENT,IN_MULTI_LINE_COMMENT>
-MORE :
-{
- < ~[] >
-}
-
-/* KEYWORDS */
-<PHPPARSING> TOKEN :
-{
- <CLASS : "class">
-| <FUNCTION : "function">
-| <VAR : "var">
-| <IF : "if">
-| <ELSEIF : "elseif">
-| <ELSE : "else">
-| <ARRAY : "array">
-}
-
-/* LANGUAGE CONSTRUCT */
-<PHPPARSING> TOKEN :
-{
- <PRINT : "print">
-| <ECHO : "echo">
-| <INCLUDE : "include">
-| <REQUIRE : "require">
-| <INCLUDE_ONCE : "include_once">
-| <REQUIRE_ONCE : "require_once">
-| <GLOBAL : "global">
-| <STATIC : "static">
-| <CLASSACCESS: "->">
-| <STATICCLASSACCESS: "::">
-| <ARRAYASSIGN: "=>">
-}
-
-/* RESERVED WORDS AND LITERALS */
-
-<PHPPARSING> TOKEN :
-{
- < BREAK: "break" >
-| < CASE: "case" >
-| < CONST: "const" >
-| < CONTINUE: "continue" >
-| < _DEFAULT: "default" >
-| < DO: "do" >
-| < EXTENDS: "extends" >
-| < FALSE: "false" >
-| < FOR: "for" >
-| < GOTO: "goto" >
-| < NEW: "new" >
-| < NULL: "null" >
-| < RETURN: "return" >
-| < SUPER: "super" >
-| < SWITCH: "switch" >
-| < THIS: "this" >
-| < TRUE: "true" >
-| < WHILE: "while" >
-| < ENDWHILE : "endwhile" >
-}
-
-/* TYPES */
-
-<PHPPARSING> TOKEN :
-{
- <STRING : "string">
-| <OBJECT : "object">
-| <BOOL : "bool">
-| <BOOLEAN : "boolean">
-| <REAL : "real">
-| <DOUBLE : "double">
-| <FLOAT : "float">
-| <INT : "int">
-| <INTEGER : "integer">
-}
-
-<PHPPARSING> TOKEN :
-{
- < _ORL : "OR" >
-| < _ANDL: "AND">
-}
-
-/* LITERALS */
-
-<PHPPARSING> TOKEN :
-{
- < INTEGER_LITERAL:
- <DECIMAL_LITERAL> (["l","L"])?
- | <HEX_LITERAL> (["l","L"])?
- | <OCTAL_LITERAL> (["l","L"])?
- >
-|
- < #DECIMAL_LITERAL: ["1"-"9"] (["0"-"9"])* >
-|
- < #HEX_LITERAL: "0" ["x","X"] (["0"-"9","a"-"f","A"-"F"])+ >
-|
- < #OCTAL_LITERAL: "0" (["0"-"7"])* >
-|
- < FLOATING_POINT_LITERAL:
- (["0"-"9"])+ "." (["0"-"9"])* (<EXPONENT>)? (["f","F","d","D"])?
- | "." (["0"-"9"])+ (<EXPONENT>)? (["f","F","d","D"])?
- | (["0"-"9"])+ <EXPONENT> (["f","F","d","D"])?
- | (["0"-"9"])+ (<EXPONENT>)? ["f","F","d","D"]
- >
-|
- < #EXPONENT: ["e","E"] (["+","-"])? (["0"-"9"])+ >
-|
- < STRING_LITERAL: (<STRING_1> | <STRING_2> | <STRING_3>)>
-| < STRING_1:
- "\""
- ( (~["\""])
- | "\\\""
- )*
- "\""
- >
-| < STRING_2:
- "'"
- ( (~["'"]))*
-
- "'"
- >
-| < STRING_3:
- "`"
- ( (~["`"]))*
- "`"
- >
-}
-
-/* IDENTIFIERS */
-
-<PHPPARSING> TOKEN :
-{
- < IDENTIFIER: (<LETTER>|<SPECIAL>) (<LETTER>|<DIGIT>|<SPECIAL>)* >
-|
- < #LETTER:
- ["a"-"z"] | ["A"-"Z"]
- >
-|
- < #DIGIT:
- ["0"-"9"]
- >
-|
- < #SPECIAL:
- "_"
- >
-}
-
-/* SEPARATORS */
-
-<PHPPARSING> TOKEN :
-{
- < LPAREN: "(" >
-| < RPAREN: ")" >
-| < LBRACE: "{" >
-| < RBRACE: "}" >
-| < LBRACKET: "[" >
-| < RBRACKET: "]" >
-| < SEMICOLON: ";" >
-| < COMMA: "," >
-| < DOT: "." >
-}
-
-/* OPERATORS */
-
-<PHPPARSING> TOKEN :
-{
- <AT : "@">
-| <DOLLAR : "$">
-| < ASSIGN: "=" >
-| < GT: ">" >
-| < LT: "<" >
-| < BANG: "!" >
-| < HOOK: "?" >
-| < COLON: ":" >
-| < EQ: "==" >
-| < LE: "<=" >
-| < GE: ">=" >
-| < NE: "!=" >
-| < SC_OR: "||" >
-| < SC_AND: "&&" >
-| < INCR: "++" >
-| < DECR: "--" >
-| < PLUS: "+" >
-| < MINUS: "-" >
-| < STAR: "*" >
-| < SLASH: "/" >
-| < BIT_AND: "&" >
-| < BIT_OR: "|" >
-| < XOR: "^" >
-| < REM: "%" >
-| < LSHIFT: "<<" >
-| < RSIGNEDSHIFT: ">>" >
-| < RUNSIGNEDSHIFT: ">>>" >
-| < PLUSASSIGN: "+=" >
-| < MINUSASSIGN: "-=" >
-| < STARASSIGN: "*=" >
-| < SLASHASSIGN: "/=" >
-| < ANDASSIGN: "&=" >
-| < ORASSIGN: "|=" >
-| < XORASSIGN: "^=" >
-| < DOTASSIGN: ".=" >
-| < REMASSIGN: "%=" >
-| < LSHIFTASSIGN: "<<=" >
-| < RSIGNEDSHIFTASSIGN: ">>=" >
-| < RUNSIGNEDSHIFTASSIGN: ">>>=" >
-}
-
-<PHPPARSING> TOKEN :
-{
- < DOLLAR_ID: <DOLLAR> <IDENTIFIER> >
-}
-
-/*****************************************
- * THE JAVA LANGUAGE GRAMMAR STARTS HERE *
- *****************************************/
-
-/*
- * Program structuring syntax follows.
- */
-
-void phpTest() :
-{}
-{
- Php()
- <EOF>
-}
-
-void phpFile() :
-{}
-{
- (<PHPSTART> Php() <PHPEND>)*
- <EOF>
-}
-
-void Php() :
-{}
-{
- (BlockStatement())*
-}
-
-void ClassDeclaration() :
-{}
-{
- <CLASS> <IDENTIFIER> [ <EXTENDS> <IDENTIFIER> ]
- ClassBody()
-}
-
-void ClassBody() :
-{}
-{
- <LBRACE> ( ClassBodyDeclaration() )* <RBRACE>
-}
-
-void ClassBodyDeclaration() :
-{}
-{
- MethodDeclaration()
-|
- FieldDeclaration()
-}
-
-void FieldDeclaration() :
-{}
-{
- <VAR> VariableDeclarator() ( <COMMA> VariableDeclarator() )* <SEMICOLON>
-}
-
-void VariableDeclarator() :
-{}
-{
- VariableDeclaratorId() [ <ASSIGN> VariableInitializer() ]
-}
-
-void VariableDeclaratorId() :
-{}
-{
- Variable() ( LOOKAHEAD(2) VariableSuffix() )*
-}
-
-void Variable():
-{}
-{
- <DOLLAR_ID> (<LBRACE> Expression() <RBRACE>) *
-|
- <DOLLAR> VariableName()
-}
-
-void VariableName():
-{}
-{
- <LBRACE> Expression() <RBRACE>
-|
- <IDENTIFIER> (<LBRACE> Expression() <RBRACE>) *
-|
- <DOLLAR> VariableName()
-}
-
-void VariableInitializer() :
-{}
-{
- Expression()
-}
-
-void ArrayVariable() :
-{}
-{
- Expression() (<ARRAYASSIGN> Expression())*
-}
-
-void ArrayInitializer() :
-{}
-{
- <LPAREN> [ ArrayVariable() ( LOOKAHEAD(2) <COMMA> ArrayVariable() )* ]<RPAREN>
-}
-
-void MethodDeclaration() :
-{}
-{
- <FUNCTION> MethodDeclarator()
- ( Block() | <SEMICOLON> )
-}
-
-void MethodDeclarator() :
-{}
-{
- [<BIT_AND>] <IDENTIFIER> FormalParameters()
-}
-
-void FormalParameters() :
-{}
-{
- <LPAREN> [ FormalParameter() ( <COMMA> FormalParameter() )* ] <RPAREN>
-}
-
-void FormalParameter() :
-{}
-{
- [<BIT_AND>] VariableDeclarator()
-}
-
-void Type() :
-{}
-{
- <STRING>
-|
- <BOOL>
-|
- <BOOLEAN>
-|
- <REAL>
-|
- <DOUBLE>
-|
- <FLOAT>
-|
- <INT>
-|
- <INTEGER>
-}
-
-/*
- * Expression syntax follows.
- */
-
-void Expression() :
-/*
- * This expansion has been written this way instead of:
- * Assignment() | ConditionalExpression()
- * for performance reasons.
- * However, it is a weakening of the grammar for it allows the LHS of
- * assignments to be any conditional expression whereas it can only be
- * a primary expression. Consider adding a semantic predicate to work
- * around this.
- */
-{}
-{
- PrintExpression()
-|
- ConditionalExpression()
- [
- AssignmentOperator() Expression()
- ]
-}
-
-void AssignmentOperator() :
-{}
-{
- <ASSIGN> | <STARASSIGN> | <SLASHASSIGN> | <REMASSIGN> | <PLUSASSIGN> | <MINUSASSIGN> | <LSHIFTASSIGN> | <RSIGNEDSHIFTASSIGN> | <RUNSIGNEDSHIFTASSIGN> | <ANDASSIGN> | <XORASSIGN> | <ORASSIGN> | <DOTASSIGN>
-}
-
-void ConditionalExpression() :
-{}
-{
- ConditionalOrExpression() [ <HOOK> Expression() <COLON> ConditionalExpression() ]
-}
-
-void ConditionalOrExpression() :
-{}
-{
- ConditionalAndExpression() ( (<SC_OR> | <_ORL>) ConditionalAndExpression() )*
-}
-
-void ConditionalAndExpression() :
-{}
-{
- ConcatExpression() ( (<SC_AND> | <_ANDL>) ConcatExpression() )*
-}
-
-void ConcatExpression() :
-{}
-{
- InclusiveOrExpression() ( <DOT> InclusiveOrExpression() )*
-}
-
-void InclusiveOrExpression() :
-{}
-{
- ExclusiveOrExpression() ( <BIT_OR> ExclusiveOrExpression() )*
-}
-
-void ExclusiveOrExpression() :
-{}
-{
- AndExpression() ( <XOR> AndExpression() )*
-}
-
-void AndExpression() :
-{}
-{
- EqualityExpression() ( <BIT_AND> EqualityExpression() )*
-}
-
-void EqualityExpression() :
-{}
-{
- RelationalExpression() ( ( <EQ> | <NE> ) RelationalExpression() )*
-}
-
-void RelationalExpression() :
-{}
-{
- ShiftExpression() ( ( <LT> | <GT> | <LE> | <GE> ) ShiftExpression() )*
-}
-
-void ShiftExpression() :
-{}
-{
- AdditiveExpression() ( ( <LSHIFT> | <RSIGNEDSHIFT> | <RUNSIGNEDSHIFT> ) AdditiveExpression() )*
-}
-
-void AdditiveExpression() :
-{}
-{
- MultiplicativeExpression() ( ( <PLUS> | <MINUS> ) MultiplicativeExpression() )*
-}
-
-void MultiplicativeExpression() :
-{}
-{
- UnaryExpression() ( ( <STAR> | <SLASH> | <REM> ) UnaryExpression() )*
-}
-
-void UnaryExpression() :
-{}
-{
- <AT> UnaryExpression()
-|
- ( <PLUS> | <MINUS> ) UnaryExpression()
-|
- PreIncrementExpression()
-|
- PreDecrementExpression()
-|
- UnaryExpressionNotPlusMinus()
-}
-
-void PreIncrementExpression() :
-{}
-{
- <INCR> PrimaryExpression()
-}
-
-void PreDecrementExpression() :
-{}
-{
- <DECR> PrimaryExpression()
-}
-
-void UnaryExpressionNotPlusMinus() :
-{}
-{
- <BANG> UnaryExpression()
-|
- LOOKAHEAD( <LPAREN> Type() <RPAREN> )
- CastExpression()
-|
- PostfixExpression()
-|
- Literal()
-|
- <LPAREN>Expression()<RPAREN>
-}
-
-void CastExpression() :
-{}
-{
- <LPAREN> Type() <RPAREN> UnaryExpression()
-}
-
-void PostfixExpression() :
-{}
-{
- PrimaryExpression() [ <INCR> | <DECR> ]
-}
-
-void PrimaryExpression() :
-{}
-{
- LOOKAHEAD(2)
- <IDENTIFIER> <STATICCLASSACCESS> ClassIdentifier() (PrimarySuffix())*
-|
- PrimaryPrefix() ( PrimarySuffix() )*
-|
- <ARRAY> ArrayInitializer()
-}
-
-void PrimaryPrefix() :
-{}
-{
- <IDENTIFIER>
-|
- <NEW> ClassIdentifier()
-|
- VariableDeclaratorId()
-}
-
-void ClassIdentifier():
-{}
-{
- <IDENTIFIER>
-|
- VariableDeclaratorId()
-}
-
-void PrimarySuffix() :
-{}
-{
- Arguments()
-|
- VariableSuffix()
-}
-
-void VariableSuffix() :
-{}
-{
- <CLASSACCESS> VariableName()
-|
- <LBRACKET> [ Expression() ] <RBRACKET>
-}
-
-void Literal() :
-{}
-{
- <INTEGER_LITERAL>
-|
- <FLOATING_POINT_LITERAL>
-|
- <STRING_LITERAL>
-|
- BooleanLiteral()
-|
- NullLiteral()
-}
-
-void BooleanLiteral() :
-{}
-{
- <TRUE>
-|
- <FALSE>
-}
-
-void NullLiteral() :
-{}
-{
- <NULL>
-}
-
-void Arguments() :
-{}
-{
- <LPAREN> [ ArgumentList() ] <RPAREN>
-}
-
-void ArgumentList() :
-{}
-{
- Expression() ( <COMMA> Expression() )*
-}
-
-/*
- * Statement syntax follows.
- */
-
-void Statement() :
-{}
-{
- LOOKAHEAD(2)
- Expression() (<SEMICOLON> | "?>")
-|
- LOOKAHEAD(2)
- LabeledStatement()
-|
- Block()
-|
- EmptyStatement()
-|
- StatementExpression()
- try {
- <SEMICOLON>
- } catch (ParseException e) {
- errorMessage = "';' expected after expression";
- errorLevel = ERROR;
- throw e;
- }
-|
- SwitchStatement()
-|
- IfStatement()
-|
- WhileStatement()
-|
- DoStatement()
-|
- ForStatement()
-|
- BreakStatement()
-|
- ContinueStatement()
-|
- ReturnStatement()
-|
- EchoStatement()
-|
- IncludeStatement()
-|
- StaticStatement()
-|
- GlobalStatement()
-}
-
-void IncludeStatement() :
-{}
-{
- <REQUIRE> Expression() (<SEMICOLON> | "?>")
-|
- <REQUIRE_ONCE> Expression() (<SEMICOLON> | "?>")
-|
- <INCLUDE> Expression() (<SEMICOLON> | "?>")
-|
- <INCLUDE_ONCE> Expression() (<SEMICOLON> | "?>")
-}
-
-void PrintExpression() :
-{}
-{
- <PRINT> Expression()
-}
-
-void EchoStatement() :
-{}
-{
- <ECHO> Expression() (<COMMA> Expression())*
- try {
- (<SEMICOLON> | "?>")
- } catch (ParseException e) {
- errorMessage = "';' expected after 'echo' statement";
- errorLevel = ERROR;
- throw e;
- }
-}
-
-void GlobalStatement() :
-{}
-{
- <GLOBAL> VariableDeclaratorId() (<COMMA> VariableDeclaratorId())* (<SEMICOLON> | "?>")
-}
-
-void StaticStatement() :
-{}
-{
- <STATIC> VariableDeclarator() (<COMMA> VariableDeclarator())* (<SEMICOLON> | "?>")
-}
-
-void LabeledStatement() :
-{}
-{
- <IDENTIFIER> <COLON> Statement()
-}
-
-void Block() :
-{}
-{
- <LBRACE> ( BlockStatement() )* <RBRACE>
-}
-
-void BlockStatement() :
-{}
-{
- Statement()
-|
- ClassDeclaration()
-|
- MethodDeclaration()
-}
-
-void LocalVariableDeclaration() :
-{}
-{
- VariableDeclarator() ( <COMMA> VariableDeclarator() )*
-}
-
-void EmptyStatement() :
-{}
-{
- <SEMICOLON>
-}
-
-void StatementExpression() :
-/*
- * The last expansion of this production accepts more than the legal
- * Java expansions for StatementExpression. This expansion does not
- * use PostfixExpression for performance reasons.
- */
-{}
-{
- PreIncrementExpression()
-|
- PreDecrementExpression()
-|
- PrimaryExpression()
- [
- <INCR>
- |
- <DECR>
- |
- AssignmentOperator() Expression()
- ]
-}
-
-void SwitchStatement() :
-{}
-{
- <SWITCH> <LPAREN> Expression() <RPAREN> <LBRACE>
- ( SwitchLabel() ( BlockStatement() )* )*
- <RBRACE>
-}
-
-void SwitchLabel() :
-{}
-{
- <CASE> Expression() <COLON>
-|
- <_DEFAULT> <COLON>
-}
-
-void IfStatement() :
-/*
- * The disambiguating algorithm of JavaCC automatically binds dangling
- * else's to the innermost if statement. The LOOKAHEAD specification
- * is to tell JavaCC that we know what we are doing.
- */
-{}
-{
- <IF> Condition("if") Statement() [ LOOKAHEAD(1) ElseIfStatement() ] [ LOOKAHEAD(1) <ELSE> Statement() ]
-}
-
-void Condition(String keyword) :
-{}
-{
- try {
- <LPAREN>
- } catch (ParseException e) {
- errorMessage = "'(' expected after " + keyword + " keyword";
- errorLevel = ERROR;
- throw e;
- }
- Expression()
- try {
- <RPAREN>
- } catch (ParseException e) {
- errorMessage = "')' expected after " + keyword + " keyword";
- errorLevel = ERROR;
- throw e;
- }
-}
-
-void ElseIfStatement() :
-{}
-{
- <ELSEIF> Condition("elseif") Statement()
-}
-
-void WhileStatement() :
-{}
-{
- <WHILE> Condition("while") WhileStatement0()
-}
-
-void WhileStatement0() :
-{}
-{
- <COLON> (Statement())* <ENDWHILE> (<SEMICOLON> | "?>")
-|
- Statement()
-}
-
-void DoStatement() :
-{}
-{
- <DO> Statement() <WHILE> Condition("while") (<SEMICOLON> | "?>")
-}
-
-void ForStatement() :
-{}
-{
- <FOR> <LPAREN> [ ForInit() ] <SEMICOLON> [ Expression() ] <SEMICOLON> [ ForUpdate() ] <RPAREN> Statement()
-}
-
-void ForInit() :
-{}
-{
- LOOKAHEAD(LocalVariableDeclaration())
- LocalVariableDeclaration()
-|
- StatementExpressionList()
-}
-
-void StatementExpressionList() :
-{}
-{
- StatementExpression() ( <COMMA> StatementExpression() )*
-}
-
-void ForUpdate() :
-{}
-{
- StatementExpressionList()
-}
-
-void BreakStatement() :
-{}
-{
- <BREAK> [ <IDENTIFIER> ] <SEMICOLON>
-}
-
-void ContinueStatement() :
-{}
-{
- <CONTINUE> [ <IDENTIFIER> ] <SEMICOLON>
-}
-
-void ReturnStatement() :
-{}
-{
- <RETURN> [ Expression() ] <SEMICOLON>
-}
\ No newline at end of file
git://git.phpeclipse.com / phpeclipse.git / blobdiff