net.sourceforge.phpeclipse/src/test/PHPParser.jj

   1
   2 options {
   3   LOOKAHEAD = 1;
   4   CHOICE_AMBIGUITY_CHECK = 2;
   5   OTHER_AMBIGUITY_CHECK = 1;
   6   STATIC = true;
   7   DEBUG_PARSER = false;
   8   DEBUG_LOOKAHEAD = false;
   9   DEBUG_TOKEN_MANAGER = false;
  10   OPTIMIZE_TOKEN_MANAGER = false;
  11   ERROR_REPORTING = true;
  12   JAVA_UNICODE_ESCAPE = false;
  13   UNICODE_INPUT = false;
  14   IGNORE_CASE = true;
  15   USER_TOKEN_MANAGER = false;
  16   USER_CHAR_STREAM = false;
  17   BUILD_PARSER = true;
  18   BUILD_TOKEN_MANAGER = true;
  19   SANITY_CHECK = true;
  20   FORCE_LA_CHECK = false;
  21   COMMON_TOKEN_ACTION = true;
  22 }
  23
  24 PARSER_BEGIN(PHPParser)
  25 package test;
  26
  27 import org.eclipse.core.resources.IFile;
  28 import org.eclipse.core.resources.IMarker;
  29 import org.eclipse.core.runtime.CoreException;
  30 import org.eclipse.ui.texteditor.MarkerUtilities;
  31 import org.eclipse.jface.preference.IPreferenceStore;
  32
  33 import java.util.Hashtable;
  34 import java.util.ArrayList;
  35 import java.io.StringReader;
  36 import java.io.*;
  37 import java.text.MessageFormat;
  38
  39 import net.sourceforge.phpeclipse.actions.PHPStartApacheAction;
  40 import net.sourceforge.phpeclipse.PHPeclipsePlugin;
  41 import net.sourceforge.phpdt.internal.compiler.ast.*;
  42 import net.sourceforge.phpdt.internal.compiler.parser.OutlineableWithChildren;
  43 import net.sourceforge.phpdt.internal.compiler.parser.Outlineable;
  44 import net.sourceforge.phpdt.internal.compiler.parser.PHPOutlineInfo;
  45 import net.sourceforge.phpdt.internal.corext.Assert;
  46
  47 /**
  48  * A new php parser.
  49  * This php parser is inspired by the Java 1.2 grammar example
  50  * given with JavaCC. You can get JavaCC at http://www.webgain.com
  51  * You can test the parser with the PHPParserTestCase2.java
  52  * @author Matthieu Casanova
  53  */
  54 public final class PHPParser extends PHPParserSuperclass {
  55
  56 //todo : fix the variables names bug
  57 //todo : handle tilde operator
  58
  59
  60   /** The current segment. */
  61   private static OutlineableWithChildren currentSegment;
  62
  63   private static final String PARSE_ERROR_STRING = "Parse error"; //$NON-NLS-1$
  64   private static final String PARSE_WARNING_STRING = "Warning"; //$NON-NLS-1$
  65   static PHPOutlineInfo outlineInfo;
  66
  67   /** The error level of the current ParseException. */
  68   private static int errorLevel = ERROR;
  69   /** The message of the current ParseException. If it's null it's because the parse exception wasn't handled */
  70   private static String errorMessage;
  71
  72   private static int errorStart = -1;
  73   private static int errorEnd = -1;
  74   private static PHPDocument phpDocument;
  75
  76   private static final String SYNTAX_ERROR_CHAR = "syntax error";
  77   /**
  78    * The point where html starts.
  79    * It will be used by the token manager to create HTMLCode objects
  80    */
  81   public static int htmlStart;
  82
  83   //ast stack
  84   private final static int AstStackIncrement = 100;
  85   /** The stack of node. */
  86   private static AstNode[] nodes;
  87   /** The cursor in expression stack. */
  88   private static int nodePtr;
  89
  90   public static final boolean PARSER_DEBUG = false;
  91
  92   public final void setFileToParse(final IFile fileToParse) {
  93     PHPParser.fileToParse = fileToParse;
  94   }
  95
  96   public PHPParser() {
  97   }
  98
  99   public PHPParser(final IFile fileToParse) {
 100     this(new StringReader(""));
 101     PHPParser.fileToParse = fileToParse;
 102   }
 103
 104   public static final void phpParserTester(final String strEval) throws ParseException {
 105     final StringReader stream = new StringReader(strEval);
 106     if (jj_input_stream == null) {
 107       jj_input_stream = new SimpleCharStream(stream, 1, 1);
 108     }
 109     ReInit(new StringReader(strEval));
 110     init();
 111     phpDocument = new PHPDocument(null,"_root".toCharArray());
 112     currentSegment = phpDocument;
 113     outlineInfo = new PHPOutlineInfo(null, currentSegment);
 114     PHPParserTokenManager.SwitchTo(PHPParserTokenManager.PHPPARSING);
 115     phpTest();
 116   }
 117
 118   public static final void htmlParserTester(final File fileName) throws FileNotFoundException, ParseException {
 119     final Reader stream = new FileReader(fileName);
 120     if (jj_input_stream == null) {
 121       jj_input_stream = new SimpleCharStream(stream, 1, 1);
 122     }
 123     ReInit(stream);
 124     init();
 125     phpDocument = new PHPDocument(null,"_root".toCharArray());
 126     currentSegment = phpDocument;
 127     outlineInfo = new PHPOutlineInfo(null, currentSegment);
 128     phpFile();
 129   }
 130
 131   public static final void htmlParserTester(final String strEval) throws ParseException {
 132     final StringReader stream = new StringReader(strEval);
 133     if (jj_input_stream == null) {
 134       jj_input_stream = new SimpleCharStream(stream, 1, 1);
 135     }
 136     ReInit(stream);
 137     init();
 138     phpDocument = new PHPDocument(null,"_root".toCharArray());
 139     currentSegment = phpDocument;
 140     outlineInfo = new PHPOutlineInfo(null, currentSegment);
 141     phpFile();
 142   }
 143
 144   /**
 145    * Reinitialize the parser.
 146    */
 147   private static final void init() {
 148     nodes = new AstNode[AstStackIncrement];
 149     nodePtr = -1;
 150     htmlStart = 0;
 151   }
 152
 153   /**
 154    * Add an php node on the stack.
 155    * @param node the node that will be added to the stack
 156    */
 157   private static final void pushOnAstNodes(final AstNode node) {
 158     try {
 159       nodes[++nodePtr] = node;
 160     } catch (IndexOutOfBoundsException e) {
 161       final int oldStackLength = nodes.length;
 162       final AstNode[] oldStack = nodes;
 163       nodes = new AstNode[oldStackLength + AstStackIncrement];
 164       System.arraycopy(oldStack, 0, nodes, 0, oldStackLength);
 165       nodePtr = oldStackLength;
 166       nodes[nodePtr] = node;
 167     }
 168   }
 169
 170   public final PHPOutlineInfo parseInfo(final Object parent, final String s) {
 171     phpDocument = new PHPDocument(parent,"_root".toCharArray());
 172     currentSegment = phpDocument;
 173     outlineInfo = new PHPOutlineInfo(parent, currentSegment);
 174     final StringReader stream = new StringReader(s);
 175     if (jj_input_stream == null) {
 176       jj_input_stream = new SimpleCharStream(stream, 1, 1);
 177     }
 178     ReInit(stream);
 179     init();
 180     try {
 181       parse();
 182       phpDocument.nodes = new AstNode[nodes.length];
 183       System.arraycopy(nodes,0,phpDocument.nodes,0,nodes.length);
 184       if (PHPeclipsePlugin.DEBUG) {
 185         PHPeclipsePlugin.log(1,phpDocument.toString());
 186       }
 187     } catch (ParseException e) {
 188       processParseException(e);
 189     }
 190     return outlineInfo;
 191   }
 192
 193   /**
 194    * This function will throw the exception if we are in debug mode
 195    * and process it if we are in production mode.
 196    * this should be fast since the PARSER_DEBUG is static final so the difference will be at compile time
 197    * @param e the exception
 198    * @throws ParseException the thrown exception
 199    */
 200   private static void processParseExceptionDebug(final ParseException e) throws ParseException {
 201     if (PARSER_DEBUG) {
 202       throw e;
 203     }
 204     processParseException(e);
 205   }
 206   /**
 207    * This method will process the parse exception.
 208    * If the error message is null, the parse exception wasn't catched and a trace is written in the log
 209    * @param e the ParseException
 210    */
 211   private static void processParseException(final ParseException e) {
 212     if (errorMessage == null) {
 213       PHPeclipsePlugin.log(e);
 214       errorMessage = "this exception wasn't handled by the parser please tell us how to reproduce it";
 215       errorStart = e.currentToken.sourceStart;
 216       errorEnd   = e.currentToken.sourceEnd;
 217     }
 218     setMarker(e);
 219     errorMessage = null;
 220   //  if (PHPeclipsePlugin.DEBUG) PHPeclipsePlugin.log(e);
 221   }
 222
 223   /**
 224    * Create marker for the parse error.
 225    * @param e the ParseException
 226    */
 227   private static void setMarker(final ParseException e) {
 228     try {
 229       if (errorStart == -1) {
 230         setMarker(fileToParse,
 231                   errorMessage,
 232                   e.currentToken.sourceStart,
 233                   e.currentToken.sourceEnd,
 234                   errorLevel,
 235                   "Line " + e.currentToken.beginLine+", "+e.currentToken.sourceStart+":"+e.currentToken.sourceEnd);
 236       } else {
 237         setMarker(fileToParse,
 238                   errorMessage,
 239                   errorStart,
 240                   errorEnd,
 241                   errorLevel,
 242                   "Line " + e.currentToken.beginLine+", "+errorStart+":"+errorEnd);
 243         errorStart = -1;
 244         errorEnd = -1;
 245       }
 246     } catch (CoreException e2) {
 247       PHPeclipsePlugin.log(e2);
 248     }
 249   }
 250
 251   private static void scanLine(final String output,
 252                                final IFile file,
 253                                final int indx,
 254                                final int brIndx) throws CoreException {
 255     String current;
 256     final StringBuffer lineNumberBuffer = new StringBuffer(10);
 257     char ch;
 258     current = output.substring(indx, brIndx);
 259
 260     if (current.indexOf(PARSE_WARNING_STRING) != -1 || current.indexOf(PARSE_ERROR_STRING) != -1) {
 261       final int onLine = current.indexOf("on line <b>");
 262       if (onLine != -1) {
 263         lineNumberBuffer.delete(0, lineNumberBuffer.length());
 264         for (int i = onLine; i < current.length(); i++) {
 265           ch = current.charAt(i);
 266           if ('0' <= ch && '9' >= ch) {
 267             lineNumberBuffer.append(ch);
 268           }
 269         }
 270
 271         final int lineNumber = Integer.parseInt(lineNumberBuffer.toString());
 272
 273         final Hashtable attributes = new Hashtable();
 274
 275         current = current.replaceAll("\n", "");
 276         current = current.replaceAll("<b>", "");
 277         current = current.replaceAll("</b>", "");
 278         MarkerUtilities.setMessage(attributes, current);
 279
 280         if (current.indexOf(PARSE_ERROR_STRING) != -1)
 281           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_ERROR));
 282         else if (current.indexOf(PARSE_WARNING_STRING) != -1)
 283           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_WARNING));
 284         else
 285           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_INFO));
 286         MarkerUtilities.setLineNumber(attributes, lineNumber);
 287         MarkerUtilities.createMarker(file, attributes, IMarker.PROBLEM);
 288       }
 289     }
 290   }
 291
 292   public final void parse(final String s) {
 293     final StringReader stream = new StringReader(s);
 294     if (jj_input_stream == null) {
 295       jj_input_stream = new SimpleCharStream(stream, 1, 1);
 296     }
 297     ReInit(stream);
 298     init();
 299     try {
 300       parse();
 301     } catch (ParseException e) {
 302       processParseException(e);
 303     }
 304   }
 305
 306   /**
 307    * Call the php parse command ( php -l -f &lt;filename&gt; )
 308    * and create markers according to the external parser output
 309    */
 310   public static void phpExternalParse(final IFile file) {
 311     final IPreferenceStore store = PHPeclipsePlugin.getDefault().getPreferenceStore();
 312     final String filename = file.getLocation().toString();
 313
 314     final String[] arguments = { filename };
 315     final MessageFormat form = new MessageFormat(store.getString(PHPeclipsePlugin.EXTERNAL_PARSER_PREF));
 316     final String command = form.format(arguments);
 317
 318     final String parserResult = PHPStartApacheAction.getParserOutput(command, "External parser: ");
 319
 320     try {
 321       // parse the buffer to find the errors and warnings
 322       createMarkers(parserResult, file);
 323     } catch (CoreException e) {
 324       PHPeclipsePlugin.log(e);
 325     }
 326   }
 327
 328   /**
 329    * Put a new html block in the stack.
 330    */
 331   public static final void createNewHTMLCode() {
 332     final int currentPosition = token.sourceStart;
 333     if (currentPosition == htmlStart ||
 334           currentPosition < htmlStart ||
 335           currentPosition > SimpleCharStream.currentBuffer.length()) {
 336       return;
 337     }
 338     final char[] chars = SimpleCharStream.currentBuffer.substring(htmlStart,
 339                                                                   currentPosition).toCharArray();
 340     pushOnAstNodes(new HTMLCode(chars, htmlStart,currentPosition));
 341   }
 342
 343   /** Create a new task. */
 344   public static final void createNewTask(final int todoStart) {
 345     final String  todo = SimpleCharStream.currentBuffer.substring(todoStart,
 346                                                                   SimpleCharStream.currentBuffer.indexOf("\n",
 347                                                                                                          todoStart)-1);
 348     if (!PARSER_DEBUG) {
 349       try {
 350         setMarker(fileToParse,
 351                   todo,
 352                   SimpleCharStream.getBeginLine(),
 353                   TASK,
 354                   "Line "+SimpleCharStream.getBeginLine());
 355       } catch (CoreException e) {
 356         PHPeclipsePlugin.log(e);
 357       }
 358     }
 359   }
 360
 361   private static final void parse() throws ParseException {
 362           phpFile();
 363   }
 364 }
 365
 366 PARSER_END(PHPParser)
 367
 368 TOKEN_MGR_DECLS:
 369 {
 370   // CommonTokenAction: use the begins/ends fields added to the Jack
 371   // CharStream class to set corresponding fields in each Token (which was
 372   // also extended with new fields). By default Jack doesn't supply absolute
 373   // offsets, just line/column offsets
 374   static void CommonTokenAction(Token t) {
 375     t.sourceStart = input_stream.beginOffset;
 376     t.sourceEnd = input_stream.endOffset;
 377   } // CommonTokenAction
 378 } // TOKEN_MGR_DECLS
 379
 380 <DEFAULT> TOKEN :
 381 {
 382   <PHPSTARTSHORT : "<?">    : PHPPARSING
 383 | <PHPSTARTLONG  : "<?php"> : PHPPARSING
 384 | <PHPECHOSTART  : "<?=">   : PHPPARSING
 385 }
 386
 387 <PHPPARSING, IN_SINGLE_LINE_COMMENT,IN_VARIABLE> TOKEN :
 388 {
 389   <PHPEND :"?>"> : DEFAULT
 390 }
 391
 392 /* Skip any character if we are not in php mode */
 393 <DEFAULT> SKIP :
 394 {
 395  < ~[] >
 396 }
 397
 398
 399 /* WHITE SPACE */
 400 <PHPPARSING> SKIP :
 401 {
 402   " "
 403 | "\t"
 404 | "\n"
 405 | "\r"
 406 | "\f"
 407 }
 408
 409 <IN_VARIABLE> SPECIAL_TOKEN :
 410 {
 411   " " : PHPPARSING
 412 | "\t" : PHPPARSING
 413 | "\n" : PHPPARSING
 414 | "\r" : PHPPARSING
 415 | "\f" : PHPPARSING
 416 }
 417 /* COMMENTS */
 418 <PHPPARSING> SPECIAL_TOKEN :
 419 {
 420   "//" : IN_SINGLE_LINE_COMMENT
 421 | "#"  : IN_SINGLE_LINE_COMMENT
 422 | <"/**" ~["/"]> { input_stream.backup(1); } : IN_FORMAL_COMMENT
 423 | "/*" : IN_MULTI_LINE_COMMENT
 424 }
 425
 426 <IN_SINGLE_LINE_COMMENT> SPECIAL_TOKEN :
 427 {
 428   <SINGLE_LINE_COMMENT: "\n" | "\r" | "\r\n" > : PHPPARSING
 429 | < ~[] >
 430 }
 431
 432 <IN_SINGLE_LINE_COMMENT,IN_FORMAL_COMMENT,IN_MULTI_LINE_COMMENT> SPECIAL_TOKEN :
 433 {
 434  "todo"
 435 }
 436
 437 void todo() :
 438 {Token todoToken;}
 439 {
 440   todoToken = "TODO" {createNewTask(todoToken.sourceStart);}
 441 }
 442 <IN_FORMAL_COMMENT> SPECIAL_TOKEN :
 443 {
 444   "*/" : PHPPARSING
 445 }
 446
 447 <IN_MULTI_LINE_COMMENT> SPECIAL_TOKEN :
 448 {
 449   "*/" : PHPPARSING
 450 }
 451
 452 <IN_SINGLE_LINE_COMMENT,IN_FORMAL_COMMENT,IN_MULTI_LINE_COMMENT>
 453 MORE :
 454 {
 455   < ~[] >
 456 }
 457
 458 /* KEYWORDS */
 459 <PHPPARSING> TOKEN :
 460 {
 461   <CLASS    : "class">
 462 | <FUNCTION : "function">
 463 | <VAR      : "var">
 464 | <IF       : "if">
 465 | <ELSEIF   : "elseif">
 466 | <ELSE     : "else">
 467 | <ARRAY    : "array">
 468 | <BREAK    : "break">
 469 | <LIST     : "list">
 470 }
 471
 472 /* LANGUAGE CONSTRUCT */
 473 <PHPPARSING> TOKEN :
 474 {
 475   <PRINT              : "print">
 476 | <ECHO               : "echo">
 477 | <INCLUDE            : "include">
 478 | <REQUIRE            : "require">
 479 | <INCLUDE_ONCE       : "include_once">
 480 | <REQUIRE_ONCE       : "require_once">
 481 | <GLOBAL             : "global">
 482 | <DEFINE             : "define">
 483 | <STATIC             : "static">
 484 }
 485
 486 <PHPPARSING,IN_VARIABLE> TOKEN :
 487 {
 488   <CLASSACCESS        : "->"> : PHPPARSING
 489 | <STATICCLASSACCESS  : "::"> : PHPPARSING
 490 | <ARRAYASSIGN        : "=>"> : PHPPARSING
 491 }
 492
 493 /* RESERVED WORDS AND LITERALS */
 494
 495 <PHPPARSING> TOKEN :
 496 {
 497   <CASE     : "case">
 498 | <CONST    : "const">
 499 | <CONTINUE : "continue">
 500 | <_DEFAULT : "default">
 501 | <DO       : "do">
 502 | <EXTENDS  : "extends">
 503 | <FOR      : "for">
 504 | <GOTO     : "goto">
 505 | <NEW      : "new">
 506 | <NULL     : "null">
 507 | <RETURN   : "return">
 508 | <SUPER    : "super">
 509 | <SWITCH   : "switch">
 510 | <THIS     : "this">
 511 | <TRUE     : "true">
 512 | <FALSE    : "false">
 513 | <WHILE    : "while">
 514 | <ENDWHILE : "endwhile">
 515 | <ENDSWITCH: "endswitch">
 516 | <ENDIF    : "endif">
 517 | <ENDFOR   : "endfor">
 518 | <FOREACH  : "foreach">
 519 | <AS       : "as" >
 520 }
 521
 522 /* TYPES */
 523 <PHPPARSING> TOKEN :
 524 {
 525   <STRING  : "string">
 526 | <OBJECT  : "object">
 527 | <BOOL    : "bool">
 528 | <BOOLEAN : "boolean">
 529 | <REAL    : "real">
 530 | <DOUBLE  : "double">
 531 | <FLOAT   : "float">
 532 | <INT     : "int">
 533 | <INTEGER : "integer">
 534 }
 535
 536 //Misc token
 537 <PHPPARSING,IN_VARIABLE> TOKEN :
 538 {
 539   <AT                 : "@"> : PHPPARSING
 540 | <BANG               : "!"> : PHPPARSING
 541 | <TILDE              : "~"> : PHPPARSING
 542 | <HOOK               : "?"> : PHPPARSING
 543 | <COLON              : ":"> : PHPPARSING
 544 }
 545
 546 /* OPERATORS */
 547 <PHPPARSING,IN_VARIABLE> TOKEN :
 548 {
 549   <OR_OR              : "||"> : PHPPARSING
 550 | <AND_AND            : "&&"> : PHPPARSING
 551 | <PLUS_PLUS          : "++"> : PHPPARSING
 552 | <MINUS_MINUS        : "--"> : PHPPARSING
 553 | <PLUS               : "+"> : PHPPARSING
 554 | <MINUS              : "-"> : PHPPARSING
 555 | <STAR               : "*"> : PHPPARSING
 556 | <SLASH              : "/"> : PHPPARSING
 557 | <BIT_AND            : "&"> : PHPPARSING
 558 | <BIT_OR             : "|"> : PHPPARSING
 559 | <XOR                : "^"> : PHPPARSING
 560 | <REMAINDER          : "%">  : PHPPARSING
 561 | <LSHIFT             : "<<"> : PHPPARSING
 562 | <RSIGNEDSHIFT       : ">>"> : PHPPARSING
 563 | <RUNSIGNEDSHIFT     : ">>>"> : PHPPARSING
 564 | <_ORL               : "OR"> : PHPPARSING
 565 | <_ANDL              : "AND"> : PHPPARSING
 566 }
 567
 568 /* LITERALS */
 569 <PHPPARSING> TOKEN :
 570 {
 571   <INTEGER_LITERAL:
 572         <DECIMAL_LITERAL> (["l","L"])?
 573       | <HEX_LITERAL> (["l","L"])?
 574       | <OCTAL_LITERAL> (["l","L"])?
 575   >
 576 |
 577   <#DECIMAL_LITERAL: ["1"-"9"] (["0"-"9"])* >
 578 |
 579   <#HEX_LITERAL: "0" ["x","X"] (["0"-"9","a"-"f","A"-"F"])+ >
 580 |
 581   <#OCTAL_LITERAL: "0" (["0"-"7"])* >
 582 |
 583   <FLOATING_POINT_LITERAL:
 584         (["0"-"9"])+ "." (["0"-"9"])* (<EXPONENT>)? (["f","F","d","D"])?
 585       | "." (["0"-"9"])+ (<EXPONENT>)? (["f","F","d","D"])?
 586       | (["0"-"9"])+ <EXPONENT> (["f","F","d","D"])?
 587       | (["0"-"9"])+ (<EXPONENT>)? ["f","F","d","D"]
 588   >
 589 |
 590   <#EXPONENT: ["e","E"] (["+","-"])? (["0"-"9"])+ >
 591 |
 592   <STRING_LITERAL: (<STRING_2> | <STRING_3>)>
 593 //|   <STRING_1: "\"" ( ~["\"","\\"] | "\\" ~[] )* "\"">
 594 |   <STRING_2: "'"  ( ~["'","\\"]  | "\\" ~[] )* "'">
 595 |   <STRING_3: "`"  ( ~["`","\\"]  | "\\" ~[] )* "`">
 596 }
 597
 598 <IN_STRING,DOLLAR_IN_STRING> SKIP :
 599 {
 600   <ESCAPED : ("\\" ~[])> : IN_STRING
 601 }
 602
 603 <PHPPARSING> TOKEN :
 604 {
 605   <DOUBLEQUOTE : "\""> : IN_STRING
 606 }
 607
 608
 609 <IN_STRING> TOKEN :
 610 {
 611   <DOLLARS : "$"> : DOLLAR_IN_STRING
 612 }
 613
 614 <IN_STRING,DOLLAR_IN_STRING> TOKEN :
 615 {
 616   <DOUBLEQUOTE2 : "\""> : PHPPARSING
 617 }
 618
 619 <DOLLAR_IN_STRING> TOKEN :
 620 {
 621   <LBRACE1 : "{"> : DOLLAR_IN_STRING_EXPR
 622 }
 623
 624 <IN_STRING> SPECIAL_TOKEN :
 625 {
 626     <"{"> : SKIPSTRING
 627 }
 628
 629 <SKIPSTRING> SPECIAL_TOKEN :
 630 {
 631     <"}"> : IN_STRING
 632 }
 633
 634 <SKIPSTRING> SKIP :
 635 {
 636     <~[]>
 637 }
 638
 639 <DOLLAR_IN_STRING_EXPR> TOKEN :
 640 {
 641   <RBRACE1 : "}"> : DOLLAR_IN_STRING
 642 }
 643
 644 <DOLLAR_IN_STRING_EXPR> TOKEN :
 645 {
 646   <ID : (~["}"])*>
 647 }
 648
 649 <IN_STRING> SKIP :
 650 {
 651   <~[]>
 652 }
 653
 654 <DOLLAR_IN_STRING_EXPR,IN_STRING> SKIP :
 655 {
 656   <~[]>
 657 }
 658 /* IDENTIFIERS */
 659
 660
 661 <PHPPARSING,IN_VARIABLE> TOKEN : {<DOLLAR : "$"> : IN_VARIABLE}
 662
 663
 664 <PHPPARSING, IN_VARIABLE, DOLLAR_IN_STRING> TOKEN :
 665 {
 666   <IDENTIFIER: (<LETTER>|<SPECIAL>) (<LETTER>|<DIGIT>|<SPECIAL>)* >
 667 |
 668   < #LETTER:
 669       ["a"-"z"] | ["A"-"Z"]
 670   >
 671 |
 672   < #DIGIT:
 673       ["0"-"9"]
 674   >
 675 |
 676   < #SPECIAL:
 677     "_" | ["\u007f"-"\u00ff"]
 678   >
 679 }
 680
 681 <DOLLAR_IN_STRING> SPECIAL_TOKEN :
 682 {
 683  < ~[] > : IN_STRING
 684 }
 685 /* SEPARATORS */
 686
 687 <PHPPARSING,IN_VARIABLE> TOKEN :
 688 {
 689   <LPAREN    : "("> : PHPPARSING
 690 | <RPAREN    : ")"> : PHPPARSING
 691 | <LBRACE    : "{"> : PHPPARSING
 692 | <RBRACE    : "}"> : PHPPARSING
 693 | <LBRACKET  : "["> : PHPPARSING
 694 | <RBRACKET  : "]"> : PHPPARSING
 695 | <SEMICOLON : ";"> : PHPPARSING
 696 | <COMMA     : ","> : PHPPARSING
 697 | <DOT       : "."> : PHPPARSING
 698 }
 699
 700
 701 /* COMPARATOR */
 702 <PHPPARSING,IN_VARIABLE> TOKEN :
 703 {
 704   <GT                 : ">"> : PHPPARSING
 705 | <LT                 : "<"> : PHPPARSING
 706 | <EQUAL_EQUAL        : "=="> : PHPPARSING
 707 | <LE                 : "<="> : PHPPARSING
 708 | <GE                 : ">="> : PHPPARSING
 709 | <NOT_EQUAL          : "!="> : PHPPARSING
 710 | <DIF                : "<>"> : PHPPARSING
 711 | <BANGDOUBLEEQUAL    : "!=="> : PHPPARSING
 712 | <TRIPLEEQUAL        : "==="> : PHPPARSING
 713 }
 714
 715 /* ASSIGNATION */
 716 <PHPPARSING,IN_VARIABLE> TOKEN :
 717 {
 718   <ASSIGN             : "="> : PHPPARSING
 719 | <PLUSASSIGN         : "+="> : PHPPARSING
 720 | <MINUSASSIGN        : "-="> : PHPPARSING
 721 | <STARASSIGN         : "*="> : PHPPARSING
 722 | <SLASHASSIGN        : "/="> : PHPPARSING
 723 | <ANDASSIGN          : "&="> : PHPPARSING
 724 | <ORASSIGN           : "|="> : PHPPARSING
 725 | <XORASSIGN          : "^="> : PHPPARSING
 726 | <DOTASSIGN          : ".="> : PHPPARSING
 727 | <REMASSIGN          : "%="> : PHPPARSING
 728 | <TILDEEQUAL         : "~="> : PHPPARSING
 729 | <LSHIFTASSIGN       : "<<="> : PHPPARSING
 730 | <RSIGNEDSHIFTASSIGN : ">>="> : PHPPARSING
 731 }
 732
 733 void phpTest() :
 734 {}
 735 {
 736   Php()
 737   <EOF>
 738 }
 739
 740 void phpFile() :
 741 {}
 742 {
 743   try {
 744     (PhpBlock())*
 745     {PHPParser.createNewHTMLCode();}
 746   } catch (TokenMgrError e) {
 747     PHPeclipsePlugin.log(e);
 748     errorStart   = SimpleCharStream.beginOffset;
 749     errorEnd     = SimpleCharStream.endOffset;
 750     errorMessage = e.getMessage();
 751     errorLevel   = ERROR;
 752     throw generateParseException();
 753   }
 754 }
 755
 756 /**
 757  * A php block is a <?= expression [;]?>
 758  * or <?php somephpcode ?>
 759  * or <? somephpcode ?>
 760  */
 761 void PhpBlock() :
 762 {
 763   final PHPEchoBlock phpEchoBlock;
 764   final Token token,phpEnd;
 765 }
 766 {
 767   phpEchoBlock = phpEchoBlock()
 768   {pushOnAstNodes(phpEchoBlock);}
 769 |
 770   [   <PHPSTARTLONG>
 771     | token = <PHPSTARTSHORT>
 772     {try {
 773       setMarker(fileToParse,
 774                 "You should use '<?php' instead of '<?' it will avoid some problems with XML",
 775                 token.sourceStart,
 776                 token.sourceEnd,
 777                 INFO,
 778                 "Line " + token.beginLine);
 779     } catch (CoreException e) {
 780       PHPeclipsePlugin.log(e);
 781     }}
 782   ]
 783   {PHPParser.createNewHTMLCode();}
 784   Php()
 785   try {
 786     phpEnd = <PHPEND>
 787    {htmlStart = phpEnd.sourceEnd;}
 788   } catch (ParseException e) {
 789     errorMessage = "'?>' expected";
 790     errorLevel   = ERROR;
 791     errorStart = e.currentToken.sourceStart;
 792     errorEnd   = e.currentToken.sourceEnd;
 793     processParseExceptionDebug(e);
 794   }
 795 }
 796
 797 PHPEchoBlock phpEchoBlock() :
 798 {
 799   final Expression expr;
 800   final PHPEchoBlock echoBlock;
 801   final Token token, token2;
 802 }
 803 {
 804   token = <PHPECHOSTART> {PHPParser.createNewHTMLCode();}
 805   expr = Expression() [ <SEMICOLON> ] token2 = <PHPEND>
 806   {
 807   htmlStart = token2.sourceEnd;
 808
 809   echoBlock = new PHPEchoBlock(expr,token.sourceStart,token2.sourceEnd);
 810   pushOnAstNodes(echoBlock);
 811   return echoBlock;}
 812 }
 813
 814 void Php() :
 815 {}
 816 {
 817   (BlockStatement())*
 818 }
 819
 820 ClassDeclaration ClassDeclaration() :
 821 {
 822   final ClassDeclaration classDeclaration;
 823   Token className = null;
 824   final Token superclassName, token, extendsToken;
 825   String classNameImage = SYNTAX_ERROR_CHAR;
 826   String superclassNameImage = null;
 827   final int classEnd;
 828 }
 829 {
 830   token = <CLASS>
 831   try {
 832     className = <IDENTIFIER>
 833     {classNameImage = className.image;}
 834   } catch (ParseException e) {
 835     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', identifier expected";
 836     errorLevel   = ERROR;
 837     errorStart   = token.sourceEnd+1;
 838     errorEnd     = token.sourceEnd+1;
 839     processParseExceptionDebug(e);
 840   }
 841   [
 842     extendsToken = <EXTENDS>
 843     try {
 844       superclassName = <IDENTIFIER>
 845       {superclassNameImage = superclassName.image;}
 846     } catch (ParseException e) {
 847       errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', identifier expected";
 848       errorLevel   = ERROR;
 849       errorStart = extendsToken.sourceEnd+1;
 850       errorEnd   = extendsToken.sourceEnd+1;
 851       processParseExceptionDebug(e);
 852       superclassNameImage = SYNTAX_ERROR_CHAR;
 853     }
 854   ]
 855   {
 856     int start, end;
 857     if (className == null) {
 858       start = token.sourceStart;
 859       end = token.sourceEnd;
 860     } else {
 861       start = className.sourceStart;
 862       end = className.sourceEnd;
 863     }
 864     if (superclassNameImage == null) {
 865
 866       classDeclaration = new ClassDeclaration(currentSegment,
 867                                               classNameImage,
 868                                               start,
 869                                               end);
 870     } else {
 871       classDeclaration = new ClassDeclaration(currentSegment,
 872                                               classNameImage,
 873                                               superclassNameImage,
 874                                               start,
 875                                               end);
 876     }
 877       currentSegment.add(classDeclaration);
 878       currentSegment = classDeclaration;
 879   }
 880   classEnd = ClassBody(classDeclaration)
 881   {currentSegment = (OutlineableWithChildren) currentSegment.getParent();
 882    classDeclaration.sourceEnd = classEnd;
 883    pushOnAstNodes(classDeclaration);
 884    return classDeclaration;}
 885 }
 886
 887 int ClassBody(final ClassDeclaration classDeclaration) :
 888 {
 889 Token token;
 890 }
 891 {
 892   try {
 893     <LBRACE>
 894   } catch (ParseException e) {
 895     errorMessage = "unexpected token : '"+ e.currentToken.next.image + "'. '{' expected";
 896     errorLevel   = ERROR;
 897     errorStart = e.currentToken.sourceStart;
 898     errorEnd   = e.currentToken.sourceEnd;
 899     processParseExceptionDebug(e);
 900   }
 901   ( ClassBodyDeclaration(classDeclaration) )*
 902   try {
 903     token = <RBRACE>
 904     {return token.sourceEnd;}
 905   } catch (ParseException e) {
 906     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. 'var', 'function' or '}' expected";
 907     errorLevel   = ERROR;
 908     errorStart = e.currentToken.sourceStart;
 909     errorEnd   = e.currentToken.sourceEnd;
 910     processParseExceptionDebug(e);
 911     return PHPParser.token.sourceEnd;
 912   }
 913 }
 914
 915 /**
 916  * A class can contain only methods and fields.
 917  */
 918 void ClassBodyDeclaration(final ClassDeclaration classDeclaration) :
 919 {
 920   final MethodDeclaration method;
 921   final FieldDeclaration field;
 922 }
 923 {
 924   method = MethodDeclaration() {method.analyzeCode();
 925                                 classDeclaration.addMethod(method);}
 926 | field = FieldDeclaration()   {classDeclaration.addField(field);}
 927 }
 928
 929 /**
 930  * A class field declaration : it's var VariableDeclarator() (, VariableDeclarator())*;.
 931  * it is only used by ClassBodyDeclaration()
 932  */
 933 FieldDeclaration FieldDeclaration() :
 934 {
 935   VariableDeclaration variableDeclaration;
 936   final VariableDeclaration[] list;
 937   final ArrayList arrayList = new ArrayList();
 938   final Token token;
 939   Token token2 = null;
 940   int pos;
 941 }
 942 {
 943   token = <VAR> variableDeclaration = VariableDeclaratorNoSuffix()
 944   {
 945     arrayList.add(variableDeclaration);
 946     pos = variableDeclaration.sourceEnd;
 947   }
 948   (
 949     <COMMA> variableDeclaration = VariableDeclaratorNoSuffix()
 950       {
 951         arrayList.add(variableDeclaration);
 952         outlineInfo.addVariable(variableDeclaration.name());
 953         pos = variableDeclaration.sourceEnd;
 954       }
 955   )*
 956   try {
 957     token2 = <SEMICOLON>
 958   } catch (ParseException e) {
 959     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected after variable declaration";
 960     errorLevel   = ERROR;
 961     errorStart   = pos+1;
 962     errorEnd     = pos+1;
 963     processParseExceptionDebug(e);
 964   }
 965
 966   {list = new VariableDeclaration[arrayList.size()];
 967    arrayList.toArray(list);
 968    int end;
 969    if (token2 == null) {
 970      end = list[list.length-1].sourceEnd;
 971    } else {
 972      end = token2.sourceEnd;
 973    }
 974    return new FieldDeclaration(list,
 975                                token.sourceStart,
 976                                end,
 977                                currentSegment);}
 978 }
 979
 980 /**
 981  * a strict variable declarator : there cannot be a suffix here.
 982  * It will be used by fields and formal parameters
 983  */
 984 VariableDeclaration VariableDeclaratorNoSuffix() :
 985 {
 986   final Token token, lbrace,rbrace;
 987   Expression expr, initializer = null;
 988   Token assignToken;
 989   Variable variable;
 990 }
 991 {
 992   <DOLLAR>
 993   (
 994      token = <IDENTIFIER>
 995      {variable = new Variable(token.image,token.sourceStart,token.sourceEnd);}
 996    |
 997      lbrace = <LBRACE> expr = Expression() rbrace = <RBRACE>
 998      {variable = new Variable(expr,lbrace.sourceStart,rbrace.sourceEnd);}
 999   )
1000   [
1001     assignToken = <ASSIGN>
1002     try {
1003       initializer = VariableInitializer()
1004     } catch (ParseException e) {
1005       errorMessage = "Literal expression expected in variable initializer";
1006       errorLevel   = ERROR;
1007       errorStart = assignToken.sourceEnd +1;
1008       errorEnd   = assignToken.sourceEnd +1;
1009       processParseExceptionDebug(e);
1010     }
1011   ]
1012   {
1013   if (initializer == null) {
1014     return new VariableDeclaration(currentSegment,
1015                                    variable,
1016                                    variable.sourceStart,
1017                                    variable.sourceEnd);
1018   }
1019   return new VariableDeclaration(currentSegment,
1020                                  variable,
1021                                  initializer,
1022                                  VariableDeclaration.EQUAL,
1023                                  variable.sourceStart);
1024   }
1025 }
1026
1027 /**
1028  * this will be used by static statement
1029  */
1030 VariableDeclaration VariableDeclarator() :
1031 {
1032   final AbstractVariable variable;
1033   Expression initializer = null;
1034   final Token token;
1035 }
1036 {
1037   variable = VariableDeclaratorId()
1038   [
1039     token = <ASSIGN>
1040     try {
1041       initializer = VariableInitializer()
1042     } catch (ParseException e) {
1043       errorMessage = "Literal expression expected in variable initializer";
1044       errorLevel   = ERROR;
1045       errorStart = token.sourceEnd+1;
1046       errorEnd   = token.sourceEnd+1;
1047       processParseExceptionDebug(e);
1048     }
1049   ]
1050   {
1051   if (initializer == null) {
1052     return new VariableDeclaration(currentSegment,
1053                                    variable,
1054                                    variable.sourceStart,
1055                                    variable.sourceEnd);
1056   }
1057     return new VariableDeclaration(currentSegment,
1058                                    variable,
1059                                    initializer,
1060                                    VariableDeclaration.EQUAL,
1061                                    variable.sourceStart);
1062   }
1063 }
1064
1065 /**
1066  * A Variable name.
1067  * @return the variable name (with suffix)
1068  */
1069 AbstractVariable VariableDeclaratorId() :
1070 {
1071   final Variable var;
1072   AbstractVariable expression = null;
1073 }
1074 {
1075   try {
1076     var = Variable()
1077     (
1078       LOOKAHEAD(2)
1079       expression = VariableSuffix(var)
1080     )*
1081     {
1082      if (expression == null) {
1083        return var;
1084      }
1085      return expression;
1086     }
1087   } catch (ParseException e) {
1088     errorMessage = "'$' expected for variable identifier";
1089     errorLevel   = ERROR;
1090     errorStart = e.currentToken.sourceStart;
1091     errorEnd   = e.currentToken.sourceEnd;
1092     throw e;
1093   }
1094 }
1095
1096 Variable Variable() :
1097 {
1098   Variable variable = null;
1099   final Token token;
1100 }
1101 {
1102   token = <DOLLAR> variable = Var()
1103   {
1104     return variable;
1105   }
1106 }
1107
1108 Variable Var() :
1109 {
1110   Variable variable = null;
1111   final Token token,token2;
1112   ConstantIdentifier constant;
1113   Expression expression;
1114 }
1115 {
1116   token = <DOLLAR> variable = Var()
1117   {return new Variable(variable,variable.sourceStart,variable.sourceEnd);}
1118 |
1119   token = <LBRACE> expression = Expression() token2 = <RBRACE>
1120   {
1121    return new Variable(expression,
1122                        token.sourceStart,
1123                        token2.sourceEnd);
1124   }
1125 |
1126   token = <IDENTIFIER>
1127   {
1128    outlineInfo.addVariable("$" + token.image);
1129    return new Variable(token.image,token.sourceStart,token.sourceEnd);
1130   }
1131 }
1132
1133 Expression VariableInitializer() :
1134 {
1135   final Expression expr;
1136   final Token token, token2;
1137 }
1138 {
1139   expr = Literal()
1140   {return expr;}
1141 |
1142   token2 = <MINUS> (token = <INTEGER_LITERAL> | token = <FLOATING_POINT_LITERAL>)
1143   {return new PrefixedUnaryExpression(new NumberLiteral(token),
1144                                       OperatorIds.MINUS,
1145                                       token2.sourceStart);}
1146 |
1147   token2 = <PLUS> (token = <INTEGER_LITERAL> | token = <FLOATING_POINT_LITERAL>)
1148   {return new PrefixedUnaryExpression(new NumberLiteral(token),
1149                                       OperatorIds.PLUS,
1150                                       token2.sourceStart);}
1151 |
1152   expr = ArrayDeclarator()
1153   {return expr;}
1154 |
1155   token = <IDENTIFIER>
1156   {return new ConstantIdentifier(token);}
1157 }
1158
1159 ArrayVariableDeclaration ArrayVariable() :
1160 {
1161 final Expression expr,expr2;
1162 }
1163 {
1164   expr = Expression()
1165   [
1166     <ARRAYASSIGN> expr2 = Expression()
1167     {return new ArrayVariableDeclaration(expr,expr2);}
1168   ]
1169   {return new ArrayVariableDeclaration(expr,SimpleCharStream.getPosition());}
1170 }
1171
1172 ArrayVariableDeclaration[] ArrayInitializer() :
1173 {
1174   ArrayVariableDeclaration expr;
1175   final ArrayList list = new ArrayList();
1176 }
1177 {
1178   <LPAREN>
1179     [
1180       expr = ArrayVariable()
1181       {list.add(expr);}
1182       ( LOOKAHEAD(2) <COMMA> expr = ArrayVariable()
1183       {list.add(expr);}
1184       )*
1185     ]
1186     [
1187       <COMMA> {list.add(null);}
1188     ]
1189   <RPAREN>
1190   {
1191   final ArrayVariableDeclaration[] vars = new ArrayVariableDeclaration[list.size()];
1192   list.toArray(vars);
1193   return vars;}
1194 }
1195
1196 /**
1197  * A Method Declaration.
1198  * <b>function</b> MetodDeclarator() Block()
1199  */
1200 MethodDeclaration MethodDeclaration() :
1201 {
1202   final MethodDeclaration functionDeclaration;
1203   final Block block;
1204   final OutlineableWithChildren seg = currentSegment;
1205   final Token token;
1206 }
1207 {
1208   token = <FUNCTION>
1209   try {
1210     functionDeclaration = MethodDeclarator(token.sourceStart)
1211     {outlineInfo.addVariable(functionDeclaration.name);}
1212   } catch (ParseException e) {
1213     if (errorMessage != null)  throw e;
1214     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', function identifier expected";
1215     errorLevel   = ERROR;
1216     errorStart = e.currentToken.sourceStart;
1217     errorEnd   = e.currentToken.sourceEnd;
1218     throw e;
1219   }
1220   {currentSegment = functionDeclaration;}
1221   block = Block()
1222   {functionDeclaration.statements = block.statements;
1223    currentSegment = seg;
1224    return functionDeclaration;}
1225 }
1226
1227 /**
1228  * A MethodDeclarator.
1229  * [&] IDENTIFIER(parameters ...).
1230  * @return a function description for the outline
1231  */
1232 MethodDeclaration MethodDeclarator(final int start) :
1233 {
1234   Token identifier = null;
1235   Token reference = null;
1236   final ArrayList formalParameters = new ArrayList();
1237   String identifierChar = SYNTAX_ERROR_CHAR;
1238   int end = start;
1239 }
1240 {
1241   [reference = <BIT_AND> {end = reference.sourceEnd;}]
1242   try {
1243     identifier = <IDENTIFIER>
1244     {
1245       identifierChar = identifier.image;
1246       end = identifier.sourceEnd;
1247     }
1248   } catch (ParseException e) {
1249     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', function identifier expected";
1250     errorLevel   = ERROR;
1251     errorStart = e.currentToken.sourceEnd;
1252     errorEnd   = e.currentToken.next.sourceStart;
1253     processParseExceptionDebug(e);
1254   }
1255   end = FormalParameters(formalParameters)
1256   {
1257   int nameStart, nameEnd;
1258   if (identifier == null) {
1259     if (reference == null) {
1260       nameStart = start + 9;
1261       nameEnd = start + 10;
1262     } else {
1263       nameStart = reference.sourceEnd + 1;
1264       nameEnd = reference.sourceEnd + 2;
1265     }
1266   } else {
1267       nameStart = identifier.sourceStart;
1268       nameEnd = identifier.sourceEnd;
1269   }
1270   return new MethodDeclaration(currentSegment,
1271                                identifierChar,
1272                                formalParameters,
1273                                reference != null,
1274                                nameStart,
1275                                nameEnd,
1276                                start,
1277                                end);
1278   }
1279 }
1280
1281 /**
1282  * FormalParameters follows method identifier.
1283  * (FormalParameter())
1284  */
1285 int FormalParameters(final ArrayList parameters) :
1286 {
1287   VariableDeclaration var;
1288   final Token token;
1289   Token tok = PHPParser.token;
1290   int end = tok.sourceEnd;
1291 }
1292 {
1293   try {
1294   tok = <LPAREN>
1295   {end = tok.sourceEnd;}
1296   } catch (ParseException e) {
1297     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', '(' expected after function identifier";
1298     errorLevel   = ERROR;
1299     errorStart = e.currentToken.next.sourceStart;
1300     errorEnd   = e.currentToken.next.sourceEnd;
1301     processParseExceptionDebug(e);
1302   }
1303   [
1304     var = FormalParameter()
1305     {parameters.add(var);end = var.sourceEnd;}
1306     (
1307       <COMMA> var = FormalParameter()
1308       {parameters.add(var);end = var.sourceEnd;}
1309     )*
1310   ]
1311   try {
1312     token = <RPAREN>
1313     {end = token.sourceEnd;}
1314   } catch (ParseException e) {
1315     errorMessage = "')' expected";
1316     errorLevel   = ERROR;
1317     errorStart = e.currentToken.next.sourceStart;
1318     errorEnd   = e.currentToken.next.sourceEnd;
1319     processParseExceptionDebug(e);
1320   }
1321  {return end;}
1322 }
1323
1324 /**
1325  * A formal parameter.
1326  * $varname[=value] (,$varname[=value])
1327  */
1328 VariableDeclaration FormalParameter() :
1329 {
1330   final VariableDeclaration variableDeclaration;
1331   Token token = null;
1332 }
1333 {
1334   [token = <BIT_AND>] variableDeclaration = VariableDeclaratorNoSuffix()
1335   {
1336     outlineInfo.addVariable("$"+variableDeclaration.name());
1337     if (token != null) {
1338       variableDeclaration.setReference(true);
1339     }
1340     return variableDeclaration;}
1341 }
1342
1343 ConstantIdentifier Type() :
1344 {final Token token;}
1345 {
1346   token = <STRING>    {return new ConstantIdentifier(token);}
1347 | token = <BOOL>      {return new ConstantIdentifier(token);}
1348 | token = <BOOLEAN>   {return new ConstantIdentifier(token);}
1349 | token = <REAL>      {return new ConstantIdentifier(token);}
1350 | token = <DOUBLE>    {return new ConstantIdentifier(token);}
1351 | token = <FLOAT>     {return new ConstantIdentifier(token);}
1352 | token = <INT>       {return new ConstantIdentifier(token);}
1353 | token = <INTEGER>   {return new ConstantIdentifier(token);}
1354 | token = <OBJECT>    {return new ConstantIdentifier(token);}
1355 }
1356
1357 Expression Expression() :
1358 {
1359   final Expression expr;
1360   Expression initializer = null;
1361   int assignOperator = -1;
1362 }
1363 {
1364   LOOKAHEAD(1)
1365   expr = ConditionalExpression()
1366   [
1367     assignOperator = AssignmentOperator()
1368     try {
1369       initializer = Expression()
1370     } catch (ParseException e) {
1371       if (errorMessage != null) {
1372         throw e;
1373       }
1374       errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', expression expected";
1375       errorLevel   = ERROR;
1376       errorEnd   = SimpleCharStream.getPosition();
1377       throw e;
1378     }
1379   ]
1380   {
1381     if (assignOperator != -1) {// todo : change this, very very bad :(
1382         if (expr instanceof AbstractVariable) {
1383           return new VariableDeclaration(currentSegment,
1384                                          (AbstractVariable) expr,
1385                                          initializer,
1386                                          expr.sourceStart,
1387                                          initializer.sourceEnd);
1388         }
1389         String varName = expr.toStringExpression().substring(1);
1390         return new VariableDeclaration(currentSegment,
1391                                        new Variable(varName,
1392                                                     expr.sourceStart,
1393                                                     expr.sourceEnd),
1394                                        expr.sourceStart,
1395                                        initializer.sourceEnd);
1396     }
1397     return expr;
1398   }
1399 | expr = ExpressionWBang()       {return expr;}
1400 }
1401
1402 Expression ExpressionWBang() :
1403 {
1404   final Expression expr;
1405   final Token token;
1406 }
1407 {
1408   token = <BANG> expr = ExpressionWBang()
1409   {return new PrefixedUnaryExpression(expr,OperatorIds.NOT,token.sourceStart);}
1410 | expr = ExpressionNoBang() {return expr;}
1411 }
1412
1413 Expression ExpressionNoBang() :
1414 {
1415   Expression expr;
1416 }
1417 {
1418   expr = ListExpression()    {return expr;}
1419 |
1420   expr = PrintExpression()   {return expr;}
1421 }
1422
1423 /**
1424  * Any assignement operator.
1425  * @return the assignement operator id
1426  */
1427 int AssignmentOperator() :
1428 {}
1429 {
1430   <ASSIGN>             {return VariableDeclaration.EQUAL;}
1431 | <STARASSIGN>         {return VariableDeclaration.STAR_EQUAL;}
1432 | <SLASHASSIGN>        {return VariableDeclaration.SLASH_EQUAL;}
1433 | <REMASSIGN>          {return VariableDeclaration.REM_EQUAL;}
1434 | <PLUSASSIGN>         {return VariableDeclaration.PLUS_EQUAL;}
1435 | <MINUSASSIGN>        {return VariableDeclaration.MINUS_EQUAL;}
1436 | <LSHIFTASSIGN>       {return VariableDeclaration.LSHIFT_EQUAL;}
1437 | <RSIGNEDSHIFTASSIGN> {return VariableDeclaration.RSIGNEDSHIFT_EQUAL;}
1438 | <ANDASSIGN>          {return VariableDeclaration.AND_EQUAL;}
1439 | <XORASSIGN>          {return VariableDeclaration.XOR_EQUAL;}
1440 | <ORASSIGN>           {return VariableDeclaration.OR_EQUAL;}
1441 | <DOTASSIGN>          {return VariableDeclaration.DOT_EQUAL;}
1442 | <TILDEEQUAL>         {return VariableDeclaration.TILDE_EQUAL;}
1443 }
1444
1445 Expression ConditionalExpression() :
1446 {
1447   final Expression expr;
1448   Expression expr2 = null;
1449   Expression expr3 = null;
1450 }
1451 {
1452   expr = ConditionalOrExpression() [ <HOOK> expr2 = Expression() <COLON> expr3 = ConditionalExpression() ]
1453 {
1454   if (expr3 == null) {
1455     return expr;
1456   }
1457   return new ConditionalExpression(expr,expr2,expr3);
1458 }
1459 }
1460
1461 Expression ConditionalOrExpression() :
1462 {
1463   Expression expr,expr2;
1464   int operator;
1465 }
1466 {
1467   expr = ConditionalAndExpression()
1468   (
1469     (
1470         <OR_OR> {operator = OperatorIds.OR_OR;}
1471       | <_ORL>  {operator = OperatorIds.ORL;}
1472     )
1473     expr2 = ConditionalAndExpression()
1474     {
1475       expr = new BinaryExpression(expr,expr2,operator);
1476     }
1477   )*
1478   {return expr;}
1479 }
1480
1481 Expression ConditionalAndExpression() :
1482 {
1483   Expression expr,expr2;
1484   int operator;
1485 }
1486 {
1487   expr = ConcatExpression()
1488   (
1489   (  <AND_AND> {operator = OperatorIds.AND_AND;}
1490    | <_ANDL>   {operator = OperatorIds.ANDL;})
1491    expr2 = ConcatExpression() {expr = new BinaryExpression(expr,expr2,operator);}
1492   )*
1493   {return expr;}
1494 }
1495
1496 Expression ConcatExpression() :
1497 {
1498   Expression expr,expr2;
1499 }
1500 {
1501   expr = InclusiveOrExpression()
1502   (
1503     <DOT> expr2 = InclusiveOrExpression()
1504     {expr = new BinaryExpression(expr,expr2,OperatorIds.DOT);}
1505   )*
1506   {return expr;}
1507 }
1508
1509 Expression InclusiveOrExpression() :
1510 {
1511   Expression expr,expr2;
1512 }
1513 {
1514   expr = ExclusiveOrExpression()
1515   (<BIT_OR> expr2 = ExclusiveOrExpression()
1516    {expr = new BinaryExpression(expr,expr2,OperatorIds.OR);}
1517   )*
1518   {return expr;}
1519 }
1520
1521 Expression ExclusiveOrExpression() :
1522 {
1523   Expression expr,expr2;
1524 }
1525 {
1526   expr = AndExpression()
1527   (
1528     <XOR> expr2 = AndExpression()
1529     {expr = new BinaryExpression(expr,expr2,OperatorIds.XOR);}
1530   )*
1531   {return expr;}
1532 }
1533
1534 Expression AndExpression() :
1535 {
1536   Expression expr,expr2;
1537 }
1538 {
1539   expr = EqualityExpression()
1540   (
1541     LOOKAHEAD(1)
1542     <BIT_AND> expr2 = EqualityExpression()
1543     {expr = new BinaryExpression(expr,expr2,OperatorIds.AND);}
1544   )*
1545   {return expr;}
1546 }
1547
1548 Expression EqualityExpression() :
1549 {
1550   Expression expr,expr2;
1551   int operator;
1552   Token token;
1553 }
1554 {
1555   expr = RelationalExpression()
1556   (
1557   (   token = <EQUAL_EQUAL>      {operator = OperatorIds.EQUAL_EQUAL;}
1558     | token = <DIF>              {operator = OperatorIds.DIF;}
1559     | token = <NOT_EQUAL>        {operator = OperatorIds.DIF;}
1560     | token = <BANGDOUBLEEQUAL>  {operator = OperatorIds.BANG_EQUAL_EQUAL;}
1561     | token = <TRIPLEEQUAL>      {operator = OperatorIds.EQUAL_EQUAL_EQUAL;}
1562   )
1563   try {
1564     expr2 = RelationalExpression()
1565   } catch (ParseException e) {
1566     if (errorMessage != null) {
1567       throw e;
1568     }
1569     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', expression expected";
1570     errorLevel   = ERROR;
1571     errorStart = token.sourceEnd +1;
1572     errorEnd   = token.sourceEnd +1;
1573     expr2 = new ConstantIdentifier(SYNTAX_ERROR_CHAR,token.sourceEnd +1,token.sourceEnd +1);
1574     processParseExceptionDebug(e);
1575   }
1576   {
1577     expr = new BinaryExpression(expr,expr2,operator);
1578   }
1579   )*
1580   {return expr;}
1581 }
1582
1583 Expression RelationalExpression() :
1584 {
1585   Expression expr,expr2;
1586   int operator;
1587 }
1588 {
1589   expr = ShiftExpression()
1590   (
1591   ( <LT> {operator = OperatorIds.LESS;}
1592   | <GT> {operator = OperatorIds.GREATER;}
1593   | <LE> {operator = OperatorIds.LESS_EQUAL;}
1594   | <GE> {operator = OperatorIds.GREATER_EQUAL;})
1595    expr2 = ShiftExpression()
1596   {expr = new BinaryExpression(expr,expr2,operator);}
1597   )*
1598   {return expr;}
1599 }
1600
1601 Expression ShiftExpression() :
1602 {
1603   Expression expr,expr2;
1604   int operator;
1605 }
1606 {
1607   expr = AdditiveExpression()
1608   (
1609   ( <LSHIFT>         {operator = OperatorIds.LEFT_SHIFT;}
1610   | <RSIGNEDSHIFT>   {operator = OperatorIds.RIGHT_SHIFT;}
1611   | <RUNSIGNEDSHIFT> {operator = OperatorIds.UNSIGNED_RIGHT_SHIFT;})
1612   expr2 = AdditiveExpression()
1613   {expr = new BinaryExpression(expr,expr2,operator);}
1614   )*
1615   {return expr;}
1616 }
1617
1618 Expression AdditiveExpression() :
1619 {
1620   Expression expr,expr2;
1621   int operator;
1622 }
1623 {
1624   expr = MultiplicativeExpression()
1625   (
1626     LOOKAHEAD(1)
1627      ( <PLUS>  {operator = OperatorIds.PLUS;}
1628      | <MINUS> {operator = OperatorIds.MINUS;}
1629   )
1630    expr2 = MultiplicativeExpression()
1631   {expr = new BinaryExpression(expr,expr2,operator);}
1632    )*
1633   {return expr;}
1634 }
1635
1636 Expression MultiplicativeExpression() :
1637 {
1638   Expression expr,expr2;
1639   int operator;
1640 }
1641 {
1642   try {
1643     expr = UnaryExpression()
1644   } catch (ParseException e) {
1645     if (errorMessage != null) throw e;
1646     errorMessage = "unexpected token '"+e.currentToken.next.image+"'";
1647     errorLevel   = ERROR;
1648     errorStart = PHPParser.token.sourceStart;
1649     errorEnd   = PHPParser.token.sourceEnd;
1650     throw e;
1651   }
1652   (
1653    (  <STAR>      {operator = OperatorIds.MULTIPLY;}
1654     | <SLASH>     {operator = OperatorIds.DIVIDE;}
1655     | <REMAINDER> {operator = OperatorIds.REMAINDER;})
1656     expr2 = UnaryExpression()
1657     {expr = new BinaryExpression(expr,expr2,operator);}
1658   )*
1659   {return expr;}
1660 }
1661
1662 /**
1663  * An unary expression starting with @, & or nothing
1664  */
1665 Expression UnaryExpression() :
1666 {
1667   final Expression expr;
1668 }
1669 {
1670  /* <BIT_AND> expr = UnaryExpressionNoPrefix()             //why did I had that ?
1671   {return new PrefixedUnaryExpression(expr,OperatorIds.AND,pos);}
1672 |      */
1673   expr = AtNotTildeUnaryExpression() {return expr;}
1674 }
1675
1676 Expression AtNotTildeUnaryExpression() :
1677 {
1678   final Expression expr;
1679   final Token token;
1680 }
1681 {
1682   token = <AT>
1683   expr = AtNotTildeUnaryExpression()
1684   {return new PrefixedUnaryExpression(expr,OperatorIds.AT,token.sourceStart);}
1685 |
1686   token = <TILDE>
1687   expr = AtNotTildeUnaryExpression()
1688   {return new PrefixedUnaryExpression(expr,OperatorIds.TWIDDLE,token.sourceStart);}
1689 |
1690   token = <BANG>
1691   expr = AtNotUnaryExpression()
1692   {return new PrefixedUnaryExpression(expr,OperatorIds.NOT,token.sourceStart);}
1693 |
1694   expr = UnaryExpressionNoPrefix()
1695   {return expr;}
1696 }
1697
1698 /**
1699  * An expression prefixed (or not) by one or more @ and !.
1700  * @return the expression
1701  */
1702 Expression AtNotUnaryExpression() :
1703 {
1704   final Expression expr;
1705   final Token token;
1706 }
1707 {
1708   token = <AT>
1709   expr = AtNotUnaryExpression()
1710   {return new PrefixedUnaryExpression(expr,OperatorIds.AT,token.sourceStart);}
1711 |
1712   token = <BANG>
1713   expr = AtNotUnaryExpression()
1714   {return new PrefixedUnaryExpression(expr,OperatorIds.NOT,token.sourceStart);}
1715 |
1716   expr = UnaryExpressionNoPrefix()
1717   {return expr;}
1718 }
1719
1720 Expression UnaryExpressionNoPrefix() :
1721 {
1722   final Expression expr;
1723   final Token token;
1724 }
1725 {
1726   token = <PLUS> expr = AtNotTildeUnaryExpression()   {return new PrefixedUnaryExpression(expr,
1727                                                                                      OperatorIds.PLUS,
1728                                                                                      token.sourceStart);}
1729 |
1730   token = <MINUS> expr = AtNotTildeUnaryExpression()  {return new PrefixedUnaryExpression(expr,
1731                                                                                      OperatorIds.MINUS,
1732                                                                                      token.sourceStart);}
1733 |
1734   expr = PreIncDecExpression()
1735   {return expr;}
1736 |
1737   expr = UnaryExpressionNotPlusMinus()
1738   {return expr;}
1739 }
1740
1741
1742 Expression PreIncDecExpression() :
1743 {
1744 final Expression expr;
1745 final int operator;
1746 final Token token;
1747 }
1748 {
1749   (
1750       token = <PLUS_PLUS>   {operator = OperatorIds.PLUS_PLUS;}
1751     |
1752       token = <MINUS_MINUS> {operator = OperatorIds.MINUS_MINUS;}
1753   )
1754   expr = PrimaryExpression()
1755   {return new PrefixedUnaryExpression(expr,operator,token.sourceStart);}
1756 }
1757
1758 Expression UnaryExpressionNotPlusMinus() :
1759 {
1760   final Expression expr;
1761 }
1762 {
1763   LOOKAHEAD( <LPAREN> (Type() | <ARRAY>) <RPAREN> )
1764   expr = CastExpression()         {return expr;}
1765 | expr = PostfixExpression()      {return expr;}
1766 | expr = Literal()                {return expr;}
1767 | <LPAREN> expr = Expression()
1768   try {
1769     <RPAREN>
1770   } catch (ParseException e) {
1771     errorMessage = "')' expected";
1772     errorLevel   = ERROR;
1773     errorStart   = expr.sourceEnd +1;
1774     errorEnd     = expr.sourceEnd +1;
1775     processParseExceptionDebug(e);
1776   }
1777   {return expr;}
1778 }
1779
1780 CastExpression CastExpression() :
1781 {
1782 final ConstantIdentifier type;
1783 final Expression expr;
1784 final Token token,token1;
1785 }
1786 {
1787   token1 = <LPAREN>
1788   (
1789       type = Type()
1790     |
1791       token = <ARRAY> {type = new ConstantIdentifier(token);}
1792   )
1793   <RPAREN> expr = UnaryExpression()
1794   {return new CastExpression(type,expr,token1.sourceStart,expr.sourceEnd);}
1795 }
1796
1797 Expression PostfixExpression() :
1798 {
1799   final Expression expr;
1800   int operator = -1;
1801   Token token = null;
1802 }
1803 {
1804   expr = PrimaryExpression()
1805   [
1806       token = <PLUS_PLUS>   {operator = OperatorIds.PLUS_PLUS;}
1807     |
1808       token = <MINUS_MINUS> {operator = OperatorIds.MINUS_MINUS;}
1809   ]
1810   {
1811     if (operator == -1) {
1812       return expr;
1813     }
1814     return new PostfixedUnaryExpression(expr,operator,token.sourceEnd);
1815   }
1816 }
1817
1818 Expression PrimaryExpression() :
1819 {
1820   Expression expr;
1821   Token token = null;
1822 }
1823 {
1824   [token = <BIT_AND>] expr = refPrimaryExpression(token)
1825   {return expr;}
1826 |
1827   expr = ArrayDeclarator()
1828   {return expr;}
1829 }
1830
1831 Expression refPrimaryExpression(final Token reference) :
1832 {
1833   Expression expr;
1834   Expression expr2 = null;
1835   final Token identifier;
1836 }
1837 {
1838   identifier = <IDENTIFIER>
1839   {
1840     expr = new ConstantIdentifier(identifier);
1841   }
1842   (
1843     <STATICCLASSACCESS> expr2 = ClassIdentifier()
1844     {expr = new ClassAccess(expr,
1845                             expr2,
1846                             ClassAccess.STATIC);}
1847   )*
1848   [ expr2 = Arguments(expr) ]
1849   {
1850     if (expr2 == null) {
1851       if (reference != null) {
1852         ParseException e = generateParseException();
1853         errorMessage = "you cannot use a constant by reference";
1854         errorLevel   = ERROR;
1855         errorStart   = reference.sourceStart;
1856         errorEnd     = reference.sourceEnd;
1857         processParseExceptionDebug(e);
1858       }
1859       return expr;
1860     }
1861     return expr2;
1862   }
1863 |
1864   expr = VariableDeclaratorId()  //todo use the reference parameter ...
1865   [ expr = Arguments(expr) ]
1866   {return expr;}
1867 |
1868   token = <NEW>
1869   expr = ClassIdentifier()
1870   {
1871     int start;
1872     if (reference == null) {
1873       start = token.sourceStart;
1874     } else {
1875       start = reference.sourceStart;
1876     }
1877     expr = new ClassInstantiation(expr,
1878                                   reference != null,
1879                                   start);
1880   }
1881   [ expr = Arguments(expr) ]
1882   {return expr;}
1883 }
1884
1885 /**
1886  * An array declarator.
1887  * array(vars)
1888  * @return an array
1889  */
1890 ArrayInitializer ArrayDeclarator() :
1891 {
1892   final ArrayVariableDeclaration[] vars;
1893   final Token token;
1894 }
1895 {
1896   token = <ARRAY> vars = ArrayInitializer()
1897   {return new ArrayInitializer(vars,
1898                                token.sourceStart,
1899                                PHPParser.token.sourceEnd);}
1900 }
1901
1902 Expression ClassIdentifier():
1903 {
1904   final Expression expr;
1905   final Token token;
1906 }
1907 {
1908   token = <IDENTIFIER>          {return new ConstantIdentifier(token);}
1909 | expr = Type()                 {return expr;}
1910 | expr = VariableDeclaratorId() {return expr;}
1911 }
1912
1913 /**
1914  * Used by Variabledeclaratorid and primarysuffix
1915  */
1916 AbstractVariable VariableSuffix(final AbstractVariable prefix) :
1917 {
1918   Expression expression = null;
1919   final Token classAccessToken,lbrace,rbrace;
1920   Token token;
1921   int pos;
1922 }
1923 {
1924   classAccessToken = <CLASSACCESS>
1925   try {
1926     (
1927       lbrace = <LBRACE> expression = Expression() rbrace = <RBRACE>
1928                 {
1929                  expression = new Variable(expression,
1930                                            lbrace.sourceStart,
1931                                            rbrace.sourceEnd);
1932                 }
1933       |
1934         token = <IDENTIFIER>
1935         {expression = new ConstantIdentifier(token.image,token.sourceStart,token.sourceEnd);}
1936       |
1937         expression = Variable()
1938     )
1939   } catch (ParseException e) {
1940     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', function call or field access expected";
1941     errorLevel   = ERROR;
1942     errorStart = classAccessToken.sourceEnd +1;
1943     errorEnd   = classAccessToken.sourceEnd +1;
1944     processParseExceptionDebug(e);
1945   }
1946   {return new ClassAccess(prefix,
1947                           expression,
1948                           ClassAccess.NORMAL);}
1949 |
1950   token = <LBRACKET> {pos = token.sourceEnd+1;}
1951   [  expression = Expression() {pos = expression.sourceEnd+1;}
1952    | expression = Type()       {pos = expression.sourceEnd+1;}]  //Not good
1953   try {
1954     token = <RBRACKET>
1955     {pos = token.sourceEnd;}
1956   } catch (ParseException e) {
1957     errorMessage = "']' expected";
1958     errorLevel   = ERROR;
1959     errorStart = pos;
1960     errorEnd   = pos;
1961     processParseExceptionDebug(e);
1962   }
1963   {return new ArrayDeclarator(prefix,expression,pos);}
1964 |
1965   token = <LBRACE> {pos = token.sourceEnd+1;}
1966   [  expression = Expression() {pos = expression.sourceEnd+1;}
1967    | expression = Type()       {pos = expression.sourceEnd+1;}]  //Not good
1968   try {
1969     token = <RBRACE>
1970     {pos = token.sourceEnd;}
1971   } catch (ParseException e) {
1972     errorMessage = "']' expected";
1973     errorLevel   = ERROR;
1974     errorStart = pos;
1975     errorEnd   = pos;
1976     processParseExceptionDebug(e);
1977   }
1978   {return new ArrayDeclarator(prefix,expression,pos);}//todo : check braces here
1979 }
1980
1981 Literal Literal() :
1982 {
1983   final Token token;
1984   StringLiteral literal;
1985 }
1986 {
1987   token = <INTEGER_LITERAL>        {return new NumberLiteral(token);}
1988 | token = <FLOATING_POINT_LITERAL> {return new NumberLiteral(token);}
1989 | token = <STRING_LITERAL>         {return new StringLiteral(token);}
1990 | token = <TRUE>                   {return new TrueLiteral(token);}
1991 | token = <FALSE>                  {return new FalseLiteral(token);}
1992 | token = <NULL>                   {return new NullLiteral(token);}
1993 | literal = evaluableString()        {return literal;}
1994 }
1995
1996 StringLiteral evaluableString() :
1997 {
1998   ArrayList list = new ArrayList();
1999   Token start,end;
2000   Token token,lbrace,rbrace;
2001   AbstractVariable var;
2002   Expression expr;
2003 }
2004 {
2005   start = <DOUBLEQUOTE>
2006   (
2007    <DOLLARS>
2008        (
2009         token = <IDENTIFIER> {list.add(new Variable(token.image,
2010                                                     token.sourceStart,
2011                                                     token.sourceEnd));}
2012         |
2013          lbrace = <LBRACE1>
2014          token = <ID>
2015          {list.add(new Variable(token.image,
2016                                 token.sourceStart,
2017                                 token.sourceEnd));}
2018          rbrace = <RBRACE1>
2019        )
2020    )*
2021   end = <DOUBLEQUOTE2>
2022   {
2023   AbstractVariable[] vars = new AbstractVariable[list.size()];
2024   list.toArray(vars);
2025   return new StringLiteral(SimpleCharStream.currentBuffer.substring(start.sourceEnd,end.sourceStart),
2026                            start.sourceStart,
2027                            end.sourceEnd,
2028                            vars);
2029   }
2030 }
2031
2032 FunctionCall Arguments(final Expression func) :
2033 {
2034 Expression[] args = null;
2035 final Token token,lparen;
2036 }
2037 {
2038   lparen = <LPAREN> [ args = ArgumentList() ]
2039   try {
2040     token = <RPAREN>
2041     {return new FunctionCall(func,args,token.sourceEnd);}
2042   } catch (ParseException e) {
2043     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', ')' expected to close the argument list";
2044     errorLevel   = ERROR;
2045     if (args == null) {
2046         errorStart = lparen.sourceEnd+1;
2047         errorEnd   = lparen.sourceEnd+2;
2048     } else {
2049         errorStart = args[args.length-1].sourceEnd+1;
2050         errorEnd   = args[args.length-1].sourceEnd+2;
2051     }
2052     processParseExceptionDebug(e);
2053   }
2054   {
2055   int sourceEnd = (args == null && args.length != 0) ? lparen.sourceEnd+1 : args[args.length-1].sourceEnd;
2056   return new FunctionCall(func,args,sourceEnd);}
2057 }
2058
2059 /**
2060  * An argument list is a list of arguments separated by comma :
2061  * argumentDeclaration() (, argumentDeclaration)*
2062  * @return an array of arguments
2063  */
2064 Expression[] ArgumentList() :
2065 {
2066 Expression arg;
2067 final ArrayList list = new ArrayList();
2068 int pos;
2069 Token token;
2070 }
2071 {
2072   arg = Expression()
2073   {list.add(arg);pos = arg.sourceEnd;}
2074   ( token = <COMMA> {pos = token.sourceEnd;}
2075       try {
2076         arg = Expression()
2077         {list.add(arg);
2078          pos = arg.sourceEnd;}
2079       } catch (ParseException e) {
2080         errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. An expression expected after a comma in argument list";
2081         errorLevel   = ERROR;
2082         errorStart   = pos+1;
2083         errorEnd     = pos+1;
2084         processParseException(e);
2085       }
2086    )*
2087    {
2088    final Expression[] arguments = new Expression[list.size()];
2089    list.toArray(arguments);
2090    return arguments;}
2091 }
2092
2093 /**
2094  * A Statement without break.
2095  * @return a statement
2096  */
2097 Statement StatementNoBreak() :
2098 {
2099   final Statement statement;
2100   Token token = null;
2101 }
2102 {
2103   LOOKAHEAD(2)
2104   statement = expressionStatement()     {return statement;}
2105 | LOOKAHEAD(1)
2106   statement = LabeledStatement()        {return statement;}
2107 | statement = Block()                   {return statement;}
2108 | statement = EmptyStatement()          {return statement;}
2109 | statement = SwitchStatement()         {return statement;}
2110 | statement = IfStatement()             {return statement;}
2111 | statement = WhileStatement()          {return statement;}
2112 | statement = DoStatement()             {return statement;}
2113 | statement = ForStatement()            {return statement;}
2114 | statement = ForeachStatement()        {return statement;}
2115 | statement = ContinueStatement()       {return statement;}
2116 | statement = ReturnStatement()         {return statement;}
2117 | statement = EchoStatement()           {return statement;}
2118 | [token=<AT>] statement = IncludeStatement()
2119   {if (token != null) {
2120     ((InclusionStatement)statement).silent = true;
2121     statement.sourceStart = token.sourceStart;
2122   }
2123   return statement;}
2124 | statement = StaticStatement()         {return statement;}
2125 | statement = GlobalStatement()         {return statement;}
2126 | statement = defineStatement()         {currentSegment.add((Outlineable)statement);return statement;}
2127 }
2128
2129 /**
2130  * A statement expression.
2131  * expression ;
2132  * @return an expression
2133  */
2134 Statement expressionStatement() :
2135 {
2136   final Statement statement;
2137   final Token token;
2138 }
2139 {
2140   statement = Expression()
2141   try {
2142     token = <SEMICOLON>
2143     {statement.sourceEnd = token.sourceEnd;}
2144   } catch (ParseException e) {
2145     if (e.currentToken.next.kind != PHPParserConstants.PHPEND) {
2146       errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected";
2147       errorLevel   = ERROR;
2148       errorStart = statement.sourceEnd+1;
2149       errorEnd   = statement.sourceEnd+1;
2150       processParseExceptionDebug(e);
2151     }
2152   }
2153   {return statement;}
2154 }
2155
2156 Define defineStatement() :
2157 {
2158   Expression defineName,defineValue;
2159   final Token defineToken;
2160   Token token;
2161   int pos;
2162 }
2163 {
2164   defineToken = <DEFINE> {pos = defineToken.sourceEnd+1;}
2165   try {
2166     token = <LPAREN>
2167     {pos = token.sourceEnd+1;}
2168   } catch (ParseException e) {
2169     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', '(' expected";
2170     errorLevel   = ERROR;
2171     errorStart   = pos;
2172     errorEnd     = pos;
2173     processParseExceptionDebug(e);
2174   }
2175   try {
2176     defineName = Expression()
2177     {pos = defineName.sourceEnd+1;}
2178   } catch (ParseException e) {
2179     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', expression expected";
2180     errorLevel   = ERROR;
2181     errorStart   = pos;
2182     errorEnd     = pos;
2183     processParseExceptionDebug(e);
2184     defineName = new StringLiteral(SYNTAX_ERROR_CHAR,pos,pos);
2185   }
2186   try {
2187     token = <COMMA>
2188     {pos = defineName.sourceEnd+1;}
2189   } catch (ParseException e) {
2190     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', ',' expected";
2191     errorLevel   = ERROR;
2192     errorStart   = pos;
2193     errorEnd     = pos;
2194     processParseExceptionDebug(e);
2195   }
2196   try {
2197     defineValue = Expression()
2198     {pos = defineValue.sourceEnd+1;}
2199   } catch (ParseException e) {
2200     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', expression expected";
2201     errorLevel   = ERROR;
2202     errorStart   = pos;
2203     errorEnd     = pos;
2204     processParseExceptionDebug(e);
2205     defineValue = new StringLiteral(SYNTAX_ERROR_CHAR,pos,pos);
2206   }
2207   try {
2208     token = <RPAREN>
2209     {pos = token.sourceEnd+1;}
2210   } catch (ParseException e) {
2211     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', ')' expected";
2212     errorLevel   = ERROR;
2213     errorStart   = pos;
2214     errorEnd     = pos;
2215     processParseExceptionDebug(e);
2216   }
2217   {return new Define(currentSegment,
2218                      defineName,
2219                      defineValue,
2220                      defineToken.sourceStart,
2221                      pos);}
2222 }
2223
2224 /**
2225  * A Normal statement.
2226  */
2227 Statement Statement() :
2228 {
2229   final Statement statement;
2230 }
2231 {
2232   statement = StatementNoBreak() {return statement;}
2233 | statement = BreakStatement()   {return statement;}
2234 }
2235
2236 /**
2237  * An html block inside a php syntax.
2238  */
2239 HTMLBlock htmlBlock() :
2240 {
2241   final int startIndex = nodePtr;
2242   final AstNode[] blockNodes;
2243   final int nbNodes;
2244   final Token phpEnd;
2245 }
2246 {
2247   phpEnd = <PHPEND>
2248   {htmlStart = phpEnd.sourceEnd;}
2249   (phpEchoBlock())*
2250   try {
2251     (<PHPSTARTLONG> | <PHPSTARTSHORT>)
2252     {PHPParser.createNewHTMLCode();}
2253   } catch (ParseException e) {
2254     errorMessage = "unexpected end of file , '<?php' expected";
2255     errorLevel   = ERROR;
2256     errorStart = e.currentToken.sourceStart;
2257     errorEnd   = e.currentToken.sourceEnd;
2258     throw e;
2259   }
2260   {
2261   nbNodes    = nodePtr - startIndex;
2262   if (nbNodes == 0) {
2263     return null;
2264   }
2265   blockNodes = new AstNode[nbNodes];
2266   System.arraycopy(nodes,startIndex+1,blockNodes,0,nbNodes);
2267   nodePtr = startIndex;
2268   return new HTMLBlock(blockNodes);}
2269 }
2270
2271 /**
2272  * An include statement. It's "include" an expression;
2273  */
2274 InclusionStatement IncludeStatement() :
2275 {
2276   Expression expr;
2277   final int keyword;
2278   final InclusionStatement inclusionStatement;
2279   final Token token, token2;
2280   int pos;
2281 }
2282 {
2283       (  token = <REQUIRE>      {keyword = InclusionStatement.REQUIRE;pos=token.sourceEnd;}
2284        | token = <REQUIRE_ONCE> {keyword = InclusionStatement.REQUIRE_ONCE;pos=token.sourceEnd;}
2285        | token = <INCLUDE>      {keyword = InclusionStatement.INCLUDE;pos=token.sourceEnd;}
2286        | token = <INCLUDE_ONCE> {keyword = InclusionStatement.INCLUDE_ONCE;pos=token.sourceEnd;})
2287   try {
2288     expr = Expression()
2289     {pos = expr.sourceEnd;}
2290   } catch (ParseException e) {
2291     if (errorMessage != null) {
2292       throw e;
2293     }
2294     errorMessage = "unexpected token '"+ e.currentToken.next.image+"', expression expected";
2295     errorLevel   = ERROR;
2296     errorStart   = e.currentToken.next.sourceStart;
2297     errorEnd     = e.currentToken.next.sourceEnd;
2298     expr = new ConstantIdentifier(SYNTAX_ERROR_CHAR,pos,pos);
2299     processParseExceptionDebug(e);
2300   }
2301   try {
2302     token2 = <SEMICOLON>
2303     {pos=token2.sourceEnd;}
2304   } catch (ParseException e) {
2305     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected";
2306     errorLevel   = ERROR;
2307     errorStart   = e.currentToken.next.sourceStart;
2308     errorEnd     = e.currentToken.next.sourceEnd;
2309     processParseExceptionDebug(e);
2310   }
2311   {
2312    inclusionStatement = new InclusionStatement(currentSegment,
2313                                                keyword,
2314                                                expr,
2315                                                token.sourceStart,
2316                                                pos);
2317    currentSegment.add(inclusionStatement);
2318    return inclusionStatement;
2319   }
2320 }
2321
2322 PrintExpression PrintExpression() :
2323 {
2324   final Expression expr;
2325   final Token printToken;
2326 }
2327 {
2328   token = <PRINT> expr = Expression()
2329   {return new PrintExpression(expr,token.sourceStart,expr.sourceEnd);}
2330 }
2331
2332 ListExpression ListExpression() :
2333 {
2334   Expression expr = null;
2335   final Expression expression;
2336   final ArrayList list = new ArrayList();
2337   int pos;
2338   final Token listToken, rParen;
2339   Token token;
2340 }
2341 {
2342   listToken = <LIST> {pos = listToken.sourceEnd;}
2343   try {
2344     token = <LPAREN> {pos = token.sourceEnd;}
2345   } catch (ParseException e) {
2346     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', '(' expected";
2347     errorLevel   = ERROR;
2348     errorStart   = listToken.sourceEnd+1;
2349     errorEnd     = listToken.sourceEnd+1;
2350     processParseExceptionDebug(e);
2351   }
2352   [
2353     expr = VariableDeclaratorId()
2354     {list.add(expr);pos = expr.sourceEnd;}
2355   ]
2356   {if (expr == null) list.add(null);}
2357   (
2358     try {
2359       token = <COMMA>
2360       {pos = token.sourceEnd;}
2361     } catch (ParseException e) {
2362       errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', ',' expected";
2363       errorLevel   = ERROR;
2364       errorStart   = pos+1;
2365       errorEnd     = pos+1;
2366       processParseExceptionDebug(e);
2367     }
2368     [expr = VariableDeclaratorId() {list.add(expr);pos = expr.sourceEnd;}]
2369   )*
2370   try {
2371     rParen = <RPAREN>
2372     {pos = rParen.sourceEnd;}
2373   } catch (ParseException e) {
2374     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"', ')' expected";
2375     errorLevel   = ERROR;
2376     errorStart = pos+1;
2377     errorEnd   = pos+1;
2378       processParseExceptionDebug(e);
2379   }
2380   [ <ASSIGN> expression = Expression()
2381     {
2382     final AbstractVariable[] vars = new AbstractVariable[list.size()];
2383     list.toArray(vars);
2384     return new ListExpression(vars,
2385                               expression,
2386                               listToken.sourceStart,
2387                               expression.sourceEnd);}
2388   ]
2389   {
2390     final AbstractVariable[] vars = new AbstractVariable[list.size()];
2391     list.toArray(vars);
2392     return new ListExpression(vars,listToken.sourceStart,pos);}
2393 }
2394
2395 /**
2396  * An echo statement.
2397  * echo anyexpression (, otherexpression)*
2398  */
2399 EchoStatement EchoStatement() :
2400 {
2401   final ArrayList expressions = new ArrayList();
2402   Expression expr;
2403   Token token;
2404   Token token2 = null;
2405 }
2406 {
2407   token = <ECHO> expr = Expression()
2408   {expressions.add(expr);}
2409   (
2410     <COMMA> expr = Expression()
2411     {expressions.add(expr);}
2412   )*
2413   try {
2414     token2 = <SEMICOLON>
2415   } catch (ParseException e) {
2416     if (e.currentToken.next.kind != 4) {
2417       errorMessage = "';' expected after 'echo' statement";
2418       errorLevel   = ERROR;
2419       errorStart   = e.currentToken.sourceEnd;
2420       errorEnd     = e.currentToken.sourceEnd;
2421       processParseExceptionDebug(e);
2422     }
2423   }
2424   {
2425    final Expression[] exprs = new Expression[expressions.size()];
2426    expressions.toArray(exprs);
2427    if (token2 == null) {
2428      return new EchoStatement(exprs,token.sourceStart, exprs[exprs.length-1].sourceEnd);
2429    }
2430    return new EchoStatement(exprs,token.sourceStart, token2.sourceEnd);
2431    }
2432 }
2433
2434 GlobalStatement GlobalStatement() :
2435 {
2436    Variable expr;
2437    final ArrayList vars = new ArrayList();
2438    final GlobalStatement global;
2439    final Token token, token2;
2440    int pos;
2441 }
2442 {
2443   token = <GLOBAL>
2444     expr = Variable()
2445     {vars.add(expr);pos = expr.sourceEnd+1;}
2446   (<COMMA>
2447     expr = Variable()
2448     {vars.add(expr);pos = expr.sourceEnd+1;}
2449   )*
2450   try {
2451     token2 = <SEMICOLON>
2452     {pos = token2.sourceEnd+1;}
2453   } catch (ParseException e) {
2454     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. a ';' was expected";
2455     errorLevel   = ERROR;
2456     errorStart = pos;
2457     errorEnd   = pos;
2458     processParseExceptionDebug(e);
2459   }
2460     {
2461     final Variable[] variables = new Variable[vars.size()];
2462     vars.toArray(variables);
2463     global = new GlobalStatement(currentSegment,
2464                                  variables,
2465                                  token.sourceStart,
2466                                  pos);
2467     currentSegment.add(global);
2468     return global;}
2469 }
2470
2471 StaticStatement StaticStatement() :
2472 {
2473   final ArrayList vars = new ArrayList();
2474   VariableDeclaration expr;
2475   final Token token, token2;
2476   int pos;
2477 }
2478 {
2479   token = <STATIC> expr = VariableDeclarator() {vars.add(expr);pos = expr.sourceEnd+1;}
2480   (
2481     <COMMA> expr = VariableDeclarator() {vars.add(expr);pos = expr.sourceEnd+1;}
2482   )*
2483   try {
2484     token2 = <SEMICOLON>
2485     {pos = token2.sourceEnd+1;}
2486   } catch (ParseException e) {
2487     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. a ';' was expected";
2488     errorLevel   = ERROR;
2489     errorStart = pos;
2490     errorEnd   = pos;
2491     processParseException(e);
2492   }
2493     {
2494     final VariableDeclaration[] variables = new VariableDeclaration[vars.size()];
2495     vars.toArray(variables);
2496     return new StaticStatement(variables,
2497                                token.sourceStart,
2498                                pos);}
2499 }
2500
2501 LabeledStatement LabeledStatement() :
2502 {
2503   final Token label;
2504   final Statement statement;
2505 }
2506 {
2507   label = <IDENTIFIER> <COLON> statement = Statement()
2508   {return new LabeledStatement(label.image,statement,label.sourceStart,statement.sourceEnd);}
2509 }
2510
2511 /**
2512  * A Block is
2513  * {
2514  * statements
2515  * }.
2516  * @return a block
2517  */
2518 Block Block() :
2519 {
2520   final ArrayList list = new ArrayList();
2521   Statement statement;
2522   final Token token, token2;
2523   int pos,start;
2524 }
2525 {
2526   try {
2527     token = <LBRACE>
2528     {pos = token.sourceEnd+1;start=token.sourceStart;}
2529   } catch (ParseException e) {
2530     errorMessage = "'{' expected";
2531     errorLevel   = ERROR;
2532     pos = PHPParser.token.sourceEnd+1;
2533     start=pos;
2534     errorStart = pos;
2535     errorEnd   = pos;
2536     processParseExceptionDebug(e);
2537   }
2538   ( statement = BlockStatement() {list.add(statement);pos = statement.sourceEnd+1;}
2539   | statement = htmlBlock()      {if (statement != null) {
2540                                     list.add(statement);
2541                                     pos = statement.sourceEnd+1;
2542                                   }
2543                                   pos = PHPParser.token.sourceEnd+1;
2544                                  }
2545   )*
2546   try {
2547     token2 = <RBRACE>
2548     {pos = token2.sourceEnd+1;}
2549   } catch (ParseException e) {
2550     errorMessage = "unexpected token : '"+ e.currentToken.image +"', '}' expected";
2551     errorLevel   = ERROR;
2552     errorStart = pos;
2553     errorEnd   = pos;
2554     processParseExceptionDebug(e);
2555   }
2556   {
2557   final Statement[] statements = new Statement[list.size()];
2558   list.toArray(statements);
2559   return new Block(statements,start,pos);}
2560 }
2561
2562 Statement BlockStatement() :
2563 {
2564   final Statement statement;
2565 }
2566 {
2567   try {
2568     statement = Statement()         {if (phpDocument == currentSegment) pushOnAstNodes(statement);
2569                                      return statement;}
2570   } catch (ParseException e) {
2571     errorMessage = "unexpected token : '"+ e.currentToken.image +"', a statement was expected";
2572     errorLevel   = ERROR;
2573     errorStart = e.currentToken.sourceStart;
2574     errorEnd   = e.currentToken.sourceEnd;
2575     throw e;
2576   }
2577 | statement = ClassDeclaration()  {return statement;}
2578 | statement = MethodDeclaration() {if (phpDocument == currentSegment) pushOnAstNodes(statement);
2579                                    currentSegment.add((MethodDeclaration) statement);
2580                                    ((MethodDeclaration) statement).analyzeCode();
2581                                    return statement;}
2582 }
2583
2584 /**
2585  * A Block statement that will not contain any 'break'
2586  */
2587 Statement BlockStatementNoBreak() :
2588 {
2589   final Statement statement;
2590 }
2591 {
2592   statement = StatementNoBreak()  {return statement;}
2593 | statement = ClassDeclaration()  {return statement;}
2594 | statement = MethodDeclaration() {currentSegment.add((MethodDeclaration) statement);
2595                                    ((MethodDeclaration) statement).analyzeCode();
2596                                    return statement;}
2597 }
2598
2599 /**
2600  * used only by ForInit()
2601  */
2602 Expression[] LocalVariableDeclaration() :
2603 {
2604   final ArrayList list = new ArrayList();
2605   Expression var;
2606 }
2607 {
2608   var = Expression()
2609   {list.add(var);}
2610   ( <COMMA> var = Expression() {list.add(var);})*
2611   {
2612     final Expression[] vars = new Expression[list.size()];
2613     list.toArray(vars);
2614     return vars;
2615   }
2616 }
2617
2618 /**
2619  * used only by LocalVariableDeclaration().
2620  */
2621 VariableDeclaration LocalVariableDeclarator() :
2622 {
2623   final Variable varName;
2624   Expression initializer = null;
2625 }
2626 {
2627   varName = Variable() [ <ASSIGN> initializer = Expression() ]
2628   {
2629    if (initializer == null) {
2630     return new VariableDeclaration(currentSegment,
2631                                    varName,
2632                                    varName.sourceStart,
2633                                    varName.sourceEnd);
2634    }
2635     return new VariableDeclaration(currentSegment,
2636                                    varName,
2637                                    initializer,
2638                                    VariableDeclaration.EQUAL,
2639                                    varName.sourceStart);
2640   }
2641 }
2642
2643 EmptyStatement EmptyStatement() :
2644 {
2645   final Token token;
2646 }
2647 {
2648   token = <SEMICOLON>
2649   {return new EmptyStatement(token.sourceStart,token.sourceEnd);}
2650 }
2651
2652 /**
2653  * used only by StatementExpressionList() which is used only by ForInit() and ForStatement()
2654  */
2655 Expression StatementExpression() :
2656 {
2657   final Expression expr;
2658   final Token operator;
2659 }
2660 {
2661   expr = PreIncDecExpression() {return expr;}
2662 |
2663   expr = PrimaryExpression()
2664   [ operator = <PLUS_PLUS> {return new PostfixedUnaryExpression(expr,
2665                                                                 OperatorIds.PLUS_PLUS,
2666                                                                 operator.sourceEnd);}
2667   | operator = <MINUS_MINUS> {return new PostfixedUnaryExpression(expr,
2668                                                                   OperatorIds.MINUS_MINUS,
2669                                                                   operator.sourceEnd);}
2670   ]
2671   {return expr;}
2672 }
2673
2674 SwitchStatement SwitchStatement() :
2675 {
2676   Expression variable;
2677   final AbstractCase[] cases;
2678   final Token switchToken,lparenToken,rparenToken;
2679   int pos;
2680 }
2681 {
2682   switchToken = <SWITCH> {pos = switchToken.sourceEnd+1;}
2683   try {
2684     lparenToken = <LPAREN>
2685     {pos = lparenToken.sourceEnd+1;}
2686   } catch (ParseException e) {
2687     errorMessage = "'(' expected after 'switch'";
2688     errorLevel   = ERROR;
2689     errorStart = pos;
2690     errorEnd   = pos;
2691     processParseExceptionDebug(e);
2692   }
2693   try {
2694     variable = Expression() {pos = variable.sourceEnd+1;}
2695   } catch (ParseException e) {
2696     if (errorMessage != null) {
2697       throw e;
2698     }
2699     errorMessage = "expression expected";
2700     errorLevel   = ERROR;
2701     errorStart = pos;
2702     errorEnd   = pos;
2703     processParseExceptionDebug(e);
2704     variable = new ConstantIdentifier(SYNTAX_ERROR_CHAR,pos,pos);
2705   }
2706   try {
2707     rparenToken = <RPAREN> {pos = rparenToken.sourceEnd+1;}
2708   } catch (ParseException e) {
2709     errorMessage = "')' expected";
2710     errorLevel   = ERROR;
2711     errorStart = pos;
2712     errorEnd   = pos;
2713     processParseExceptionDebug(e);
2714   }
2715   (  cases = switchStatementBrace()
2716    | cases = switchStatementColon(switchToken.sourceStart, switchToken.sourceEnd))
2717   {return new SwitchStatement(variable,
2718                               cases,
2719                               switchToken.sourceStart,
2720                               PHPParser.token.sourceEnd);}
2721 }
2722
2723 AbstractCase[] switchStatementBrace() :
2724 {
2725   AbstractCase cas;
2726   final ArrayList cases = new ArrayList();
2727   Token token;
2728   int pos;
2729 }
2730 {
2731   token = <LBRACE> {pos = token.sourceEnd;}
2732  ( cas = switchLabel0() {cases.add(cas);pos = cas.sourceEnd;})*
2733   try {
2734     token = <RBRACE>
2735     {pos = token.sourceEnd;}
2736   } catch (ParseException e) {
2737     errorMessage = "'}' expected";
2738     errorLevel   = ERROR;
2739     errorStart = pos+1;
2740     errorEnd   = pos+1;
2741     processParseExceptionDebug(e);
2742   }
2743   {
2744     final AbstractCase[] abcase = new AbstractCase[cases.size()];
2745     cases.toArray(abcase);
2746     return abcase;
2747   }
2748 }
2749
2750 /**
2751  * A Switch statement with : ... endswitch;
2752  * @param start the begin offset of the switch
2753  * @param end the end offset of the switch
2754  */
2755 AbstractCase[] switchStatementColon(final int start, final int end) :
2756 {
2757   AbstractCase cas;
2758   final ArrayList cases = new ArrayList();
2759   Token token;
2760   int pos;
2761 }
2762 {
2763   token = <COLON> {pos = token.sourceEnd;}
2764   {try {
2765   setMarker(fileToParse,
2766             "Ugly syntax detected, you should switch () {...} instead of switch (): ... enswitch;",
2767             start,
2768             end,
2769             INFO,
2770             "Line " + token.beginLine);
2771   } catch (CoreException e) {
2772     PHPeclipsePlugin.log(e);
2773   }}
2774   ( cas = switchLabel0() {cases.add(cas);pos = cas.sourceEnd;})*
2775   try {
2776     token = <ENDSWITCH> {pos = token.sourceEnd;}
2777   } catch (ParseException e) {
2778     errorMessage = "'endswitch' expected";
2779     errorLevel   = ERROR;
2780     errorStart = pos+1;
2781     errorEnd   = pos+1;
2782     processParseExceptionDebug(e);
2783   }
2784   try {
2785     token = <SEMICOLON> {pos = token.sourceEnd;}
2786   } catch (ParseException e) {
2787     errorMessage = "';' expected after 'endswitch' keyword";
2788     errorLevel   = ERROR;
2789     errorStart = pos+1;
2790     errorEnd   = pos+1;
2791     processParseExceptionDebug(e);
2792   }
2793   {
2794     final AbstractCase[] abcase = new AbstractCase[cases.size()];
2795     cases.toArray(abcase);
2796     return abcase;
2797   }
2798 }
2799
2800 AbstractCase switchLabel0() :
2801 {
2802   final Expression expr;
2803   Statement statement;
2804   final ArrayList stmts = new ArrayList();
2805   final Token token = PHPParser.token;
2806 }
2807 {
2808   expr = SwitchLabel()
2809   ( statement = BlockStatementNoBreak() {stmts.add(statement);}
2810   | statement = htmlBlock()             {if (statement != null) {stmts.add(statement);}}
2811   | statement = BreakStatement()        {stmts.add(statement);})*
2812   //[ statement = BreakStatement()        {stmts.add(statement);}]
2813   {
2814     final int listSize = stmts.size();
2815     final Statement[] stmtsArray = new Statement[listSize];
2816     stmts.toArray(stmtsArray);
2817     if (expr == null) {//it's a default
2818       return new DefaultCase(stmtsArray,token.sourceStart,stmtsArray[listSize-1].sourceEnd);
2819     }
2820     if (listSize != 0) {
2821       return new Case(expr,stmtsArray,expr.sourceStart,stmtsArray[listSize-1].sourceEnd);
2822     } else {
2823       return new Case(expr,stmtsArray,expr.sourceStart,expr.sourceEnd);
2824     }
2825   }
2826 }
2827
2828 /**
2829  * A SwitchLabel.
2830  * case Expression() :
2831  * default :
2832  * @return the if it was a case and null if not
2833  */
2834 Expression SwitchLabel() :
2835 {
2836   final Expression expr;
2837 }
2838 {
2839   token = <CASE>
2840   try {
2841     expr = Expression()
2842   } catch (ParseException e) {
2843     if (errorMessage != null) throw e;
2844     errorMessage = "expression expected after 'case' keyword";
2845     errorLevel   = ERROR;
2846     errorStart = token.sourceEnd +1;
2847     errorEnd   = token.sourceEnd +1;
2848     throw e;
2849   }
2850   try {
2851     token = <COLON>
2852   } catch (ParseException e) {
2853     errorMessage = "':' expected after case expression";
2854     errorLevel   = ERROR;
2855     errorStart = expr.sourceEnd+1;
2856     errorEnd   = expr.sourceEnd+1;
2857     processParseExceptionDebug(e);
2858   }
2859   {return expr;}
2860 |
2861   token = <_DEFAULT>
2862   try {
2863     <COLON>
2864   } catch (ParseException e) {
2865     errorMessage = "':' expected after 'default' keyword";
2866     errorLevel   = ERROR;
2867     errorStart = token.sourceEnd+1;
2868     errorEnd   = token.sourceEnd+1;
2869     processParseExceptionDebug(e);
2870   }
2871   {return null;}
2872 }
2873
2874 Break BreakStatement() :
2875 {
2876   Expression expression = null;
2877   final Token token, token2;
2878   int pos;
2879 }
2880 {
2881   token = <BREAK> {pos = token.sourceEnd+1;}
2882   [ expression = Expression() {pos = expression.sourceEnd+1;}]
2883   try {
2884     token2 = <SEMICOLON>
2885     {pos = token2.sourceEnd;}
2886   } catch (ParseException e) {
2887     errorMessage = "';' expected after 'break' keyword";
2888     errorLevel   = ERROR;
2889     errorStart = pos;
2890     errorEnd   = pos;
2891     processParseExceptionDebug(e);
2892   }
2893   {return new Break(expression, token.sourceStart, pos);}
2894 }
2895
2896 IfStatement IfStatement() :
2897 {
2898   final Expression condition;
2899   final IfStatement ifStatement;
2900   Token token;
2901 }
2902 {
2903   token = <IF> condition = Condition("if")
2904   ifStatement = IfStatement0(condition,token.sourceStart,token.sourceEnd)
2905   {return ifStatement;}
2906 }
2907
2908
2909 Expression Condition(final String keyword) :
2910 {
2911   final Expression condition;
2912 }
2913 {
2914   try {
2915     <LPAREN>
2916   } catch (ParseException e) {
2917     errorMessage = "'(' expected after " + keyword + " keyword";
2918     errorLevel   = ERROR;
2919     errorStart = PHPParser.token.sourceEnd + 1;
2920     errorEnd   = PHPParser.token.sourceEnd + 1;
2921     processParseExceptionDebug(e);
2922   }
2923   condition = Expression()
2924   try {
2925      <RPAREN>
2926   } catch (ParseException e) {
2927     errorMessage = "')' expected after " + keyword + " keyword";
2928     errorLevel   = ERROR;
2929     errorStart = condition.sourceEnd+1;
2930     errorEnd   = condition.sourceEnd+1;
2931     processParseExceptionDebug(e);
2932   }
2933   {return condition;}
2934 }
2935
2936 IfStatement IfStatement0(final Expression condition, final int start,final int end) :
2937 {
2938   Statement statement;
2939   final Statement stmt;
2940   final Statement[] statementsArray;
2941   ElseIf elseifStatement;
2942   Else elseStatement = null;
2943   final ArrayList stmts;
2944   final ArrayList elseIfList = new ArrayList();
2945   final ElseIf[] elseIfs;
2946   int pos = SimpleCharStream.getPosition();
2947   final int endStatements;
2948 }
2949 {
2950   <COLON>
2951   {stmts = new ArrayList();}
2952   (  statement = Statement() {stmts.add(statement);}
2953    | statement = htmlBlock() {if (statement != null) {stmts.add(statement);}})*
2954    {endStatements = SimpleCharStream.getPosition();}
2955    (elseifStatement = ElseIfStatementColon() {elseIfList.add(elseifStatement);})*
2956    [elseStatement = ElseStatementColon()]
2957
2958   {try {
2959   setMarker(fileToParse,
2960             "Ugly syntax detected, you should if () {...} instead of if (): ... endif;",
2961             start,
2962             end,
2963             INFO,
2964             "Line " + token.beginLine);
2965   } catch (CoreException e) {
2966     PHPeclipsePlugin.log(e);
2967   }}
2968   try {
2969     <ENDIF>
2970   } catch (ParseException e) {
2971     errorMessage = "'endif' expected";
2972     errorLevel   = ERROR;
2973     errorStart = e.currentToken.sourceStart;
2974     errorEnd   = e.currentToken.sourceEnd;
2975     throw e;
2976   }
2977   try {
2978     <SEMICOLON>
2979   } catch (ParseException e) {
2980     errorMessage = "';' expected after 'endif' keyword";
2981     errorLevel   = ERROR;
2982     errorStart = e.currentToken.sourceStart;
2983     errorEnd   = e.currentToken.sourceEnd;
2984     throw e;
2985   }
2986     {
2987     elseIfs = new ElseIf[elseIfList.size()];
2988     elseIfList.toArray(elseIfs);
2989     if (stmts.size() == 1) {
2990       return new IfStatement(condition,
2991                              (Statement) stmts.get(0),
2992                               elseIfs,
2993                               elseStatement,
2994                               pos,
2995                               SimpleCharStream.getPosition());
2996     } else {
2997       statementsArray = new Statement[stmts.size()];
2998       stmts.toArray(statementsArray);
2999       return new IfStatement(condition,
3000                              new Block(statementsArray,pos,endStatements),
3001                              elseIfs,
3002                              elseStatement,
3003                              pos,
3004                              SimpleCharStream.getPosition());
3005     }
3006     }
3007
3008 |
3009   (stmt = Statement() | stmt = htmlBlock())
3010   ( LOOKAHEAD(1) elseifStatement = ElseIfStatement() {elseIfList.add(elseifStatement);})*
3011   [ LOOKAHEAD(1)
3012     <ELSE>
3013     try {
3014       {pos = SimpleCharStream.getPosition();}
3015       statement = Statement()
3016       {elseStatement = new Else(statement,pos,SimpleCharStream.getPosition());}
3017     } catch (ParseException e) {
3018       if (errorMessage != null) {
3019         throw e;
3020       }
3021       errorMessage = "unexpected token '"+e.currentToken.next.image+"', a statement was expected";
3022       errorLevel   = ERROR;
3023       errorStart = e.currentToken.sourceStart;
3024       errorEnd   = e.currentToken.sourceEnd;
3025       throw e;
3026     }
3027   ]
3028   {
3029     elseIfs = new ElseIf[elseIfList.size()];
3030     elseIfList.toArray(elseIfs);
3031     return new IfStatement(condition,
3032                            stmt,
3033                            elseIfs,
3034                            elseStatement,
3035                            pos,
3036                            SimpleCharStream.getPosition());}
3037 }
3038
3039 ElseIf ElseIfStatementColon() :
3040 {
3041   final Expression condition;
3042   Statement statement;
3043   final ArrayList list = new ArrayList();
3044   final Token elseifToken;
3045 }
3046 {
3047   elseifToken = <ELSEIF> condition = Condition("elseif")
3048   <COLON> (  statement = Statement() {list.add(statement);}
3049            | statement = htmlBlock() {if (statement != null) {list.add(statement);}})*
3050   {
3051   final int sizeList = list.size();
3052   final Statement[] stmtsArray = new Statement[sizeList];
3053   list.toArray(stmtsArray);
3054   return new ElseIf(condition,stmtsArray ,
3055                     elseifToken.sourceStart,
3056                     stmtsArray[sizeList-1].sourceEnd);}
3057 }
3058
3059 Else ElseStatementColon() :
3060 {
3061   Statement statement;
3062   final ArrayList list = new ArrayList();
3063   final Token elseToken;
3064 }
3065 {
3066   elseToken = <ELSE> <COLON> (  statement = Statement() {list.add(statement);}
3067                   | statement = htmlBlock() {if (statement != null) {list.add(statement);}})*
3068   {
3069   final int sizeList = list.size();
3070   final Statement[] stmtsArray = new Statement[sizeList];
3071   list.toArray(stmtsArray);
3072   return new Else(stmtsArray,elseToken.sourceStart,stmtsArray[sizeList-1].sourceEnd);}
3073 }
3074
3075 ElseIf ElseIfStatement() :
3076 {
3077   final Expression condition;
3078   //final Statement statement;
3079   final Token elseifToken;
3080   final Statement[] statement = new Statement[1];
3081 }
3082 {
3083   elseifToken = <ELSEIF> condition = Condition("elseif") statement[0] = Statement()
3084   {
3085   return new ElseIf(condition,statement,elseifToken.sourceStart,statement[0].sourceEnd);}
3086 }
3087
3088 WhileStatement WhileStatement() :
3089 {
3090   final Expression condition;
3091   final Statement action;
3092   final Token whileToken;
3093 }
3094 {
3095   whileToken = <WHILE>
3096     condition = Condition("while")
3097     action    = WhileStatement0(whileToken.sourceStart,whileToken.sourceEnd)
3098     {return new WhileStatement(condition,action,whileToken.sourceStart,action.sourceEnd);}
3099 }
3100
3101 Statement WhileStatement0(final int start, final int end) :
3102 {
3103   Statement statement;
3104   final ArrayList stmts = new ArrayList();
3105   final int pos = SimpleCharStream.getPosition();
3106 }
3107 {
3108   <COLON> (statement = Statement() {stmts.add(statement);})*
3109   {try {
3110   setMarker(fileToParse,
3111             "Ugly syntax detected, you should while () {...} instead of while (): ... endwhile;",
3112             start,
3113             end,
3114             INFO,
3115             "Line " + token.beginLine);
3116   } catch (CoreException e) {
3117     PHPeclipsePlugin.log(e);
3118   }}
3119   try {
3120     <ENDWHILE>
3121   } catch (ParseException e) {
3122     errorMessage = "'endwhile' expected";
3123     errorLevel   = ERROR;
3124     errorStart = e.currentToken.sourceStart;
3125     errorEnd   = e.currentToken.sourceEnd;
3126     throw e;
3127   }
3128   try {
3129     <SEMICOLON>
3130     {
3131     final Statement[] stmtsArray = new Statement[stmts.size()];
3132     stmts.toArray(stmtsArray);
3133     return new Block(stmtsArray,pos,SimpleCharStream.getPosition());}
3134   } catch (ParseException e) {
3135     errorMessage = "';' expected after 'endwhile' keyword";
3136     errorLevel   = ERROR;
3137     errorStart = e.currentToken.sourceStart;
3138     errorEnd   = e.currentToken.sourceEnd;
3139     throw e;
3140   }
3141 |
3142   statement = Statement()
3143   {return statement;}
3144 }
3145
3146 DoStatement DoStatement() :
3147 {
3148   final Statement action;
3149   final Expression condition;
3150   final Token token;
3151   Token token2 = null;
3152 }
3153 {
3154   token = <DO> action = Statement() <WHILE> condition = Condition("while")
3155   try {
3156     token2 = <SEMICOLON>
3157   } catch (ParseException e) {
3158     errorMessage = "unexpected token : '"+ e.currentToken.next.image +"'. A ';' was expected";
3159     errorLevel   = ERROR;
3160     errorStart = condition.sourceEnd+1;
3161     errorEnd   = condition.sourceEnd+1;
3162     processParseExceptionDebug(e);
3163   }
3164   {
3165     if (token2 == null) {
3166       return new DoStatement(condition,action,token.sourceStart,condition.sourceEnd);
3167     }
3168     return new DoStatement(condition,action,token.sourceStart,token2.sourceEnd);
3169   }
3170 }
3171
3172 ForeachStatement ForeachStatement() :
3173 {
3174   Statement statement = null;
3175   Expression expression = null;
3176   ArrayVariableDeclaration variable = null;
3177   Token foreachToken;
3178   Token lparenToken = null;
3179   Token asToken = null;
3180   Token rparenToken = null;
3181   int pos;
3182 }
3183 {
3184   foreachToken = <FOREACH>
3185   try {
3186     lparenToken = <LPAREN>
3187     {pos = lparenToken.sourceEnd+1;}
3188   } catch (ParseException e) {
3189     errorMessage = "'(' expected after 'foreach' keyword";
3190     errorLevel   = ERROR;
3191     errorStart = e.currentToken.sourceStart;
3192     errorEnd   = e.currentToken.sourceEnd;
3193     processParseExceptionDebug(e);
3194     {pos = foreachToken.sourceEnd+1;}
3195   }
3196   try {
3197     expression = Expression()
3198     {pos = expression.sourceEnd+1;}
3199   } catch (ParseException e) {
3200     errorMessage = "variable expected";
3201     errorLevel   = ERROR;
3202     errorStart = e.currentToken.sourceStart;
3203     errorEnd   = e.currentToken.sourceEnd;
3204     processParseExceptionDebug(e);
3205   }
3206   try {
3207     asToken = <AS>
3208     {pos = asToken.sourceEnd+1;}
3209   } catch (ParseException e) {
3210     errorMessage = "'as' expected";
3211     errorLevel   = ERROR;
3212     errorStart = e.currentToken.sourceStart;
3213     errorEnd   = e.currentToken.sourceEnd;
3214     processParseExceptionDebug(e);
3215   }
3216   try {
3217     variable = ArrayVariable()
3218     {pos = variable.sourceEnd+1;}
3219   } catch (ParseException e) {
3220     if (errorMessage != null) throw e;
3221     errorMessage = "variable expected";
3222     errorLevel   = ERROR;
3223     errorStart = e.currentToken.sourceStart;
3224     errorEnd   = e.currentToken.sourceEnd;
3225     processParseExceptionDebug(e);
3226   }
3227   try {
3228     rparenToken = <RPAREN>
3229     {pos = rparenToken.sourceEnd+1;}
3230   } catch (ParseException e) {
3231     errorMessage = "')' expected after 'foreach' keyword";
3232     errorLevel   = ERROR;
3233     errorStart = e.currentToken.sourceStart;
3234     errorEnd   = e.currentToken.sourceEnd;
3235     processParseExceptionDebug(e);
3236   }
3237   try {
3238     statement = Statement()
3239     {pos = rparenToken.sourceEnd+1;}
3240   } catch (ParseException e) {
3241     if (errorMessage != null) throw e;
3242     errorMessage = "statement expected";
3243     errorLevel   = ERROR;
3244     errorStart = e.currentToken.sourceStart;
3245     errorEnd   = e.currentToken.sourceEnd;
3246     processParseExceptionDebug(e);
3247   }
3248   {return new ForeachStatement(expression,
3249                                variable,
3250                                statement,
3251                                foreachToken.sourceStart,
3252                                statement.sourceEnd);}
3253
3254 }
3255
3256 /**
3257  * a for declaration.
3258  * @return a node representing the for statement
3259  */
3260 ForStatement ForStatement() :
3261 {
3262 final Token token,tokenEndFor,token2,tokenColon;
3263 int pos;
3264 Expression[] initializations = null;
3265 Expression condition = null;
3266 Expression[] increments = null;
3267 Statement action;
3268 final ArrayList list = new ArrayList();
3269 }
3270 {
3271   token = <FOR>
3272   try {
3273     <LPAREN>
3274   } catch (ParseException e) {
3275     errorMessage = "'(' expected after 'for' keyword";
3276     errorLevel   = ERROR;
3277     errorStart = token.sourceEnd;
3278     errorEnd   = token.sourceEnd +1;
3279     processParseExceptionDebug(e);
3280   }
3281      [ initializations = ForInit() ] <SEMICOLON>
3282      [ condition = Expression() ] <SEMICOLON>
3283      [ increments = StatementExpressionList() ] <RPAREN>
3284     (
3285       action = Statement()
3286       {return new ForStatement(initializations,
3287                                condition,
3288                                increments,
3289                                action,
3290                                token.sourceStart,
3291                                action.sourceEnd);}
3292     |
3293       tokenColon = <COLON> {pos = tokenColon.sourceEnd+1;}
3294       (action = Statement() {list.add(action);pos = action.sourceEnd+1;})*
3295       {
3296         try {
3297         setMarker(fileToParse,
3298                   "Ugly syntax detected, you should for () {...} instead of for (): ... endfor;",
3299                   token.sourceStart,
3300                   token.sourceEnd,
3301                   INFO,
3302                   "Line " + token.beginLine);
3303         } catch (CoreException e) {
3304           PHPeclipsePlugin.log(e);
3305         }
3306       }
3307       try {
3308         tokenEndFor = <ENDFOR>
3309         {pos = tokenEndFor.sourceEnd+1;}
3310       } catch (ParseException e) {
3311         errorMessage = "'endfor' expected";
3312         errorLevel   = ERROR;
3313         errorStart = pos;
3314         errorEnd   = pos;
3315         processParseExceptionDebug(e);
3316       }
3317       try {
3318         token2 = <SEMICOLON>
3319         {pos = token2.sourceEnd+1;}
3320       } catch (ParseException e) {
3321         errorMessage = "';' expected after 'endfor' keyword";
3322         errorLevel   = ERROR;
3323         errorStart = pos;
3324         errorEnd   = pos;
3325         processParseExceptionDebug(e);
3326       }
3327       {
3328       final Statement[] stmtsArray = new Statement[list.size()];
3329       list.toArray(stmtsArray);
3330       return new ForStatement(initializations,
3331                               condition,
3332                               increments,
3333                               new Block(stmtsArray,
3334                                         stmtsArray[0].sourceStart,
3335                                         stmtsArray[stmtsArray.length-1].sourceEnd),
3336                               token.sourceStart,
3337                               pos);}
3338     )
3339 }
3340
3341 Expression[] ForInit() :
3342 {
3343   final Expression[] exprs;
3344 }
3345 {
3346   LOOKAHEAD(LocalVariableDeclaration())
3347   exprs = LocalVariableDeclaration()
3348   {return exprs;}
3349 |
3350   exprs = StatementExpressionList()
3351   {return exprs;}
3352 }
3353
3354 Expression[] StatementExpressionList() :
3355 {
3356   final ArrayList list = new ArrayList();
3357   final Expression expr;
3358 }
3359 {
3360   expr = Expression()   {list.add(expr);}
3361   (<COMMA> Expression() {list.add(expr);})*
3362   {
3363     final Expression[] exprsArray = new Expression[list.size()];
3364     list.toArray(exprsArray);
3365     return exprsArray;
3366   }
3367 }
3368
3369 Continue ContinueStatement() :
3370 {
3371   Expression expr = null;
3372   final Token token;
3373   Token token2 = null;
3374 }
3375 {
3376   token = <CONTINUE> [ expr = Expression() ]
3377   try {
3378     token2 = <SEMICOLON>
3379   } catch (ParseException e) {
3380     errorMessage = "';' expected after 'continue' statement";
3381     errorLevel   = ERROR;
3382     if (expr == null) {
3383       errorStart = token.sourceEnd+1;
3384       errorEnd   = token.sourceEnd+1;
3385     } else {
3386       errorStart = expr.sourceEnd+1;
3387       errorEnd   = expr.sourceEnd+1;
3388     }
3389     processParseExceptionDebug(e);
3390   }
3391   {
3392     if (token2 == null) {
3393       if (expr == null) {
3394         return new Continue(expr,token.sourceStart,token.sourceEnd);
3395       }
3396       return new Continue(expr,token.sourceStart,expr.sourceEnd);
3397     }
3398     return new Continue(expr,token.sourceStart,token2.sourceEnd);
3399   }
3400 }
3401
3402 ReturnStatement ReturnStatement() :
3403 {
3404   Expression expr = null;
3405   final Token token;
3406   Token token2 = null;
3407 }
3408 {
3409   token = <RETURN> [ expr = Expression() ]
3410   try {
3411     token2 = <SEMICOLON>
3412   } catch (ParseException e) {
3413     errorMessage = "';' expected after 'return' statement";
3414     errorLevel   = ERROR;
3415     if (expr == null) {
3416       errorStart = token.sourceEnd+1;
3417       errorEnd   = token.sourceEnd+1;
3418     } else {
3419       errorStart = expr.sourceEnd+1;
3420       errorEnd   = expr.sourceEnd+1;
3421     }
3422     processParseExceptionDebug(e);
3423   }
3424   {
3425     if (token2 == null) {
3426       if (expr == null) {
3427         return new ReturnStatement(expr,token.sourceStart,token.sourceEnd);
3428       }
3429       return new ReturnStatement(expr,token.sourceStart,expr.sourceEnd);
3430     }
3431     return new ReturnStatement(expr,token.sourceStart,token2.sourceEnd);
3432   }
3433 }
3434