net.sourceforge.phpeclipse/src/test/PHPParser.jj

   1 options {
   2   LOOKAHEAD = 1;
   3   CHOICE_AMBIGUITY_CHECK = 2;
   4   OTHER_AMBIGUITY_CHECK = 1;
   5   STATIC = true;
   6   DEBUG_PARSER = false;
   7   DEBUG_LOOKAHEAD = false;
   8   DEBUG_TOKEN_MANAGER = false;
   9   OPTIMIZE_TOKEN_MANAGER = false;
  10   ERROR_REPORTING = true;
  11   JAVA_UNICODE_ESCAPE = false;
  12   UNICODE_INPUT = false;
  13   IGNORE_CASE = true;
  14   USER_TOKEN_MANAGER = false;
  15   USER_CHAR_STREAM = false;
  16   BUILD_PARSER = true;
  17   BUILD_TOKEN_MANAGER = true;
  18   SANITY_CHECK = true;
  19   FORCE_LA_CHECK = false;
  20 }
  21
  22 PARSER_BEGIN(PHPParser)
  23 package test;
  24
  25 import org.eclipse.core.resources.IFile;
  26 import org.eclipse.core.resources.IMarker;
  27 import org.eclipse.core.runtime.CoreException;
  28 import org.eclipse.ui.texteditor.MarkerUtilities;
  29 import org.eclipse.jface.preference.IPreferenceStore;
  30
  31 import java.util.Hashtable;
  32 import java.io.StringReader;
  33 import java.text.MessageFormat;
  34
  35 import net.sourceforge.phpeclipse.actions.PHPStartApacheAction;
  36 import net.sourceforge.phpeclipse.PHPeclipsePlugin;
  37 import net.sourceforge.phpdt.internal.compiler.parser.PHPOutlineInfo;
  38 import net.sourceforge.phpdt.internal.compiler.parser.PHPSegmentWithChildren;
  39 import net.sourceforge.phpdt.internal.compiler.parser.PHPFunctionDeclaration;
  40 import net.sourceforge.phpdt.internal.compiler.parser.PHPClassDeclaration;
  41
  42 /**
  43  * A new php parser.
  44  * This php parser is inspired by the Java 1.2 grammar example
  45  * given with JavaCC. You can get JavaCC at http://www.webgain.com
  46  * You can test the parser with the PHPParserTestCase2.java
  47  * @author Matthieu Casanova
  48  */
  49 public class PHPParser extends PHPParserSuperclass {
  50
  51   private static IFile fileToParse;
  52
  53   /** The current segment */
  54   private static PHPSegmentWithChildren currentSegment;
  55
  56   private static final String PARSE_ERROR_STRING = "Parse error"; //$NON-NLS-1$
  57   private static final String PARSE_WARNING_STRING = "Warning"; //$NON-NLS-1$
  58   public static final int ERROR = 2;
  59   public static final int WARNING = 1;
  60   public static final int INFO = 0;
  61   PHPOutlineInfo outlineInfo;
  62   private static int errorLevel = ERROR;
  63   private static String errorMessage;
  64
  65   public PHPParser() {
  66   }
  67
  68   public void setFileToParse(IFile fileToParse) {
  69     this.fileToParse = fileToParse;
  70   }
  71
  72   public PHPParser(IFile fileToParse) {
  73     this(new StringReader(""));
  74     this.fileToParse = fileToParse;
  75   }
  76
  77   public void phpParserTester(String strEval) throws CoreException, ParseException {
  78     PHPParserTokenManager.SwitchTo(PHPParserTokenManager.PHPPARSING);
  79     StringReader stream = new StringReader(strEval);
  80     if (jj_input_stream == null) {
  81       jj_input_stream = new SimpleCharStream(stream, 1, 1);
  82     }
  83     ReInit(new StringReader(strEval));
  84     phpTest();
  85   }
  86
  87   public void htmlParserTester(String strEval) throws CoreException, ParseException {
  88     StringReader stream = new StringReader(strEval);
  89     if (jj_input_stream == null) {
  90       jj_input_stream = new SimpleCharStream(stream, 1, 1);
  91     }
  92     ReInit(stream);
  93     phpFile();
  94   }
  95
  96   public PHPOutlineInfo parseInfo(Object parent, String s) {
  97     outlineInfo = new PHPOutlineInfo(parent);
  98     currentSegment = outlineInfo.getDeclarations();
  99     StringReader stream = new StringReader(s);
 100     if (jj_input_stream == null) {
 101       jj_input_stream = new SimpleCharStream(stream, 1, 1);
 102     }
 103     ReInit(stream);
 104     try {
 105       parse();
 106     } catch (ParseException e) {
 107       if (errorMessage == null) {
 108         PHPeclipsePlugin.log(e);
 109       } else {
 110         setMarker(errorMessage, e.currentToken.beginLine, errorLevel);
 111         errorMessage = null;
 112       }
 113     }
 114     return outlineInfo;
 115   }
 116
 117
 118   /**
 119    * Create marker for the parse error
 120    */
 121   private static void setMarker(String message, int lineNumber, int errorLevel) {
 122     try {
 123       setMarker(fileToParse, message, lineNumber, errorLevel);
 124     } catch (CoreException e) {
 125       PHPeclipsePlugin.log(e);
 126     }
 127   }
 128
 129   public static void setMarker(IFile file, String message, int lineNumber, int errorLevel) throws CoreException {
 130     if (file != null) {
 131       Hashtable attributes = new Hashtable();
 132       MarkerUtilities.setMessage(attributes, message);
 133       switch (errorLevel) {
 134         case ERROR :
 135           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_ERROR));
 136           break;
 137         case WARNING :
 138           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_WARNING));
 139           break;
 140         case INFO :
 141           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_INFO));
 142           break;
 143       }
 144       MarkerUtilities.setLineNumber(attributes, lineNumber);
 145       MarkerUtilities.createMarker(file, attributes, IMarker.PROBLEM);
 146     }
 147   }
 148
 149   /**
 150    * Create markers according to the external parser output
 151    */
 152   private static void createMarkers(String output, IFile file) throws CoreException {
 153     // delete all markers
 154     file.deleteMarkers(IMarker.PROBLEM, false, 0);
 155
 156     int indx = 0;
 157     int brIndx = 0;
 158     boolean flag = true;
 159     while ((brIndx = output.indexOf("<br />", indx)) != -1) {
 160       // newer php error output (tested with 4.2.3)
 161       scanLine(output, file, indx, brIndx);
 162       indx = brIndx + 6;
 163       flag = false;
 164     }
 165     if (flag) {
 166       while ((brIndx = output.indexOf("<br>", indx)) != -1) {
 167         // older php error output (tested with 4.2.3)
 168         scanLine(output, file, indx, brIndx);
 169         indx = brIndx + 4;
 170       }
 171     }
 172   }
 173
 174   private static void scanLine(String output, IFile file, int indx, int brIndx) throws CoreException {
 175     String current;
 176     StringBuffer lineNumberBuffer = new StringBuffer(10);
 177     char ch;
 178     current = output.substring(indx, brIndx);
 179
 180     if (current.indexOf(PARSE_WARNING_STRING) != -1 || current.indexOf(PARSE_ERROR_STRING) != -1) {
 181       int onLine = current.indexOf("on line <b>");
 182       if (onLine != -1) {
 183         lineNumberBuffer.delete(0, lineNumberBuffer.length());
 184         for (int i = onLine; i < current.length(); i++) {
 185           ch = current.charAt(i);
 186           if ('0' <= ch && '9' >= ch) {
 187             lineNumberBuffer.append(ch);
 188           }
 189         }
 190
 191         int lineNumber = Integer.parseInt(lineNumberBuffer.toString());
 192
 193         Hashtable attributes = new Hashtable();
 194
 195         current = current.replaceAll("\n", "");
 196         current = current.replaceAll("<b>", "");
 197         current = current.replaceAll("</b>", "");
 198         MarkerUtilities.setMessage(attributes, current);
 199
 200         if (current.indexOf(PARSE_ERROR_STRING) != -1)
 201           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_ERROR));
 202         else if (current.indexOf(PARSE_WARNING_STRING) != -1)
 203           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_WARNING));
 204         else
 205           attributes.put(IMarker.SEVERITY, new Integer(IMarker.SEVERITY_INFO));
 206         MarkerUtilities.setLineNumber(attributes, lineNumber);
 207         MarkerUtilities.createMarker(file, attributes, IMarker.PROBLEM);
 208       }
 209     }
 210   }
 211
 212   public void parse(String s) throws CoreException {
 213     ReInit(new StringReader(s));
 214     try {
 215       parse();
 216     } catch (ParseException e) {
 217       if (errorMessage == null) {
 218         PHPeclipsePlugin.log(e);
 219       } else {
 220         setMarker(errorMessage, e.currentToken.beginLine, errorLevel);
 221         errorMessage = null;
 222       }
 223     }
 224   }
 225
 226   /**
 227    * Call the php parse command ( php -l -f &lt;filename&gt; )
 228    * and create markers according to the external parser output
 229    */
 230   public static void phpExternalParse(IFile file) {
 231     IPreferenceStore store = PHPeclipsePlugin.getDefault().getPreferenceStore();
 232     String filename = file.getLocation().toString();
 233
 234     String[] arguments = { filename };
 235     MessageFormat form = new MessageFormat(store.getString(PHPeclipsePlugin.EXTERNAL_PARSER_PREF));
 236     String command = form.format(arguments);
 237
 238     String parserResult = PHPStartApacheAction.getParserOutput(command, "External parser: ");
 239
 240     try {
 241       // parse the buffer to find the errors and warnings
 242       createMarkers(parserResult, file);
 243     } catch (CoreException e) {
 244       PHPeclipsePlugin.log(e);
 245     }
 246   }
 247
 248   public void parse() throws ParseException {
 249           phpFile();
 250   }
 251 }
 252
 253 PARSER_END(PHPParser)
 254
 255 <DEFAULT> TOKEN :
 256 {
 257   <PHPSTART : "<?php" | "<?"> : PHPPARSING
 258 }
 259
 260 <PHPPARSING> TOKEN :
 261 {
 262   <PHPEND :"?>"> : DEFAULT
 263 }
 264
 265 <DEFAULT> SKIP :
 266 {
 267  < ~[] >
 268 }
 269
 270
 271 /* WHITE SPACE */
 272
 273 <PHPPARSING> SKIP :
 274 {
 275   " "
 276 | "\t"
 277 | "\n"
 278 | "\r"
 279 | "\f"
 280 }
 281
 282 /* COMMENTS */
 283
 284 <PHPPARSING> MORE :
 285 {
 286   "//" : IN_SINGLE_LINE_COMMENT
 287 |
 288   <"/**" ~["/"]> { input_stream.backup(1); } : IN_FORMAL_COMMENT
 289 |
 290   "/*" : IN_MULTI_LINE_COMMENT
 291 }
 292
 293 <IN_SINGLE_LINE_COMMENT>
 294 SPECIAL_TOKEN :
 295 {
 296   <SINGLE_LINE_COMMENT: "\n" | "\r" | "\r\n" | "?>" > : PHPPARSING
 297 }
 298
 299 <IN_FORMAL_COMMENT>
 300 SPECIAL_TOKEN :
 301 {
 302   <FORMAL_COMMENT: "*/" > : PHPPARSING
 303 }
 304
 305 <IN_MULTI_LINE_COMMENT>
 306 SPECIAL_TOKEN :
 307 {
 308   <MULTI_LINE_COMMENT: "*/" > : PHPPARSING
 309 }
 310
 311 <IN_SINGLE_LINE_COMMENT,IN_FORMAL_COMMENT,IN_MULTI_LINE_COMMENT>
 312 MORE :
 313 {
 314   < ~[] >
 315 }
 316
 317 /* KEYWORDS */
 318 <PHPPARSING> TOKEN :
 319 {
 320   <CLASS    : "class">
 321 | <FUNCTION : "function">
 322 | <VAR      : "var">
 323 | <IF       : "if">
 324 | <ELSEIF   : "elseif">
 325 | <ELSE     : "else">
 326 | <ARRAY    : "array">
 327 }
 328
 329 /* LANGUAGE CONSTRUCT */
 330 <PHPPARSING> TOKEN :
 331 {
 332   <PRINT : "print">
 333 | <ECHO : "echo">
 334 | <INCLUDE : "include">
 335 | <REQUIRE : "require">
 336 | <INCLUDE_ONCE : "include_once">
 337 | <REQUIRE_ONCE : "require_once">
 338 | <GLOBAL : "global">
 339 | <STATIC : "static">
 340 | <CLASSACCESS: "->">
 341 | <STATICCLASSACCESS: "::">
 342 | <ARRAYASSIGN: "=>">
 343 }
 344
 345 /* RESERVED WORDS AND LITERALS */
 346
 347 <PHPPARSING> TOKEN :
 348 {
 349   < BREAK: "break" >
 350 | < CASE: "case" >
 351 | < CONST: "const" >
 352 | < CONTINUE: "continue" >
 353 | < _DEFAULT: "default" >
 354 | < DO: "do" >
 355 | < EXTENDS: "extends" >
 356 | < FALSE: "false" >
 357 | < FOR: "for" >
 358 | < GOTO: "goto" >
 359 | < NEW: "new" >
 360 | < NULL: "null" >
 361 | < RETURN: "return" >
 362 | < SUPER: "super" >
 363 | < SWITCH: "switch" >
 364 | < THIS: "this" >
 365 | < TRUE: "true" >
 366 | < WHILE: "while" >
 367 | < ENDWHILE : "endwhile" >
 368 }
 369
 370 /* TYPES */
 371
 372 <PHPPARSING> TOKEN :
 373 {
 374   <STRING : "string">
 375 | <OBJECT : "object">
 376 | <BOOL : "bool">
 377 | <BOOLEAN : "boolean">
 378 | <REAL : "real">
 379 | <DOUBLE : "double">
 380 | <FLOAT : "float">
 381 | <INT : "int">
 382 | <INTEGER : "integer">
 383 }
 384
 385 <PHPPARSING> TOKEN :
 386 {
 387   < _ORL : "OR" >
 388 | < _ANDL: "AND">
 389 }
 390
 391 /* LITERALS */
 392
 393 <PHPPARSING> TOKEN :
 394 {
 395   < INTEGER_LITERAL:
 396         <DECIMAL_LITERAL> (["l","L"])?
 397       | <HEX_LITERAL> (["l","L"])?
 398       | <OCTAL_LITERAL> (["l","L"])?
 399   >
 400 |
 401   < #DECIMAL_LITERAL: ["1"-"9"] (["0"-"9"])* >
 402 |
 403   < #HEX_LITERAL: "0" ["x","X"] (["0"-"9","a"-"f","A"-"F"])+ >
 404 |
 405   < #OCTAL_LITERAL: "0" (["0"-"7"])* >
 406 |
 407   < FLOATING_POINT_LITERAL:
 408         (["0"-"9"])+ "." (["0"-"9"])* (<EXPONENT>)? (["f","F","d","D"])?
 409       | "." (["0"-"9"])+ (<EXPONENT>)? (["f","F","d","D"])?
 410       | (["0"-"9"])+ <EXPONENT> (["f","F","d","D"])?
 411       | (["0"-"9"])+ (<EXPONENT>)? ["f","F","d","D"]
 412   >
 413 |
 414   < #EXPONENT: ["e","E"] (["+","-"])? (["0"-"9"])+ >
 415 |
 416   < STRING_LITERAL: (<STRING_1> | <STRING_2> | <STRING_3>)>
 417 |    < STRING_1:
 418       "\""
 419       (   (~["\""])
 420         | "\\\""
 421       )*
 422       "\""
 423     >
 424 |    < STRING_2:
 425       "'"
 426       (   (~["'"]))*
 427
 428       "'"
 429     >
 430 |   < STRING_3:
 431       "`"
 432       (   (~["`"]))*
 433       "`"
 434     >
 435 }
 436
 437 /* IDENTIFIERS */
 438
 439 <PHPPARSING> TOKEN :
 440 {
 441   < IDENTIFIER: (<LETTER>|<SPECIAL>) (<LETTER>|<DIGIT>|<SPECIAL>)* >
 442 |
 443   < #LETTER:
 444       ["a"-"z"] | ["A"-"Z"]
 445   >
 446 |
 447   < #DIGIT:
 448       ["0"-"9"]
 449   >
 450 |
 451   < #SPECIAL:
 452     "_"
 453   >
 454 }
 455
 456 /* SEPARATORS */
 457
 458 <PHPPARSING> TOKEN :
 459 {
 460   < LPAREN: "(" >
 461 | < RPAREN: ")" >
 462 | < LBRACE: "{" >
 463 | < RBRACE: "}" >
 464 | < LBRACKET: "[" >
 465 | < RBRACKET: "]" >
 466 | < SEMICOLON: ";" >
 467 | < COMMA: "," >
 468 | < DOT: "." >
 469 }
 470
 471 /* OPERATORS */
 472
 473 <PHPPARSING> TOKEN :
 474 {
 475   <AT     : "@">
 476 | <DOLLAR : "$">
 477 | < ASSIGN: "=" >
 478 | < GT: ">" >
 479 | < LT: "<" >
 480 | < BANG: "!" >
 481 | < HOOK: "?" >
 482 | < COLON: ":" >
 483 | < EQ: "==" >
 484 | < LE: "<=" >
 485 | < GE: ">=" >
 486 | < NE: "!=" >
 487 | < SC_OR: "||" >
 488 | < SC_AND: "&&" >
 489 | < INCR: "++" >
 490 | < DECR: "--" >
 491 | < PLUS: "+" >
 492 | < MINUS: "-" >
 493 | < STAR: "*" >
 494 | < SLASH: "/" >
 495 | < BIT_AND: "&" >
 496 | < BIT_OR: "|" >
 497 | < XOR: "^" >
 498 | < REM: "%" >
 499 | < LSHIFT: "<<" >
 500 | < RSIGNEDSHIFT: ">>" >
 501 | < RUNSIGNEDSHIFT: ">>>" >
 502 | < PLUSASSIGN: "+=" >
 503 | < MINUSASSIGN: "-=" >
 504 | < STARASSIGN: "*=" >
 505 | < SLASHASSIGN: "/=" >
 506 | < ANDASSIGN: "&=" >
 507 | < ORASSIGN: "|=" >
 508 | < XORASSIGN: "^=" >
 509 | < DOTASSIGN: ".=" >
 510 | < REMASSIGN: "%=" >
 511 | < LSHIFTASSIGN: "<<=" >
 512 | < RSIGNEDSHIFTASSIGN: ">>=" >
 513 | < RUNSIGNEDSHIFTASSIGN: ">>>=" >
 514 }
 515
 516 <PHPPARSING> TOKEN :
 517 {
 518   < DOLLAR_ID: <DOLLAR> <IDENTIFIER>  >
 519 }
 520
 521 /*****************************************
 522  * THE JAVA LANGUAGE GRAMMAR STARTS HERE *
 523  *****************************************/
 524
 525 /*
 526  * Program structuring syntax follows.
 527  */
 528
 529 void phpTest() :
 530 {}
 531 {
 532   Php()
 533   <EOF>
 534 }
 535
 536 void phpFile() :
 537 {}
 538 {
 539   (<PHPSTART> Php() <PHPEND>)*
 540   <EOF>
 541 }
 542
 543 void Php() :
 544 {}
 545 {
 546   (BlockStatement())*
 547 }
 548
 549 void ClassDeclaration() :
 550 {
 551   PHPClassDeclaration classDeclaration;
 552   Token className;
 553   int pos = jj_input_stream.bufpos;
 554 }
 555 {
 556   <CLASS> className = <IDENTIFIER> [ <EXTENDS> <IDENTIFIER> ]
 557   {
 558     classDeclaration = new PHPClassDeclaration(currentSegment,className.image,pos);
 559     currentSegment.add(classDeclaration);
 560     currentSegment = classDeclaration;
 561   }
 562   ClassBody()
 563   {
 564     currentSegment = (PHPSegmentWithChildren) currentSegment.getParent();
 565   }
 566 }
 567
 568 void ClassBody() :
 569 {}
 570 {
 571   <LBRACE> ( ClassBodyDeclaration() )* <RBRACE>
 572 }
 573
 574 void ClassBodyDeclaration() :
 575 {}
 576 {
 577   MethodDeclaration()
 578 |
 579   FieldDeclaration()
 580 }
 581
 582 void FieldDeclaration() :
 583 {}
 584 {
 585   <VAR> VariableDeclarator() ( <COMMA> VariableDeclarator() )* <SEMICOLON>
 586 }
 587
 588 void VariableDeclarator() :
 589 {}
 590 {
 591   VariableDeclaratorId() [ <ASSIGN> VariableInitializer() ]
 592 }
 593
 594 void VariableDeclaratorId() :
 595 {}
 596 {
 597   Variable() ( LOOKAHEAD(2) VariableSuffix() )*
 598 }
 599
 600 void Variable():
 601 {}
 602 {
 603   <DOLLAR_ID> (<LBRACE> Expression() <RBRACE>) *
 604 |
 605   <DOLLAR> VariableName()
 606 }
 607
 608 void VariableName():
 609 {}
 610 {
 611   <LBRACE> Expression() <RBRACE>
 612 |
 613   <IDENTIFIER> (<LBRACE> Expression() <RBRACE>) *
 614 |
 615   <DOLLAR> VariableName()
 616 }
 617
 618 void VariableInitializer() :
 619 {}
 620 {
 621   Expression()
 622 }
 623
 624 void ArrayVariable() :
 625 {}
 626 {
 627   Expression() (<ARRAYASSIGN> Expression())*
 628 }
 629
 630 void ArrayInitializer() :
 631 {}
 632 {
 633   <LPAREN> [ ArrayVariable() ( LOOKAHEAD(2) <COMMA> ArrayVariable() )* ]<RPAREN>
 634 }
 635
 636 void MethodDeclaration() :
 637 {
 638   PHPFunctionDeclaration functionDeclaration;
 639 }
 640 {
 641   <FUNCTION> functionDeclaration = MethodDeclarator()
 642   {
 643     currentSegment.add(functionDeclaration);
 644     currentSegment = functionDeclaration;
 645   }
 646   ( Block() | <SEMICOLON> )
 647   {
 648     currentSegment = (PHPSegmentWithChildren) currentSegment.getParent();
 649   }
 650 }
 651
 652 PHPFunctionDeclaration MethodDeclarator() :
 653 {
 654   Token bit_and = null;
 655   Token identifier;
 656   StringBuffer methodDeclaration = new StringBuffer();
 657   String formalParameters;
 658   int pos = jj_input_stream.bufpos;
 659 }
 660 {
 661   [ bit_and = <BIT_AND>]
 662   identifier = <IDENTIFIER> FormalParameters()
 663   {
 664     if (bit_and != null) {
 665       methodDeclaration.append("&");
 666     }
 667     methodDeclaration.append(identifier);
 668     return new PHPFunctionDeclaration(currentSegment,methodDeclaration.toString(),pos);
 669   }
 670 }
 671
 672 void FormalParameters() :
 673 {}
 674 {
 675   <LPAREN> [ FormalParameter() ( <COMMA> FormalParameter() )* ] <RPAREN>
 676 }
 677
 678 void FormalParameter() :
 679 {}
 680 {
 681   [<BIT_AND>] VariableDeclarator()
 682 }
 683
 684 void Type() :
 685 {}
 686 {
 687   <STRING>
 688 |
 689   <BOOL>
 690 |
 691   <BOOLEAN>
 692 |
 693   <REAL>
 694 |
 695   <DOUBLE>
 696 |
 697   <FLOAT>
 698 |
 699   <INT>
 700 |
 701   <INTEGER>
 702 }
 703
 704 /*
 705  * Expression syntax follows.
 706  */
 707
 708 void Expression() :
 709 /*
 710  * This expansion has been written this way instead of:
 711  *   Assignment() | ConditionalExpression()
 712  * for performance reasons.
 713  * However, it is a weakening of the grammar for it allows the LHS of
 714  * assignments to be any conditional expression whereas it can only be
 715  * a primary expression.  Consider adding a semantic predicate to work
 716  * around this.
 717  */
 718 {}
 719 {
 720   PrintExpression()
 721 |
 722   ConditionalExpression()
 723   [
 724     AssignmentOperator() Expression()
 725   ]
 726 }
 727
 728 void AssignmentOperator() :
 729 {}
 730 {
 731   <ASSIGN> | <STARASSIGN> | <SLASHASSIGN> | <REMASSIGN> | <PLUSASSIGN> | <MINUSASSIGN> | <LSHIFTASSIGN> | <RSIGNEDSHIFTASSIGN> | <RUNSIGNEDSHIFTASSIGN> | <ANDASSIGN> | <XORASSIGN> | <ORASSIGN> | <DOTASSIGN>
 732 }
 733
 734 void ConditionalExpression() :
 735 {}
 736 {
 737   ConditionalOrExpression() [ <HOOK> Expression() <COLON> ConditionalExpression() ]
 738 }
 739
 740 void ConditionalOrExpression() :
 741 {}
 742 {
 743   ConditionalAndExpression() ( (<SC_OR> | <_ORL>) ConditionalAndExpression() )*
 744 }
 745
 746 void ConditionalAndExpression() :
 747 {}
 748 {
 749   ConcatExpression() ( (<SC_AND> | <_ANDL>) ConcatExpression() )*
 750 }
 751
 752 void ConcatExpression() :
 753 {}
 754 {
 755   InclusiveOrExpression() ( <DOT> InclusiveOrExpression() )*
 756 }
 757
 758 void InclusiveOrExpression() :
 759 {}
 760 {
 761   ExclusiveOrExpression() ( <BIT_OR> ExclusiveOrExpression() )*
 762 }
 763
 764 void ExclusiveOrExpression() :
 765 {}
 766 {
 767   AndExpression() ( <XOR> AndExpression() )*
 768 }
 769
 770 void AndExpression() :
 771 {}
 772 {
 773   EqualityExpression() ( <BIT_AND> EqualityExpression() )*
 774 }
 775
 776 void EqualityExpression() :
 777 {}
 778 {
 779   RelationalExpression() ( ( <EQ> | <NE> ) RelationalExpression() )*
 780 }
 781
 782 void RelationalExpression() :
 783 {}
 784 {
 785   ShiftExpression() ( ( <LT> | <GT> | <LE> | <GE> ) ShiftExpression() )*
 786 }
 787
 788 void ShiftExpression() :
 789 {}
 790 {
 791   AdditiveExpression() ( ( <LSHIFT> | <RSIGNEDSHIFT> | <RUNSIGNEDSHIFT> ) AdditiveExpression() )*
 792 }
 793
 794 void AdditiveExpression() :
 795 {}
 796 {
 797   MultiplicativeExpression() ( ( <PLUS> | <MINUS> ) MultiplicativeExpression() )*
 798 }
 799
 800 void MultiplicativeExpression() :
 801 {}
 802 {
 803   UnaryExpression() ( ( <STAR> | <SLASH> | <REM> ) UnaryExpression() )*
 804 }
 805
 806 void UnaryExpression() :
 807 {}
 808 {
 809   <AT> UnaryExpression()
 810 |
 811   ( <PLUS> | <MINUS> ) UnaryExpression()
 812 |
 813   PreIncrementExpression()
 814 |
 815   PreDecrementExpression()
 816 |
 817   UnaryExpressionNotPlusMinus()
 818 }
 819
 820 void PreIncrementExpression() :
 821 {}
 822 {
 823   <INCR> PrimaryExpression()
 824 }
 825
 826 void PreDecrementExpression() :
 827 {}
 828 {
 829   <DECR> PrimaryExpression()
 830 }
 831
 832 void UnaryExpressionNotPlusMinus() :
 833 {}
 834 {
 835   <BANG> UnaryExpression()
 836 |
 837   LOOKAHEAD( <LPAREN> Type() <RPAREN> )
 838   CastExpression()
 839 |
 840   PostfixExpression()
 841 |
 842   Literal()
 843 |
 844   <LPAREN>Expression()<RPAREN>
 845 }
 846
 847 void CastExpression() :
 848 {}
 849 {
 850   <LPAREN> Type() <RPAREN> UnaryExpression()
 851 }
 852
 853 void PostfixExpression() :
 854 {}
 855 {
 856   PrimaryExpression() [ <INCR> | <DECR> ]
 857 }
 858
 859 void PrimaryExpression() :
 860 {}
 861 {
 862   LOOKAHEAD(2)
 863   <IDENTIFIER> <STATICCLASSACCESS> ClassIdentifier() (PrimarySuffix())*
 864 |
 865   PrimaryPrefix() ( PrimarySuffix() )*
 866 |
 867   <ARRAY> ArrayInitializer()
 868 }
 869
 870 void PrimaryPrefix() :
 871 {}
 872 {
 873   <IDENTIFIER>
 874 |
 875   <NEW> ClassIdentifier()
 876 |
 877   VariableDeclaratorId()
 878 }
 879
 880 void ClassIdentifier():
 881 {}
 882 {
 883   <IDENTIFIER>
 884 |
 885   VariableDeclaratorId()
 886 }
 887
 888 void PrimarySuffix() :
 889 {}
 890 {
 891   Arguments()
 892 |
 893   VariableSuffix()
 894 }
 895
 896 void VariableSuffix() :
 897 {}
 898 {
 899   <CLASSACCESS> VariableName()
 900 |
 901   <LBRACKET> [ Expression() ] <RBRACKET>
 902 }
 903
 904 void Literal() :
 905 {}
 906 {
 907   <INTEGER_LITERAL>
 908 |
 909   <FLOATING_POINT_LITERAL>
 910 |
 911   <STRING_LITERAL>
 912 |
 913   BooleanLiteral()
 914 |
 915   NullLiteral()
 916 }
 917
 918 void BooleanLiteral() :
 919 {}
 920 {
 921   <TRUE>
 922 |
 923   <FALSE>
 924 }
 925
 926 void NullLiteral() :
 927 {}
 928 {
 929   <NULL>
 930 }
 931
 932 void Arguments() :
 933 {}
 934 {
 935   <LPAREN> [ ArgumentList() ]
 936   try {
 937     <RPAREN>
 938   } catch (ParseException e) {
 939     errorMessage = "')' expected to close the argument list";
 940     errorLevel   = ERROR;
 941     throw e;
 942   }
 943 }
 944
 945 void ArgumentList() :
 946 {}
 947 {
 948   Expression()
 949   ( <COMMA>
 950       try {
 951         Expression()
 952       } catch (ParseException e) {
 953         errorMessage = "expression expected after a comma in argument list";
 954         errorLevel   = ERROR;
 955         throw e;
 956       }
 957    )*
 958 }
 959
 960 /*
 961  * Statement syntax follows.
 962  */
 963
 964 void Statement() :
 965 {}
 966 {
 967   LOOKAHEAD(2)
 968   Expression()  (<SEMICOLON> | "?>")
 969 |
 970   LOOKAHEAD(2)
 971   LabeledStatement()
 972 |
 973   Block()
 974 |
 975   EmptyStatement()
 976 |
 977   StatementExpression()
 978   try {
 979     <SEMICOLON>
 980   } catch (ParseException e) {
 981     errorMessage = "';' expected after expression";
 982     errorLevel   = ERROR;
 983     throw e;
 984   }
 985 |
 986   SwitchStatement()
 987 |
 988   IfStatement()
 989 |
 990   WhileStatement()
 991 |
 992   DoStatement()
 993 |
 994   ForStatement()
 995 |
 996   BreakStatement()
 997 |
 998   ContinueStatement()
 999 |
1000   ReturnStatement()
1001 |
1002   EchoStatement()
1003 |
1004   IncludeStatement()
1005 |
1006   StaticStatement()
1007 |
1008   GlobalStatement()
1009 }
1010
1011 void IncludeStatement() :
1012 {}
1013 {
1014   <REQUIRE> Expression() (<SEMICOLON> | "?>")
1015 |
1016   <REQUIRE_ONCE> Expression() (<SEMICOLON> | "?>")
1017 |
1018   <INCLUDE> Expression() (<SEMICOLON> | "?>")
1019 |
1020   <INCLUDE_ONCE> Expression() (<SEMICOLON> | "?>")
1021 }
1022
1023 void PrintExpression() :
1024 {}
1025 {
1026   <PRINT> Expression()
1027 }
1028
1029 void EchoStatement() :
1030 {}
1031 {
1032   <ECHO> Expression() (<COMMA> Expression())*
1033   try {
1034     (<SEMICOLON> | "?>")
1035   } catch (ParseException e) {
1036     errorMessage = "';' expected after 'echo' statement";
1037     errorLevel   = ERROR;
1038     throw e;
1039   }
1040 }
1041
1042 void GlobalStatement() :
1043 {}
1044 {
1045   <GLOBAL> VariableDeclaratorId() (<COMMA> VariableDeclaratorId())* (<SEMICOLON> | "?>")
1046 }
1047
1048 void StaticStatement() :
1049 {}
1050 {
1051   <STATIC> VariableDeclarator() (<COMMA> VariableDeclarator())* (<SEMICOLON> | "?>")
1052 }
1053
1054 void LabeledStatement() :
1055 {}
1056 {
1057   <IDENTIFIER> <COLON> Statement()
1058 }
1059
1060 void Block() :
1061 {}
1062 {
1063   <LBRACE> ( BlockStatement() )* <RBRACE>
1064 }
1065
1066 void BlockStatement() :
1067 {}
1068 {
1069   Statement()
1070 |
1071   ClassDeclaration()
1072 |
1073   MethodDeclaration()
1074 }
1075
1076 void LocalVariableDeclaration() :
1077 {}
1078 {
1079   VariableDeclarator() ( <COMMA> VariableDeclarator() )*
1080 }
1081
1082 void EmptyStatement() :
1083 {}
1084 {
1085   <SEMICOLON>
1086 }
1087
1088 void StatementExpression() :
1089 /*
1090  * The last expansion of this production accepts more than the legal
1091  * Java expansions for StatementExpression.  This expansion does not
1092  * use PostfixExpression for performance reasons.
1093  */
1094 {}
1095 {
1096   PreIncrementExpression()
1097 |
1098   PreDecrementExpression()
1099 |
1100   PrimaryExpression()
1101   [
1102    <INCR>
1103   |
1104     <DECR>
1105   |
1106     AssignmentOperator() Expression()
1107   ]
1108 }
1109
1110 void SwitchStatement() :
1111 {}
1112 {
1113   <SWITCH> <LPAREN> Expression() <RPAREN> <LBRACE>
1114     ( SwitchLabel() ( BlockStatement() )* )*
1115   <RBRACE>
1116 }
1117
1118 void SwitchLabel() :
1119 {}
1120 {
1121   <CASE> Expression() <COLON>
1122 |
1123   <_DEFAULT> <COLON>
1124 }
1125
1126 void IfStatement() :
1127 /*
1128  * The disambiguating algorithm of JavaCC automatically binds dangling
1129  * else's to the innermost if statement.  The LOOKAHEAD specification
1130  * is to tell JavaCC that we know what we are doing.
1131  */
1132 {}
1133 {
1134   <IF> Condition("if") Statement() [ LOOKAHEAD(1) ElseIfStatement() ] [ LOOKAHEAD(1) <ELSE> Statement() ]
1135 }
1136
1137 void Condition(String keyword) :
1138 {}
1139 {
1140   try {
1141     <LPAREN>
1142   } catch (ParseException e) {
1143     errorMessage = "'(' expected after " + keyword + " keyword";
1144     errorLevel   = ERROR;
1145     throw e;
1146   }
1147   Expression()
1148   try {
1149      <RPAREN>
1150   } catch (ParseException e) {
1151     errorMessage = "')' expected after " + keyword + " keyword";
1152     errorLevel   = ERROR;
1153     throw e;
1154   }
1155 }
1156
1157 void ElseIfStatement() :
1158 {}
1159 {
1160   <ELSEIF> Condition("elseif") Statement()
1161 }
1162
1163 void WhileStatement() :
1164 {}
1165 {
1166   <WHILE> Condition("while") WhileStatement0()
1167 }
1168
1169 void WhileStatement0() :
1170 {}
1171 {
1172   <COLON> (Statement())* <ENDWHILE> (<SEMICOLON> | "?>")
1173 |
1174   Statement()
1175 }
1176
1177 void DoStatement() :
1178 {}
1179 {
1180   <DO> Statement() <WHILE> Condition("while") (<SEMICOLON> | "?>")
1181 }
1182
1183 void ForStatement() :
1184 {}
1185 {
1186   <FOR> <LPAREN> [ ForInit() ] <SEMICOLON> [ Expression() ] <SEMICOLON> [ ForUpdate() ] <RPAREN> Statement()
1187 }
1188
1189 void ForInit() :
1190 {}
1191 {
1192   LOOKAHEAD(LocalVariableDeclaration())
1193   LocalVariableDeclaration()
1194 |
1195   StatementExpressionList()
1196 }
1197
1198 void StatementExpressionList() :
1199 {}
1200 {
1201   StatementExpression() ( <COMMA> StatementExpression() )*
1202 }
1203
1204 void ForUpdate() :
1205 {}
1206 {
1207   StatementExpressionList()
1208 }
1209
1210 void BreakStatement() :
1211 {}
1212 {
1213   <BREAK> [ <IDENTIFIER> ] <SEMICOLON>
1214 }
1215
1216 void ContinueStatement() :
1217 {}
1218 {
1219   <CONTINUE> [ <IDENTIFIER> ] <SEMICOLON>
1220 }
1221
1222 void ReturnStatement() :
1223 {}
1224 {
1225   <RETURN> [ Expression() ] <SEMICOLON>
1226 }